Skip to content

armgit / Handy

Public Imported from GitHub
0

A free, open source, and extensible speech-to-text application that works completely offline.

feat: add portable mode to NSIS installer (#807)

Shehab Tarek10beb60d637d
diff --git a/src-tauri/nsis/installer.nsi b/src-tauri/nsis/installer.nsi
new file mode 100644
index 00000000..5f72bae0
--- /dev/null
+++ b/src-tauri/nsis/installer.nsi
@@ -0,0 +1,1078 @@
+; Custom NSIS template for Handy with portable mode support.
+; Based on tauri-apps/[email protected] crates/tauri-bundler/src/bundle/windows/nsis/installer.nsi
+; Portable changes are marked with "; --- PORTABLE MODE ---" comments.
+;
+; When upgrading Tauri, diff this file against the new upstream template and
+; merge changes while preserving the portable sections.
+
+Unicode true
+ManifestDPIAware true
+; Add in `dpiAwareness` `PerMonitorV2` to manifest for Windows 10 1607+ (note this should not affect lower versions since they should be able to ignore this and pick up `dpiAware` `true` set by `ManifestDPIAware true`)
+; Currently undocumented on NSIS's website but is in the Docs folder of source tree, see
+; https://github.com/kichik/nsis/blob/5fc0b87b819a9eec006df4967d08e522ddd651c9/Docs/src/attributes.but#L286-L300
+; https://github.com/tauri-apps/tauri/pull/10106
+ManifestDPIAwareness PerMonitorV2
+
+!if "{{compression}}" == "none"
+ SetCompress off
+!else
+ ; Set the compression algorithm. We default to LZMA.
+ SetCompressor /SOLID "{{compression}}"
+!endif
+
+!include MUI2.nsh
+!include FileFunc.nsh
+!include x64.nsh
+!include WordFunc.nsh
+!include "utils.nsh"
+!include "FileAssociation.nsh"
+!include "Win\COM.nsh"
+!include "Win\Propkey.nsh"
+!include "StrFunc.nsh"
+${StrCase}
+${StrLoc}
+
+{{#if installer_hooks}}
+!include "{{installer_hooks}}"
+{{/if}}
+
+!define WEBVIEW2APPGUID "{F3017226-FE2A-4295-8BDF-00C3A9A7E4C5}"
+
+!define MANUFACTURER "{{manufacturer}}"
+!define PRODUCTNAME "{{product_name}}"
+!define VERSION "{{version}}"
+!define VERSIONWITHBUILD "{{version_with_build}}"
+!define HOMEPAGE "{{homepage}}"
+!define INSTALLMODE "{{install_mode}}"
+!define LICENSE "{{license}}"
+!define INSTALLERICON "{{installer_icon}}"
+!define SIDEBARIMAGE "{{sidebar_image}}"
+!define HEADERIMAGE "{{header_image}}"
+!define MAINBINARYNAME "{{main_binary_name}}"
+!define MAINBINARYSRCPATH "{{main_binary_path}}"
+!define BUNDLEID "{{bundle_id}}"
+!define COPYRIGHT "{{copyright}}"
+!define OUTFILE "{{out_file}}"
+!define ARCH "{{arch}}"
+!define ADDITIONALPLUGINSPATH "{{additional_plugins_path}}"
+!define ALLOWDOWNGRADES "{{allow_downgrades}}"
+!define DISPLAYLANGUAGESELECTOR "{{display_language_selector}}"
+!define INSTALLWEBVIEW2MODE "{{install_webview2_mode}}"
+!define WEBVIEW2INSTALLERARGS "{{webview2_installer_args}}"
+!define WEBVIEW2BOOTSTRAPPERPATH "{{webview2_bootstrapper_path}}"
+!define WEBVIEW2INSTALLERPATH "{{webview2_installer_path}}"
+!define MINIMUMWEBVIEW2VERSION "{{minimum_webview2_version}}"
+!define UNINSTKEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCTNAME}"
+!define MANUKEY "Software\${MANUFACTURER}"
+!define MANUPRODUCTKEY "${MANUKEY}\${PRODUCTNAME}"
+!define UNINSTALLERSIGNCOMMAND "{{uninstaller_sign_cmd}}"
+!define ESTIMATEDSIZE "{{estimated_size}}"
+!define STARTMENUFOLDER "{{start_menu_folder}}"
+
+Var PassiveMode
+Var UpdateMode
+Var NoShortcutMode
+Var WixMode
+Var OldMainBinaryName
+
+; --- PORTABLE MODE ---
+Var PortableMode
+
+Name "${PRODUCTNAME}"
+BrandingText "${COPYRIGHT}"
+OutFile "${OUTFILE}"
+
+; We don't actually use this value as default install path,
+; it's just for nsis to append the product name folder in the directory selector
+; https://nsis.sourceforge.io/Reference/InstallDir
+!define PLACEHOLDER_INSTALL_DIR "placeholder\${PRODUCTNAME}"
+InstallDir "${PLACEHOLDER_INSTALL_DIR}"
+
+VIProductVersion "${VERSIONWITHBUILD}"
+VIAddVersionKey "ProductName" "${PRODUCTNAME}"
+VIAddVersionKey "FileDescription" "${PRODUCTNAME}"
+VIAddVersionKey "LegalCopyright" "${COPYRIGHT}"
+VIAddVersionKey "FileVersion" "${VERSION}"
+VIAddVersionKey "ProductVersion" "${VERSION}"
+
+# additional plugins
+!addplugindir "${ADDITIONALPLUGINSPATH}"
+
+; Uninstaller signing command
+!if "${UNINSTALLERSIGNCOMMAND}" != ""
+ !uninstfinalize '${UNINSTALLERSIGNCOMMAND}'
+!endif
+
+; Handle install mode, `perUser`, `perMachine` or `both`
+!if "${INSTALLMODE}" == "perMachine"
+ RequestExecutionLevel admin
+!endif
+
+!if "${INSTALLMODE}" == "currentUser"
+ RequestExecutionLevel user
+!endif
+
+!if "${INSTALLMODE}" == "both"
+ !define MULTIUSER_MUI
+ !define MULTIUSER_INSTALLMODE_INSTDIR "${PRODUCTNAME}"
+ !define MULTIUSER_INSTALLMODE_COMMANDLINE
+ !if "${ARCH}" == "x64"
+ !define MULTIUSER_USE_PROGRAMFILES64
+ !else if "${ARCH}" == "arm64"
+ !define MULTIUSER_USE_PROGRAMFILES64
+ !endif
+ !define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_KEY "${UNINSTKEY}"
+ !define MULTIUSER_INSTALLMODE_DEFAULT_REGISTRY_VALUENAME "CurrentUser"
+ !define MULTIUSER_INSTALLMODEPAGE_SHOWUSERNAME
+ !define MULTIUSER_INSTALLMODE_FUNCTION RestorePreviousInstallLocation
+ !define MULTIUSER_EXECUTIONLEVEL Highest
+ !include MultiUser.nsh
+!endif
+
+; Installer icon
+!if "${INSTALLERICON}" != ""
+ !define MUI_ICON "${INSTALLERICON}"
+!endif
+
+; Installer sidebar image
+!if "${SIDEBARIMAGE}" != ""
+ !define MUI_WELCOMEFINISHPAGE_BITMAP "${SIDEBARIMAGE}"
+!endif
+
+; Installer header image
+!if "${HEADERIMAGE}" != ""
+ !define MUI_HEADERIMAGE
+ !define MUI_HEADERIMAGE_BITMAP "${HEADERIMAGE}"
+!endif
+
+; Define registry key to store installer language
+!define MUI_LANGDLL_REGISTRY_ROOT "HKCU"
+!define MUI_LANGDLL_REGISTRY_KEY "${MANUPRODUCTKEY}"
+!define MUI_LANGDLL_REGISTRY_VALUENAME "Installer Language"
+
+; Installer pages, must be ordered as they appear
+; 1. Welcome Page
+!define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassive
+!insertmacro MUI_PAGE_WELCOME
+
+; 2. License Page (if defined)
+!if "${LICENSE}" != ""
+ !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassive
+ !insertmacro MUI_PAGE_LICENSE "${LICENSE}"
+!endif
+
+; 3. Install mode (if it is set to `both`)
+!if "${INSTALLMODE}" == "both"
+ !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassive
+ !insertmacro MULTIUSER_PAGE_INSTALLMODE
+!endif
+
+; --- PORTABLE MODE --- 4. Install type selection page (Normal vs Portable)
+Var InstallTypeRadioNormal
+Var InstallTypeRadioPortable
+Page custom PageInstallType PageLeaveInstallType
+
+Function PageInstallType
+ ; Skip for passive/silent/update modes — portable flag is handled via /PORTABLE
+ ${If} $PassiveMode = 1
+ ${OrIf} ${Silent}
+ ${OrIf} $UpdateMode = 1
+ Abort
+ ${EndIf}
+
+ !insertmacro MUI_HEADER_TEXT "Choose Install Type" "Select how you want to install ${PRODUCTNAME}."
+
+ nsDialogs::Create 1018
+ Pop $0
+ ${If} $0 == error
+ Abort
+ ${EndIf}
+
+ ${NSD_CreateLabel} 0 0 100% 24u "Choose whether to perform a normal installation or a portable installation."
+ Pop $0
+
+ ${NSD_CreateRadioButton} 30u 35u -30u 12u "Normal Installation (recommended)"
+ Pop $InstallTypeRadioNormal
+
+ ${NSD_CreateLabel} 44u 49u -44u 20u "Installs to your system with Start Menu shortcuts, uninstaller, and auto-update support."
+ Pop $0
+
+ ${NSD_CreateRadioButton} 30u 75u -30u 12u "Portable Installation"
+ Pop $InstallTypeRadioPortable
+
+ ${NSD_CreateLabel} 44u 89u -44u 20u "Self-contained folder with no registry changes, shortcuts, or uninstaller. Data stored next to the app."
+ Pop $0
+
+ ; Pre-select based on current state
+ ${If} $PortableMode = 1
+ ${NSD_Check} $InstallTypeRadioPortable
+ ${Else}
+ ${NSD_Check} $InstallTypeRadioNormal
+ ${EndIf}
+
+ nsDialogs::Show
+FunctionEnd
+
+Function PageLeaveInstallType
+ ${NSD_GetState} $InstallTypeRadioPortable $0
+ ${If} $0 = ${BST_CHECKED}
+ StrCpy $PortableMode 1
+ ; --- PORTABLE MODE --- Switch default directory to Desktop\Handy for portable
+ ${If} $INSTDIR == "${PLACEHOLDER_INSTALL_DIR}"
+ ${OrIf} $INSTDIR == "$LOCALAPPDATA\${PRODUCTNAME}"
+ StrCpy $INSTDIR "$DESKTOP\${PRODUCTNAME}"
+ ${EndIf}
+ ${Else}
+ StrCpy $PortableMode 0
+ ; Restore normal default if user switched back from portable
+ ${If} $INSTDIR == "$DESKTOP\${PRODUCTNAME}"
+ StrCpy $INSTDIR "$LOCALAPPDATA\${PRODUCTNAME}"
+ ${EndIf}
+ ${EndIf}
+FunctionEnd
+; --- END PORTABLE MODE ---
+
+; 5. (was 4) Custom page to ask user if he wants to reinstall/uninstall
+; only if a previous installation was detected
+Var ReinstallPageCheck
+Page custom PageReinstall PageLeaveReinstall
+Function PageReinstall
+ ; --- PORTABLE MODE --- Skip reinstall page for portable installs
+ ${If} $PortableMode = 1
+ Abort
+ ${EndIf}
+
+ ; Uninstall previous WiX installation if exists.
+ ;
+ ; A WiX installer stores the installation info in registry
+ ; using a UUID and so we have to loop through all keys under
+ ; `HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall`
+ ; and check if `DisplayName` and `Publisher` keys match ${PRODUCTNAME} and ${MANUFACTURER}
+ ;
+ ; This has a potential issue that there maybe another installation that matches
+ ; our ${PRODUCTNAME} and ${MANUFACTURER} but wasn't installed by our WiX installer,
+ ; however, this should be fine since the user will have to confirm the uninstallation
+ ; and they can chose to abort it if doesn't make sense.
+ StrCpy $0 0
+ wix_loop:
+ EnumRegKey $1 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" $0
+ StrCmp $1 "" wix_loop_done ; Exit loop if there is no more keys to loop on
+ IntOp $0 $0 + 1
+ ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$1" "DisplayName"
+ ReadRegStr $R1 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$1" "Publisher"
+ StrCmp "$R0$R1" "${PRODUCTNAME}${MANUFACTURER}" 0 wix_loop
+ ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$1" "UninstallString"
+ ${StrCase} $R1 $R0 "L"
+ ${StrLoc} $R0 $R1 "msiexec" ">"
+ StrCmp $R0 0 0 wix_loop_done
+ StrCpy $WixMode 1
+ StrCpy $R6 "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\$1"
+ Goto compare_version
+ wix_loop_done:
+
+ ; Check if there is an existing installation, if not, abort the reinstall page
+ ReadRegStr $R0 SHCTX "${UNINSTKEY}" ""
+ ReadRegStr $R1 SHCTX "${UNINSTKEY}" "UninstallString"
+ ${IfThen} "$R0$R1" == "" ${|} Abort ${|}
+
+ ; Compare this installar version with the existing installation
+ ; and modify the messages presented to the user accordingly
+ compare_version:
+ StrCpy $R4 "$(older)"
+ ${If} $WixMode = 1
+ ReadRegStr $R0 HKLM "$R6" "DisplayVersion"
+ ${Else}
+ ReadRegStr $R0 SHCTX "${UNINSTKEY}" "DisplayVersion"
+ ${EndIf}
+ ${IfThen} $R0 == "" ${|} StrCpy $R4 "$(unknown)" ${|}
+
+ nsis_tauri_utils::SemverCompare "${VERSION}" $R0
+ Pop $R0
+ ; Reinstalling the same version
+ ${If} $R0 = 0
+ StrCpy $R1 "$(alreadyInstalledLong)"
+ StrCpy $R2 "$(addOrReinstall)"
+ StrCpy $R3 "$(uninstallApp)"
+ !insertmacro MUI_HEADER_TEXT "$(alreadyInstalled)" "$(chooseMaintenanceOption)"
+ ; Upgrading
+ ${ElseIf} $R0 = 1
+ StrCpy $R1 "$(olderOrUnknownVersionInstalled)"
+ StrCpy $R2 "$(uninstallBeforeInstalling)"
+ StrCpy $R3 "$(dontUninstall)"
+ !insertmacro MUI_HEADER_TEXT "$(alreadyInstalled)" "$(choowHowToInstall)"
+ ; Downgrading
+ ${ElseIf} $R0 = -1
+ StrCpy $R1 "$(newerVersionInstalled)"
+ StrCpy $R2 "$(uninstallBeforeInstalling)"
+ !if "${ALLOWDOWNGRADES}" == "true"
+ StrCpy $R3 "$(dontUninstall)"
+ !else
+ StrCpy $R3 "$(dontUninstallDowngrade)"
+ !endif
+ !insertmacro MUI_HEADER_TEXT "$(alreadyInstalled)" "$(choowHowToInstall)"
+ ${Else}
+ Abort
+ ${EndIf}
+
+ ; Skip showing the page if passive
+ ;
+ ; Note that we don't call this earlier at the begining
+ ; of this function because we need to populate some variables
+ ; related to current installed version if detected and whether
+ ; we are downgrading or not.
+ ${If} $PassiveMode = 1
+ Call PageLeaveReinstall
+ ${Else}
+ nsDialogs::Create 1018
+ Pop $R4
+ ${IfThen} $(^RTL) = 1 ${|} nsDialogs::SetRTL $(^RTL) ${|}
+
+ ${NSD_CreateLabel} 0 0 100% 24u $R1
+ Pop $R1
+
+ ${NSD_CreateRadioButton} 30u 50u -30u 8u $R2
+ Pop $R2
+ ${NSD_OnClick} $R2 PageReinstallUpdateSelection
+
+ ${NSD_CreateRadioButton} 30u 70u -30u 8u $R3
+ Pop $R3
+ ; Disable this radio button if downgrading and downgrades are disabled
+ !if "${ALLOWDOWNGRADES}" == "false"
+ ${IfThen} $R0 = -1 ${|} EnableWindow $R3 0 ${|}
+ !endif
+ ${NSD_OnClick} $R3 PageReinstallUpdateSelection
+
+ ; Check the first radio button if this the first time
+ ; we enter this page or if the second button wasn't
+ ; selected the last time we were on this page
+ ${If} $ReinstallPageCheck <> 2
+ SendMessage $R2 ${BM_SETCHECK} ${BST_CHECKED} 0
+ ${Else}
+ SendMessage $R3 ${BM_SETCHECK} ${BST_CHECKED} 0
+ ${EndIf}
+
+ ${NSD_SetFocus} $R2
+ nsDialogs::Show
+ ${EndIf}
+FunctionEnd
+Function PageReinstallUpdateSelection
+ ${NSD_GetState} $R2 $R1
+ ${If} $R1 == ${BST_CHECKED}
+ StrCpy $ReinstallPageCheck 1
+ ${Else}
+ StrCpy $ReinstallPageCheck 2
+ ${EndIf}
+FunctionEnd
+Function PageLeaveReinstall
+ ${NSD_GetState} $R2 $R1
+
+ ; If migrating from Wix, always uninstall
+ ${If} $WixMode = 1
+ Goto reinst_uninstall
+ ${EndIf}
+
+ ; In update mode, always proceeds without uninstalling
+ ${If} $UpdateMode = 1
+ Goto reinst_done
+ ${EndIf}
+
+ ; $R0 holds whether same(0)/upgrading(1)/downgrading(-1) version
+ ; $R1 holds the radio buttons state:
+ ; 1 => first choice was selected
+ ; 0 => second choice was selected
+ ${If} $R0 = 0 ; Same version, proceed
+ ${If} $R1 = 1 ; User chose to add/reinstall
+ Goto reinst_done
+ ${Else} ; User chose to uninstall
+ Goto reinst_uninstall
+ ${EndIf}
+ ${ElseIf} $R0 = 1 ; Upgrading
+ ${If} $R1 = 1 ; User chose to uninstall
+ Goto reinst_uninstall
+ ${Else}
+ Goto reinst_done ; User chose NOT to uninstall
+ ${EndIf}
+ ${ElseIf} $R0 = -1 ; Downgrading
+ ${If} $R1 = 1 ; User chose to uninstall
+ Goto reinst_uninstall
+ ${Else}
+ Goto reinst_done ; User chose NOT to uninstall
+ ${EndIf}
+ ${EndIf}
+
+ reinst_uninstall:
+ HideWindow
+ ClearErrors
+
+ ${If} $WixMode = 1
+ ReadRegStr $R1 HKLM "$R6" "UninstallString"
+ ExecWait '$R1' $0
+ ${Else}
+ ReadRegStr $4 SHCTX "${MANUPRODUCTKEY}" ""
+ ReadRegStr $R1 SHCTX "${UNINSTKEY}" "UninstallString"
+ ${IfThen} $UpdateMode = 1 ${|} StrCpy $R1 "$R1 /UPDATE" ${|} ; append /UPDATE
+ ${IfThen} $PassiveMode = 1 ${|} StrCpy $R1 "$R1 /P" ${|} ; append /P
+ StrCpy $R1 "$R1 _?=$4" ; append uninstall directory
+ ExecWait '$R1' $0
+ ${EndIf}
+
+ BringToFront
+
+ ${IfThen} ${Errors} ${|} StrCpy $0 2 ${|} ; ExecWait failed, set fake exit code
+
+ ${If} $0 <> 0
+ ${OrIf} ${FileExists} "$INSTDIR\${MAINBINARYNAME}.exe"
+ ; User cancelled wix uninstaller? return to select un/reinstall page
+ ${If} $WixMode = 1
+ ${AndIf} $0 = 1602
+ Abort
+ ${EndIf}
+
+ ; User cancelled NSIS uninstaller? return to select un/reinstall page
+ ${If} $0 = 1
+ Abort
+ ${EndIf}
+
+ ; Other erros? show generic error message and return to select un/reinstall page
+ MessageBox MB_ICONEXCLAMATION "$(unableToUninstall)"
+ Abort
+ ${EndIf}
+ reinst_done:
+FunctionEnd
+
+; 5. Choose install directory page
+!define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassive
+!insertmacro MUI_PAGE_DIRECTORY
+
+; 6. Start menu shortcut page
+Var AppStartMenuFolder
+!if "${STARTMENUFOLDER}" != ""
+ ; --- PORTABLE MODE --- Also skip start menu page for portable installs
+ !define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassiveOrPortable
+ !define MUI_STARTMENUPAGE_DEFAULTFOLDER "${STARTMENUFOLDER}"
+!else
+ !define MUI_PAGE_CUSTOMFUNCTION_PRE Skip
+!endif
+!insertmacro MUI_PAGE_STARTMENU Application $AppStartMenuFolder
+
+; 7. Installation page
+!insertmacro MUI_PAGE_INSTFILES
+
+; 8. Finish page
+;
+; Don't auto jump to finish page after installation page,
+; because the installation page has useful info that can be used debug any issues with the installer.
+!define MUI_FINISHPAGE_NOAUTOCLOSE
+; Use show readme button in the finish page as a button create a desktop shortcut
+!define MUI_FINISHPAGE_SHOWREADME
+!define MUI_FINISHPAGE_SHOWREADME_TEXT "$(createDesktop)"
+!define MUI_FINISHPAGE_SHOWREADME_FUNCTION CreateOrUpdateDesktopShortcut
+; Show run app after installation.
+!define MUI_FINISHPAGE_RUN
+!define MUI_FINISHPAGE_RUN_FUNCTION RunMainBinary
+!define MUI_PAGE_CUSTOMFUNCTION_PRE SkipIfPassive
+!insertmacro MUI_PAGE_FINISH
+
+Function RunMainBinary
+ nsis_tauri_utils::RunAsUser "$INSTDIR\${MAINBINARYNAME}.exe" ""
+FunctionEnd
+
+; Uninstaller Pages
+; 1. Confirm uninstall page
+Var DeleteAppDataCheckbox
+Var DeleteAppDataCheckboxState
+!define /ifndef WS_EX_LAYOUTRTL 0x00400000
+!define MUI_PAGE_CUSTOMFUNCTION_SHOW un.ConfirmShow
+Function un.ConfirmShow ; Add add a `Delete app data` check box
+ ; $1 inner dialog HWND
+ ; $2 window DPI
+ ; $3 style
+ ; $4 x
+ ; $5 y
+ ; $6 width
+ ; $7 height
+ FindWindow $1 "#32770" "" $HWNDPARENT ; Find inner dialog
+ System::Call "user32::GetDpiForWindow(p r1) i .r2"
+ ${If} $(^RTL) = 1
+ StrCpy $3 "${__NSD_CheckBox_EXSTYLE} | ${WS_EX_LAYOUTRTL}"
+ IntOp $4 50 * $2
+ ${Else}
+ StrCpy $3 "${__NSD_CheckBox_EXSTYLE}"
+ IntOp $4 0 * $2
+ ${EndIf}
+ IntOp $5 100 * $2
+ IntOp $6 400 * $2
+ IntOp $7 25 * $2
+ IntOp $4 $4 / 96
+ IntOp $5 $5 / 96
+ IntOp $6 $6 / 96
+ IntOp $7 $7 / 96
+ System::Call 'user32::CreateWindowEx(i r3, w "${__NSD_CheckBox_CLASS}", w "$(deleteAppData)", i ${__NSD_CheckBox_STYLE}, i r4, i r5, i r6, i r7, p r1, i0, i0, i0) i .s'
+ Pop $DeleteAppDataCheckbox
+ SendMessage $HWNDPARENT ${WM_GETFONT} 0 0 $1
+ SendMessage $DeleteAppDataCheckbox ${WM_SETFONT} $1 1
+FunctionEnd
+!define MUI_PAGE_CUSTOMFUNCTION_LEAVE un.ConfirmLeave
+Function un.ConfirmLeave
+ SendMessage $DeleteAppDataCheckbox ${BM_GETCHECK} 0 0 $DeleteAppDataCheckboxState
+FunctionEnd
+!define MUI_PAGE_CUSTOMFUNCTION_PRE un.SkipIfPassive
+!insertmacro MUI_UNPAGE_CONFIRM
+
+; 2. Uninstalling Page
+!insertmacro MUI_UNPAGE_INSTFILES
+
+;Languages
+{{#each languages}}
+!insertmacro MUI_LANGUAGE "{{this}}"
+{{/each}}
+!insertmacro MUI_RESERVEFILE_LANGDLL
+{{#each language_files}}
+ !include "{{this}}"
+{{/each}}
+
+Function .onInit
+ ${GetOptions} $CMDLINE "/P" $PassiveMode
+ ${IfNot} ${Errors}
+ StrCpy $PassiveMode 1
+ ${EndIf}
+
+ ${GetOptions} $CMDLINE "/NS" $NoShortcutMode
+ ${IfNot} ${Errors}
+ StrCpy $NoShortcutMode 1
+ ${EndIf}
+
+ ${GetOptions} $CMDLINE "/UPDATE" $UpdateMode
+ ${IfNot} ${Errors}
+ StrCpy $UpdateMode 1
+ ${EndIf}
+
+ ; --- PORTABLE MODE --- Parse /PORTABLE flag for silent/passive installs
+ ${GetOptions} $CMDLINE "/PORTABLE" $PortableMode
+ ${IfNot} ${Errors}
+ StrCpy $PortableMode 1
+ ${EndIf}
+
+ !if "${DISPLAYLANGUAGESELECTOR}" == "true"
+ !insertmacro MUI_LANGDLL_DISPLAY
+ !endif
+
+ !insertmacro SetContext
+
+ ${If} $INSTDIR == "${PLACEHOLDER_INSTALL_DIR}"
+ ; Set default install location
+ !if "${INSTALLMODE}" == "perMachine"
+ ${If} ${RunningX64}
+ !if "${ARCH}" == "x64"
+ StrCpy $INSTDIR "$PROGRAMFILES64\${PRODUCTNAME}"
+ !else if "${ARCH}" == "arm64"
+ StrCpy $INSTDIR "$PROGRAMFILES64\${PRODUCTNAME}"
+ !else
+ StrCpy $INSTDIR "$PROGRAMFILES\${PRODUCTNAME}"
+ !endif
+ ${Else}
+ StrCpy $INSTDIR "$PROGRAMFILES\${PRODUCTNAME}"
+ ${EndIf}
+ !else if "${INSTALLMODE}" == "currentUser"
+ StrCpy $INSTDIR "$LOCALAPPDATA\${PRODUCTNAME}"
+ !endif
+
+ ; --- PORTABLE MODE --- Override default dir for silent/passive portable installs
+ ${If} $PortableMode = 1
+ StrCpy $INSTDIR "$DESKTOP\${PRODUCTNAME}"
+ ${Else}
+ Call RestorePreviousInstallLocation
+ ${EndIf}
+ ${EndIf}
+
+
+ ; --- PORTABLE MODE --- Auto-detect portable mode during updates.
+ ; If the target directory already has a portable marker file, preserve
+ ; portable mode so the Tauri updater works without needing /PORTABLE.
+ ${If} $PortableMode <> 1
+ ${AndIf} ${FileExists} "$INSTDIR\portable"
+ StrCpy $PortableMode 1
+ ${EndIf}
+
+ !if "${INSTALLMODE}" == "both"
+ !insertmacro MULTIUSER_INIT
+ !endif
+FunctionEnd
+
+
+Section EarlyChecks
+ ; Abort silent installer if downgrades is disabled
+ !if "${ALLOWDOWNGRADES}" == "false"
+ ${If} ${Silent}
+ ; If downgrading
+ ${If} $R0 = -1
+ System::Call 'kernel32::AttachConsole(i -1)i.r0'
+ ${If} $0 <> 0
+ System::Call 'kernel32::GetStdHandle(i -11)i.r0'
+ System::call 'kernel32::SetConsoleTextAttribute(i r0, i 0x0004)' ; set red color
+ FileWrite $0 "$(silentDowngrades)"
+ ${EndIf}
+ Abort
+ ${EndIf}
+ ${EndIf}
+ !endif
+
+SectionEnd
+
+Section WebView2
+ ; Check if Webview2 is already installed and skip this section
+ ${If} ${RunningX64}
+ ReadRegStr $4 HKLM "SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate\Clients\${WEBVIEW2APPGUID}" "pv"
+ ${Else}
+ ReadRegStr $4 HKLM "SOFTWARE\Microsoft\EdgeUpdate\Clients\${WEBVIEW2APPGUID}" "pv"
+ ${EndIf}
+ ${If} $4 == ""
+ ReadRegStr $4 HKCU "SOFTWARE\Microsoft\EdgeUpdate\Clients\${WEBVIEW2APPGUID}" "pv"
+ ${EndIf}
+
+ ${If} $4 == ""
+ ; Webview2 installation
+ ;
+ ; Skip if updating
+ ${If} $UpdateMode <> 1
+ !if "${INSTALLWEBVIEW2MODE}" == "downloadBootstrapper"
+ Delete "$TEMP\MicrosoftEdgeWebview2Setup.exe"
+ DetailPrint "$(webview2Downloading)"
+ NSISdl::download "https://go.microsoft.com/fwlink/p/?LinkId=2124703" "$TEMP\MicrosoftEdgeWebview2Setup.exe"
+ Pop $0
+ ${If} $0 == "success"
+ DetailPrint "$(webview2DownloadSuccess)"
+ ${Else}
+ DetailPrint "$(webview2DownloadError)"
+ Abort "$(webview2AbortError)"
+ ${EndIf}
+ StrCpy $6 "$TEMP\MicrosoftEdgeWebview2Setup.exe"
+ Goto install_webview2
+ !endif
+
+ !if "${INSTALLWEBVIEW2MODE}" == "embedBootstrapper"
+ Delete "$TEMP\MicrosoftEdgeWebview2Setup.exe"
+ File "/oname=$TEMP\MicrosoftEdgeWebview2Setup.exe" "${WEBVIEW2BOOTSTRAPPERPATH}"
+ DetailPrint "$(installingWebview2)"
+ StrCpy $6 "$TEMP\MicrosoftEdgeWebview2Setup.exe"
+ Goto install_webview2
+ !endif
+
+ !if "${INSTALLWEBVIEW2MODE}" == "offlineInstaller"
+ Delete "$TEMP\MicrosoftEdgeWebView2RuntimeInstaller.exe"
+ File "/oname=$TEMP\MicrosoftEdgeWebView2RuntimeInstaller.exe" "${WEBVIEW2INSTALLERPATH}"
+ DetailPrint "$(installingWebview2)"
+ StrCpy $6 "$TEMP\MicrosoftEdgeWebView2RuntimeInstaller.exe"
+ Goto install_webview2
+ !endif
+
+ Goto webview2_done
+
+ install_webview2:
+ DetailPrint "$(installingWebview2)"
+ ; $6 holds the path to the webview2 installer
+ ExecWait "$6 ${WEBVIEW2INSTALLERARGS} /install" $1
+ ${If} $1 = 0
+ DetailPrint "$(webview2InstallSuccess)"
+ ${Else}
+ DetailPrint "$(webview2InstallError)"
+ Abort "$(webview2AbortError)"
+ ${EndIf}
+ webview2_done:
+ ${EndIf}
+ ${Else}
+ !if "${MINIMUMWEBVIEW2VERSION}" != ""
+ ${VersionCompare} "${MINIMUMWEBVIEW2VERSION}" "$4" $R0
+ ${If} $R0 = 1
+ update_webview:
+ DetailPrint "$(installingWebview2)"
+ ${If} ${RunningX64}
+ ReadRegStr $R1 HKLM "SOFTWARE\WOW6432Node\Microsoft\EdgeUpdate" "path"
+ ${Else}
+ ReadRegStr $R1 HKLM "SOFTWARE\Microsoft\EdgeUpdate" "path"
+ ${EndIf}
+ ${If} $R1 == ""
+ ReadRegStr $R1 HKCU "SOFTWARE\Microsoft\EdgeUpdate" "path"
+ ${EndIf}
+ ${If} $R1 != ""
+ ; Chromium updater docs: https://source.chromium.org/chromium/chromium/src/+/main:docs/updater/user_manual.md
+ ; Modified from "HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Microsoft EdgeWebView\ModifyPath"
+ ExecWait `"$R1" /install appguid=${WEBVIEW2APPGUID}&needsadmin=true` $1
+ ${If} $1 = 0
+ DetailPrint "$(webview2InstallSuccess)"
+ ${Else}
+ MessageBox MB_ICONEXCLAMATION|MB_ABORTRETRYIGNORE "$(webview2InstallError)" IDIGNORE ignore IDRETRY update_webview
+ Quit
+ ignore:
+ ${EndIf}
+ ${EndIf}
+ ${EndIf}
+ !endif
+ ${EndIf}
+SectionEnd
+
+Section Install
+ SetOutPath $INSTDIR
+
+ !ifmacrodef NSIS_HOOK_PREINSTALL
+ !insertmacro NSIS_HOOK_PREINSTALL
+ !endif
+
+ !insertmacro CheckIfAppIsRunning "${MAINBINARYNAME}.exe" "${PRODUCTNAME}"
+
+ ; Copy main executable
+ File "${MAINBINARYSRCPATH}"
+
+ ; Copy resources
+ {{#each resources_dirs}}
+ CreateDirectory "$INSTDIR\\{{this}}"
+ {{/each}}
+ {{#each resources}}
+ File /a "/oname={{this.[1]}}" "{{no-escape @key}}"
+ {{/each}}
+
+ ; Copy external binaries
+ {{#each binaries}}
+ File /a "/oname={{this}}" "{{no-escape @key}}"
+ {{/each}}
+
+ ; --- PORTABLE MODE --- Skip file associations and deep links for portable installs
+ ${If} $PortableMode <> 1
+ ; Create file associations
+ {{#each file_associations as |association| ~}}
+ {{#each association.ext as |ext| ~}}
+ !insertmacro APP_ASSOCIATE "{{ext}}" "{{or association.name ext}}" "{{association-description association.description ext}}" "$INSTDIR\${MAINBINARYNAME}.exe,0" "Open with ${PRODUCTNAME}" "$INSTDIR\${MAINBINARYNAME}.exe $\"%1$\""
+ {{/each}}
+ {{/each}}
+
+ ; Register deep links
+ {{#each deep_link_protocols as |protocol| ~}}
+ WriteRegStr SHCTX "Software\Classes\\{{protocol}}" "URL Protocol" ""
+ WriteRegStr SHCTX "Software\Classes\\{{protocol}}" "" "URL:${BUNDLEID} protocol"
+ WriteRegStr SHCTX "Software\Classes\\{{protocol}}\DefaultIcon" "" "$\"$INSTDIR\${MAINBINARYNAME}.exe$\",0"
+ WriteRegStr SHCTX "Software\Classes\\{{protocol}}\shell\open\command" "" "$\"$INSTDIR\${MAINBINARYNAME}.exe$\" $\"%1$\""
+ {{/each}}
+ ${EndIf}
+
+ ; --- PORTABLE MODE --- Create portable marker and Data directory
+ ${If} $PortableMode = 1
+ FileOpen $0 "$INSTDIR\portable" w
+ FileClose $0
+ CreateDirectory "$INSTDIR\Data"
+ DetailPrint "Portable mode: created marker file and Data directory."
+ ${EndIf}
+
+ ; --- PORTABLE MODE --- Skip uninstaller, registry, and shortcuts for portable installs
+ ${If} $PortableMode <> 1
+ ; Create uninstaller
+ WriteUninstaller "$INSTDIR\uninstall.exe"
+
+ ; Save $INSTDIR in registry for future installations
+ WriteRegStr SHCTX "${MANUPRODUCTKEY}" "" $INSTDIR
+
+ !if "${INSTALLMODE}" == "both"
+ ; Save install mode to be selected by default for the next installation such as updating
+ ; or when uninstalling
+ WriteRegStr SHCTX "${UNINSTKEY}" $MultiUser.InstallMode 1
+ !endif
+
+ ; Remove old main binary if it doesn't match new main binary name
+ ReadRegStr $OldMainBinaryName SHCTX "${UNINSTKEY}" "MainBinaryName"
+ ${If} $OldMainBinaryName != ""
+ ${AndIf} $OldMainBinaryName != "${MAINBINARYNAME}.exe"
+ Delete "$INSTDIR\$OldMainBinaryName"
+ ${EndIf}
+
+ ; Save current MAINBINARYNAME for future updates
+ WriteRegStr SHCTX "${UNINSTKEY}" "MainBinaryName" "${MAINBINARYNAME}.exe"
+
+ ; Registry information for add/remove programs
+ WriteRegStr SHCTX "${UNINSTKEY}" "DisplayName" "${PRODUCTNAME}"
+ WriteRegStr SHCTX "${UNINSTKEY}" "DisplayIcon" "$\"$INSTDIR\${MAINBINARYNAME}.exe$\""
+ WriteRegStr SHCTX "${UNINSTKEY}" "DisplayVersion" "${VERSION}"
+ WriteRegStr SHCTX "${UNINSTKEY}" "Publisher" "${MANUFACTURER}"
+ WriteRegStr SHCTX "${UNINSTKEY}" "InstallLocation" "$\"$INSTDIR$\""
+ WriteRegStr SHCTX "${UNINSTKEY}" "UninstallString" "$\"$INSTDIR\uninstall.exe$\""
+ WriteRegDWORD SHCTX "${UNINSTKEY}" "NoModify" "1"
+ WriteRegDWORD SHCTX "${UNINSTKEY}" "NoRepair" "1"
+
+ ${GetSize} "$INSTDIR" "/M=uninstall.exe /S=0K /G=0" $0 $1 $2
+ IntOp $0 $0 + ${ESTIMATEDSIZE}
+ IntFmt $0 "0x%08X" $0
+ WriteRegDWORD SHCTX "${UNINSTKEY}" "EstimatedSize" "$0"
+
+ !if "${HOMEPAGE}" != ""
+ WriteRegStr SHCTX "${UNINSTKEY}" "URLInfoAbout" "${HOMEPAGE}"
+ WriteRegStr SHCTX "${UNINSTKEY}" "URLUpdateInfo" "${HOMEPAGE}"
+ WriteRegStr SHCTX "${UNINSTKEY}" "HelpLink" "${HOMEPAGE}"
+ !endif
+
+ ; Create start menu shortcut
+ !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
+ Call CreateOrUpdateStartMenuShortcut
+ !insertmacro MUI_STARTMENU_WRITE_END
+
+ ; Create desktop shortcut for silent and passive installers
+ ; because finish page will be skipped
+ ${If} $PassiveMode = 1
+ ${OrIf} ${Silent}
+ Call CreateOrUpdateDesktopShortcut
+ ${EndIf}
+ ${EndIf} ; --- END PORTABLE MODE guard ---
+
+ !ifmacrodef NSIS_HOOK_POSTINSTALL
+ !insertmacro NSIS_HOOK_POSTINSTALL
+ !endif
+
+ ; Auto close this page for passive mode
+ ${If} $PassiveMode = 1
+ SetAutoClose true
+ ${EndIf}
+SectionEnd
+
+Function .onInstSuccess
+ ; Check for `/R` flag only in silent and passive installers because
+ ; GUI installer has a toggle for the user to (re)start the app
+ ${If} $PassiveMode = 1
+ ${OrIf} ${Silent}
+ ${GetOptions} $CMDLINE "/R" $R0
+ ${IfNot} ${Errors}
+ ${GetOptions} $CMDLINE "/ARGS" $R0
+ nsis_tauri_utils::RunAsUser "$INSTDIR\${MAINBINARYNAME}.exe" "$R0"
+ ${EndIf}
+ ${EndIf}
+FunctionEnd
+
+Function un.onInit
+ !insertmacro SetContext
+
+ !if "${INSTALLMODE}" == "both"
+ !insertmacro MULTIUSER_UNINIT
+ !endif
+
+ !insertmacro MUI_UNGETLANGUAGE
+
+ ${GetOptions} $CMDLINE "/P" $PassiveMode
+ ${IfNot} ${Errors}
+ StrCpy $PassiveMode 1
+ ${EndIf}
+
+ ${GetOptions} $CMDLINE "/UPDATE" $UpdateMode
+ ${IfNot} ${Errors}
+ StrCpy $UpdateMode 1
+ ${EndIf}
+FunctionEnd
+
+Section Uninstall
+
+ !ifmacrodef NSIS_HOOK_PREUNINSTALL
+ !insertmacro NSIS_HOOK_PREUNINSTALL
+ !endif
+
+ !insertmacro CheckIfAppIsRunning "${MAINBINARYNAME}.exe" "${PRODUCTNAME}"
+
+ ; Delete the app directory and its content from disk
+ ; Copy main executable
+ Delete "$INSTDIR\${MAINBINARYNAME}.exe"
+
+ ; Delete resources
+ {{#each resources}}
+ Delete "$INSTDIR\\{{this.[1]}}"
+ {{/each}}
+
+ ; Delete external binaries
+ {{#each binaries}}
+ Delete "$INSTDIR\\{{this}}"
+ {{/each}}
+
+ ; Delete app associations
+ {{#each file_associations as |association| ~}}
+ {{#each association.ext as |ext| ~}}
+ !insertmacro APP_UNASSOCIATE "{{ext}}" "{{or association.name ext}}"
+ {{/each}}
+ {{/each}}
+
+ ; Delete deep links
+ {{#each deep_link_protocols as |protocol| ~}}
+ ReadRegStr $R7 SHCTX "Software\Classes\\{{protocol}}\shell\open\command" ""
+ ${If} $R7 == "$\"$INSTDIR\${MAINBINARYNAME}.exe$\" $\"%1$\""
+ DeleteRegKey SHCTX "Software\Classes\\{{protocol}}"
+ ${EndIf}
+ {{/each}}
+
+
+ ; Delete uninstaller
+ Delete "$INSTDIR\uninstall.exe"
+
+ {{#each resources_ancestors}}
+ RMDir /REBOOTOK "$INSTDIR\\{{this}}"
+ {{/each}}
+ RMDir "$INSTDIR"
+
+ ; Remove shortcuts if not updating
+ ${If} $UpdateMode <> 1
+ !insertmacro DeleteAppUserModelId
+
+ ; Remove start menu shortcut
+ !insertmacro MUI_STARTMENU_GETFOLDER Application $AppStartMenuFolder
+ !insertmacro IsShortcutTarget "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro UnpinShortcut "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk"
+ Delete "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk"
+ RMDir "$SMPROGRAMS\$AppStartMenuFolder"
+ ${EndIf}
+ !insertmacro IsShortcutTarget "$SMPROGRAMS\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro UnpinShortcut "$SMPROGRAMS\${PRODUCTNAME}.lnk"
+ Delete "$SMPROGRAMS\${PRODUCTNAME}.lnk"
+ ${EndIf}
+
+ ; Remove desktop shortcuts
+ !insertmacro IsShortcutTarget "$DESKTOP\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro UnpinShortcut "$DESKTOP\${PRODUCTNAME}.lnk"
+ Delete "$DESKTOP\${PRODUCTNAME}.lnk"
+ ${EndIf}
+ ${EndIf}
+
+ ; Remove registry information for add/remove programs
+ !if "${INSTALLMODE}" == "both"
+ DeleteRegKey SHCTX "${UNINSTKEY}"
+ !else if "${INSTALLMODE}" == "perMachine"
+ DeleteRegKey HKLM "${UNINSTKEY}"
+ !else
+ DeleteRegKey HKCU "${UNINSTKEY}"
+ !endif
+
+ ; Removes the Autostart entry for ${PRODUCTNAME} from the HKCU Run key if it exists.
+ ; This ensures the program does not launch automatically after uninstallation if it exists.
+ ; If it doesn't exist, it does nothing.
+ ; We do this when not updating (to preserve the registry value on updates)
+ ${If} $UpdateMode <> 1
+ DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "${PRODUCTNAME}"
+ ${EndIf}
+
+ ; Delete app data if the checkbox is selected
+ ; and if not updating
+ ${If} $DeleteAppDataCheckboxState = 1
+ ${AndIf} $UpdateMode <> 1
+ ; Clear the install location $INSTDIR from registry
+ DeleteRegKey SHCTX "${MANUPRODUCTKEY}"
+ DeleteRegKey /ifempty SHCTX "${MANUKEY}"
+
+ ; Clear the install language from registry
+ DeleteRegValue HKCU "${MANUPRODUCTKEY}" "Installer Language"
+ DeleteRegKey /ifempty HKCU "${MANUPRODUCTKEY}"
+ DeleteRegKey /ifempty HKCU "${MANUKEY}"
+
+ SetShellVarContext current
+ RmDir /r "$APPDATA\${BUNDLEID}"
+ RmDir /r "$LOCALAPPDATA\${BUNDLEID}"
+ ${EndIf}
+
+ !ifmacrodef NSIS_HOOK_POSTUNINSTALL
+ !insertmacro NSIS_HOOK_POSTUNINSTALL
+ !endif
+
+ ; Auto close if passive mode or updating
+ ${If} $PassiveMode = 1
+ ${OrIf} $UpdateMode = 1
+ SetAutoClose true
+ ${EndIf}
+SectionEnd
+
+Function RestorePreviousInstallLocation
+ ReadRegStr $4 SHCTX "${MANUPRODUCTKEY}" ""
+ StrCmp $4 "" +2 0
+ StrCpy $INSTDIR $4
+FunctionEnd
+
+Function Skip
+ Abort
+FunctionEnd
+
+Function SkipIfPassive
+ ${IfThen} $PassiveMode = 1 ${|} Abort ${|}
+FunctionEnd
+
+; --- PORTABLE MODE ---
+Function SkipIfPassiveOrPortable
+ ${IfThen} $PassiveMode = 1 ${|} Abort ${|}
+ ${IfThen} $PortableMode = 1 ${|} Abort ${|}
+FunctionEnd
+Function un.SkipIfPassive
+ ${IfThen} $PassiveMode = 1 ${|} Abort ${|}
+FunctionEnd
+
+Function CreateOrUpdateStartMenuShortcut
+ ; We used to use product name as MAINBINARYNAME
+ ; migrate old shortcuts to target the new MAINBINARYNAME
+ StrCpy $R0 0
+
+ !insertmacro IsShortcutTarget "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk" "$INSTDIR\$OldMainBinaryName"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro SetShortcutTarget "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ StrCpy $R0 1
+ ${EndIf}
+
+ !insertmacro IsShortcutTarget "$SMPROGRAMS\${PRODUCTNAME}.lnk" "$INSTDIR\$OldMainBinaryName"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro SetShortcutTarget "$SMPROGRAMS\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ StrCpy $R0 1
+ ${EndIf}
+
+ ${If} $R0 = 1
+ Return
+ ${EndIf}
+
+ ; Skip creating shortcut if in update mode or no shortcut mode
+ ; but always create if migrating from wix
+ ${If} $WixMode = 0
+ ${If} $UpdateMode = 1
+ ${OrIf} $NoShortcutMode = 1
+ Return
+ ${EndIf}
+ ${EndIf}
+
+ !if "${STARTMENUFOLDER}" != ""
+ CreateDirectory "$SMPROGRAMS\$AppStartMenuFolder"
+ CreateShortcut "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ !insertmacro SetLnkAppUserModelId "$SMPROGRAMS\$AppStartMenuFolder\${PRODUCTNAME}.lnk"
+ !else
+ CreateShortcut "$SMPROGRAMS\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ !insertmacro SetLnkAppUserModelId "$SMPROGRAMS\${PRODUCTNAME}.lnk"
+ !endif
+FunctionEnd
+
+Function CreateOrUpdateDesktopShortcut
+ ; --- PORTABLE MODE --- No desktop shortcut for portable installs
+ ${If} $PortableMode = 1
+ Return
+ ${EndIf}
+
+ ; We used to use product name as MAINBINARYNAME
+ ; migrate old shortcuts to target the new MAINBINARYNAME
+ !insertmacro IsShortcutTarget "$DESKTOP\${PRODUCTNAME}.lnk" "$INSTDIR\$OldMainBinaryName"
+ Pop $0
+ ${If} $0 = 1
+ !insertmacro SetShortcutTarget "$DESKTOP\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ Return
+ ${EndIf}
+
+ ; Skip creating shortcut if in update mode or no shortcut mode
+ ; but always create if migrating from wix
+ ${If} $WixMode = 0
+ ${If} $UpdateMode = 1
+ ${OrIf} $NoShortcutMode = 1
+ Return
+ ${EndIf}
+ ${EndIf}
+
+ CreateShortcut "$DESKTOP\${PRODUCTNAME}.lnk" "$INSTDIR\${MAINBINARYNAME}.exe"
+ !insertmacro SetLnkAppUserModelId "$DESKTOP\${PRODUCTNAME}.lnk"
+FunctionEnd
diff --git a/src-tauri/src/audio_feedback.rs b/src-tauri/src/audio_feedback.rs
index c02058ce..ef759a13 100644
--- a/src-tauri/src/audio_feedback.rs
+++ b/src-tauri/src/audio_feedback.rs
@@ -21,7 +21,12 @@ fn resolve_sound_path(
) -> Option<PathBuf> {
let sound_file = get_sound_path(settings, sound_type);
let base_dir = get_sound_base_dir(settings);
- app.path().resolve(&sound_file, base_dir).ok()
+ match base_dir {
+ tauri::path::BaseDirectory::AppData => {
+ crate::portable::resolve_app_data(app, &sound_file).ok()
+ }
+ _ => app.path().resolve(&sound_file, base_dir).ok(),
+ }
}
fn get_sound_path(settings: &AppSettings, sound_type: SoundType) -> String {
diff --git a/src-tauri/src/commands/audio.rs b/src-tauri/src/commands/audio.rs
index 1d135f5d..38a5b7cb 100644
--- a/src-tauri/src/commands/audio.rs
+++ b/src-tauri/src/commands/audio.rs
@@ -15,11 +15,7 @@ pub struct CustomSounds {
}
fn custom_sound_exists(app: &AppHandle, sound_type: &str) -> bool {
- app.path()
- .resolve(
- format!("custom_{}.wav", sound_type),
- tauri::path::BaseDirectory::AppData,
- )
+ crate::portable::resolve_app_data(app, &format!("custom_{}.wav", sound_type))
.map_or(false, |path| path.exists())
}
diff --git a/src-tauri/src/commands/mod.rs b/src-tauri/src/commands/mod.rs
index 015c60bd..415efb06 100644
--- a/src-tauri/src/commands/mod.rs
+++ b/src-tauri/src/commands/mod.rs
@@ -17,9 +17,7 @@ pub fn cancel_operation(app: AppHandle) {
#[tauri::command]
#[specta::specta]
pub fn get_app_dir_path(app: AppHandle) -> Result<String, String> {
- let app_data_dir = app
- .path()
- .app_data_dir()
+ let app_data_dir = crate::portable::app_data_dir(&app)
.map_err(|e| format!("Failed to get app data directory: {}", e))?;
Ok(app_data_dir.to_string_lossy().to_string())
@@ -40,9 +38,7 @@ pub fn get_default_settings() -> Result<AppSettings, String> {
#[tauri::command]
#[specta::specta]
pub fn get_log_dir_path(app: AppHandle) -> Result<String, String> {
- let log_dir = app
- .path()
- .app_log_dir()
+ let log_dir = crate::portable::app_log_dir(&app)
.map_err(|e| format!("Failed to get log directory: {}", e))?;
Ok(log_dir.to_string_lossy().to_string())
@@ -69,9 +65,7 @@ pub fn set_log_level(app: AppHandle, level: LogLevel) -> Result<(), String> {
#[specta::specta]
#[tauri::command]
pub fn open_recordings_folder(app: AppHandle) -> Result<(), String> {
- let app_data_dir = app
- .path()
- .app_data_dir()
+ let app_data_dir = crate::portable::app_data_dir(&app)
.map_err(|e| format!("Failed to get app data directory: {}", e))?;
let recordings_dir = app_data_dir.join("recordings");
@@ -87,9 +81,7 @@ pub fn open_recordings_folder(app: AppHandle) -> Result<(), String> {
#[specta::specta]
#[tauri::command]
pub fn open_log_dir(app: AppHandle) -> Result<(), String> {
- let log_dir = app
- .path()
- .app_log_dir()
+ let log_dir = crate::portable::app_log_dir(&app)
.map_err(|e| format!("Failed to get log directory: {}", e))?;
let path = log_dir.to_string_lossy().as_ref().to_string();
@@ -103,9 +95,7 @@ pub fn open_log_dir(app: AppHandle) -> Result<(), String> {
#[specta::specta]
#[tauri::command]
pub fn open_app_data_dir(app: AppHandle) -> Result<(), String> {
- let app_data_dir = app
- .path()
- .app_data_dir()
+ let app_data_dir = crate::portable::app_data_dir(&app)
.map_err(|e| format!("Failed to get app data directory: {}", e))?;
let path = app_data_dir.to_string_lossy().as_ref().to_string();
diff --git a/src-tauri/src/lib.rs b/src-tauri/src/lib.rs
index dc598372..a9de79d0 100644
--- a/src-tauri/src/lib.rs
+++ b/src-tauri/src/lib.rs
@@ -11,6 +11,7 @@ mod input;
mod llm_client;
mod managers;
mod overlay;
+pub mod portable;
mod settings;
mod shortcut;
mod signal_handle;
@@ -252,6 +253,9 @@ fn trigger_update_check(app: AppHandle) -> Result<(), String> {
#[cfg_attr(mobile, tauri::mobile_entry_point)]
pub fn run(cli_args: CliArgs) {
+ // Detect portable mode before anything else
+ portable::init();
+
// Parse console logging directives from RUST_LOG, falling back to info-level logging
// when the variable is unset
let console_filter = build_console_filter();
@@ -373,8 +377,15 @@ pub fn run(cli_args: CliArgs) {
move |metadata| console_filter.enabled(metadata)
}),
// File logs respect the user's settings (stored in FILE_LOG_LEVEL atomic)
- Target::new(TargetKind::LogDir {
- file_name: Some("handy".into()),
+ Target::new(if let Some(data_dir) = portable::data_dir() {
+ TargetKind::Folder {
+ path: data_dir.join("logs"),
+ file_name: Some("handy".into()),
+ }
+ } else {
+ TargetKind::LogDir {
+ file_name: Some("handy".into()),
+ }
})
.filter(|metadata| {
let file_level = FILE_LOG_LEVEL.load(Ordering::Relaxed);
@@ -416,6 +427,23 @@ pub fn run(cli_args: CliArgs) {
))
.manage(cli_args.clone())
.setup(move |app| {
+ // Create main window programmatically so we can set data_directory
+ // for portable mode (redirects WebView2 cache to portable Data dir)
+ let mut win_builder =
+ tauri::WebviewWindowBuilder::new(app, "main", tauri::WebviewUrl::App("/".into()))
+ .title("Handy")
+ .inner_size(680.0, 570.0)
+ .min_inner_size(680.0, 570.0)
+ .resizable(true)
+ .maximizable(false)
+ .visible(false);
+
+ if let Some(data_dir) = portable::data_dir() {
+ win_builder = win_builder.data_directory(data_dir.join("webview"));
+ }
+
+ win_builder.build()?;
+
let mut settings = get_settings(&app.handle());
// CLI --debug flag overrides debug_mode and log level (runtime-only, not persisted)
diff --git a/src-tauri/src/managers/history.rs b/src-tauri/src/managers/history.rs
index cd5ee269..d05dae76 100644
--- a/src-tauri/src/managers/history.rs
+++ b/src-tauri/src/managers/history.rs
@@ -54,7 +54,7 @@ pub struct HistoryManager {
impl HistoryManager {
pub fn new(app_handle: &AppHandle) -> Result<Self> {
// Create recordings directory in app data dir
- let app_data_dir = app_handle.path().app_data_dir()?;
+ let app_data_dir = crate::portable::app_data_dir(app_handle)?;
let recordings_dir = app_data_dir.join("recordings");
let db_path = app_data_dir.join("history.db");
diff --git a/src-tauri/src/managers/model.rs b/src-tauri/src/managers/model.rs
index 50b2c04d..59150c7b 100644
--- a/src-tauri/src/managers/model.rs
+++ b/src-tauri/src/managers/model.rs
@@ -66,9 +66,7 @@ pub struct ModelManager {
impl ModelManager {
pub fn new(app_handle: &AppHandle) -> Result<Self> {
// Create models directory in app data
- let models_dir = app_handle
- .path()
- .app_data_dir()
+ let models_dir = crate::portable::app_data_dir(app_handle)
.map_err(|e| anyhow::anyhow!("Failed to get app data dir: {}", e))?
.join("models");
diff --git a/src-tauri/src/overlay.rs b/src-tauri/src/overlay.rs
index 98c5b917..026dca5d 100644
--- a/src-tauri/src/overlay.rs
+++ b/src-tauri/src/overlay.rs
@@ -227,6 +227,10 @@ pub fn create_recording_overlay(app_handle: &AppHandle) {
.focused(false)
.visible(false);
+ if let Some(data_dir) = crate::portable::data_dir() {
+ builder = builder.data_directory(data_dir.join("webview"));
+ }
+
if let Some((x, y)) = position {
builder = builder.position(x, y);
}
diff --git a/src-tauri/src/portable.rs b/src-tauri/src/portable.rs
new file mode 100644
index 00000000..8d794331
--- /dev/null
+++ b/src-tauri/src/portable.rs
@@ -0,0 +1,77 @@
+use std::path::PathBuf;
+use std::sync::OnceLock;
+use tauri::Manager;
+
+/// Portable mode support for Handy.
+///
+/// When a file named `portable` exists next to the executable, all user data
+/// (settings, models, recordings, database, logs) is stored in a `Data/`
+/// directory alongside the executable instead of `%APPDATA%`.
+
+static PORTABLE_DATA_DIR: OnceLock<Option<PathBuf>> = OnceLock::new();
+
+/// Detect portable mode by looking for a `portable` marker file next to the exe.
+/// Must be called once at startup before Tauri initializes.
+pub fn init() {
+ PORTABLE_DATA_DIR.get_or_init(|| {
+ let exe_path = std::env::current_exe().ok()?;
+ let exe_dir = exe_path.parent()?;
+
+ if exe_dir.join("portable").exists() {
+ let data_dir = exe_dir.join("Data");
+ if !data_dir.exists() {
+ std::fs::create_dir_all(&data_dir).ok()?;
+ }
+ eprintln!("[portable] data dir: {}", data_dir.display());
+ Some(data_dir)
+ } else {
+ None
+ }
+ });
+}
+
+/// Returns `true` if running in portable mode.
+pub fn is_portable() -> bool {
+ PORTABLE_DATA_DIR.get().and_then(|v| v.as_ref()).is_some()
+}
+
+/// Get the portable data dir (if active). Does not require an AppHandle.
+/// Returns `None` when not in portable mode.
+pub fn data_dir() -> Option<&'static PathBuf> {
+ PORTABLE_DATA_DIR.get().and_then(|v| v.as_ref())
+}
+
+/// Portable-aware replacement for `app.path().app_data_dir()`.
+pub fn app_data_dir(app: &tauri::AppHandle) -> Result<PathBuf, tauri::Error> {
+ if let Some(dir) = data_dir() {
+ Ok(dir.clone())
+ } else {
+ app.path().app_data_dir()
+ }
+}
+
+/// Portable-aware replacement for `app.path().app_log_dir()`.
+pub fn app_log_dir(app: &tauri::AppHandle) -> Result<PathBuf, tauri::Error> {
+ if let Some(dir) = data_dir() {
+ Ok(dir.join("logs"))
+ } else {
+ app.path().app_log_dir()
+ }
+}
+
+/// Resolve a relative path against the app data directory (portable-aware).
+/// Replaces `app.path().resolve(path, BaseDirectory::AppData)`.
+pub fn resolve_app_data(app: &tauri::AppHandle, relative: &str) -> Result<PathBuf, tauri::Error> {
+ Ok(app_data_dir(app)?.join(relative))
+}
+
+/// Get the path to use with `tauri-plugin-store`.
+/// Returns an absolute path in portable mode (so the store plugin writes to
+/// the portable Data dir) or the original relative path otherwise.
+pub fn store_path(relative: &str) -> PathBuf {
+ if let Some(dir) = data_dir() {
+ dir.join(relative)
+ } else {
+ PathBuf::from(relative)
+ }
+}
diff --git a/src-tauri/src/settings.rs b/src-tauri/src/settings.rs
index 88433781..430ec762 100644
--- a/src-tauri/src/settings.rs
+++ b/src-tauri/src/settings.rs
@@ -753,7 +753,7 @@ impl AppSettings {
pub fn load_or_create_app_settings(app: &AppHandle) -> AppSettings {
// Initialize store
let store = app
- .store(SETTINGS_STORE_PATH)
+ .store(crate::portable::store_path(SETTINGS_STORE_PATH))
.expect("Failed to initialize store");
let mut settings = if let Some(settings_value) = store.get("settings") {
@@ -803,7 +803,7 @@ pub fn load_or_create_app_settings(app: &AppHandle) -> AppSettings {
pub fn get_settings(app: &AppHandle) -> AppSettings {
let store = app
- .store(SETTINGS_STORE_PATH)
+ .store(crate::portable::store_path(SETTINGS_STORE_PATH))
.expect("Failed to initialize store");
let mut settings = if let Some(settings_value) = store.get("settings") {
@@ -827,7 +827,7 @@ pub fn get_settings(app: &AppHandle) -> AppSettings {
pub fn write_settings(app: &AppHandle, settings: AppSettings) {
let store = app
- .store(SETTINGS_STORE_PATH)
+ .store(crate::portable::store_path(SETTINGS_STORE_PATH))
.expect("Failed to initialize store");
store.set("settings", serde_json::to_value(&settings).unwrap());
diff --git a/src-tauri/tauri.conf.json b/src-tauri/tauri.conf.json
index 6fcf1b3e..cb8054c4 100644
--- a/src-tauri/tauri.conf.json
+++ b/src-tauri/tauri.conf.json
@@ -11,19 +11,7 @@
},
"app": {
"macOSPrivateApi": true,
- "windows": [
- {
- "label": "main",
- "title": "Handy",
- "width": 680,
- "height": 570,
- "minWidth": 680,
- "minHeight": 570,
- "resizable": true,
- "maximizable": false,
- "visible": false
- }
- ],
+ "windows": [],
"security": {
"csp": null,
"assetProtocol": {
@@ -70,7 +58,10 @@
}
},
"windows": {
- "signCommand": "trusted-signing-cli -e https://eus.codesigning.azure.net/ -a CJ-Signing -c cjpais-dev -d Handy %1"
+ "signCommand": "trusted-signing-cli -e https://eus.codesigning.azure.net/ -a CJ-Signing -c cjpais-dev -d Handy %1",
+ "nsis": {
+ "template": "nsis/installer.nsi"
+ }
}
},
"plugins": {