Skip to content

Satellite tracker and pass predictor for Android, inspired by Gpredict

Migrated project build files to use kotlin script

Arty Bishop3580854479c3
diff --git a/app/build.gradle b/app/build.gradle
deleted file mode 100644
index e40829cd..00000000
--- a/app/build.gradle
+++ /dev/null
@@ -1,83 +0,0 @@
-plugins {
- id "com.android.application"
- id "com.google.devtools.ksp"
- id "org.jetbrains.kotlin.android"
-}
-
-android {
- namespace "com.rtbishop.look4sat"
- compileSdk 33
-
- defaultConfig {
- applicationId "com.rtbishop.look4sat"
- minSdk 21
- targetSdk 33
- versionCode 313
- versionName "3.1.3"
-
- testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
- }
- buildFeatures {
- compose true
- }
- buildTypes {
- release {
- minifyEnabled true
- shrinkResources true
- proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
- }
- }
- compileOptions {
- sourceCompatibility JavaVersion.VERSION_17
- targetCompatibility JavaVersion.VERSION_17
- }
- composeOptions {
- kotlinCompilerExtensionVersion compose_compiler_version
- }
- kotlinOptions {
- jvmTarget = JavaVersion.VERSION_17.toString()
- }
- packagingOptions {
- resources {
- excludes += '/META-INF/{AL2.0,LGPL2.1}'
- }
- }
- testOptions {
- animationsDisabled true
- unitTests.includeAndroidResources true
- }
-}
-
-kotlin {
- jvmToolchain(17)
-}
-
-dependencies {
- implementation project(":data")
- implementation project(":domain")
- // Android
- implementation "androidx.core:core-splashscreen:$splashscreen_version"
- implementation "androidx.room:room-runtime:$room_version"
- implementation "androidx.room:room-ktx:$room_version"
- ksp "androidx.room:room-compiler:$room_version"
- // Compose
- implementation "androidx.activity:activity-compose:$activity_compose_version"
- implementation "androidx.compose.animation:animation:$compose_version"
- implementation "androidx.compose.compiler:compiler:$compose_compiler_version"
- implementation "androidx.compose.material3:material3:$material3_version"
- implementation "androidx.compose.runtime:runtime:$compose_version"
- implementation "androidx.compose.ui:ui-tooling-preview:$compose_version"
- implementation "androidx.lifecycle:lifecycle-viewmodel-compose:$lifecycle_version"
- implementation "androidx.navigation:navigation-compose:$navigation_version"
- // Utility
- implementation "com.squareup.okhttp3:okhttp:$okhttp_version"
- implementation "org.osmdroid:osmdroid-android:$osmdroid_version"
- debugImplementation "androidx.compose.ui:ui-tooling:$compose_version"
- debugImplementation "androidx.compose.ui:ui-test-manifest:$compose_version"
- debugImplementation "com.squareup.leakcanary:leakcanary-android:$leakcanary_version"
- // Test
- testImplementation "junit:junit:$junit_version"
- testImplementation "io.mockk:mockk:$mockk_version"
- testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$coroutines_test_version"
- androidTestImplementation "androidx.compose.ui:ui-test-junit4:$compose_version"
-}
diff --git a/app/build.gradle.kts b/app/build.gradle.kts
new file mode 100644
index 00000000..6645ef4e
--- /dev/null
+++ b/app/build.gradle.kts
@@ -0,0 +1,102 @@
+@file: Suppress("UnstableApiUsage")
+
+plugins {
+ id("com.android.application")
+ id("com.google.devtools.ksp")
+ id("org.jetbrains.kotlin.android")
+}
+
+android {
+ namespace = "com.rtbishop.look4sat"
+ compileSdk = 33
+
+ defaultConfig {
+ applicationId = "com.rtbishop.look4sat"
+ minSdk = 21
+ targetSdk = 33
+ versionCode = 313
+ versionName = "3.1.3"
+
+ testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+ }
+ buildFeatures {
+ compose = true
+ }
+ buildTypes {
+ release {
+ isMinifyEnabled = true
+ isShrinkResources = true
+ proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
+ }
+ }
+ compileOptions {
+ sourceCompatibility = JavaVersion.VERSION_17
+ targetCompatibility = JavaVersion.VERSION_17
+ }
+ kotlinOptions {
+ jvmTarget = JavaVersion.VERSION_17.toString()
+ }
+ testOptions {
+ unitTests {
+ all { it.useJUnitPlatform() }
+ isIncludeAndroidResources = true
+ isReturnDefaultValues = true
+ }
+ }
+ composeOptions {
+ kotlinCompilerExtensionVersion = "1.4.7"
+ }
+ packaging {
+ resources {
+ excludes += listOf(
+ "/META-INF/{AL2.0,LGPL2.1}",
+ "META-INF/DEPENDENCIES.txt",
+ "META-INF/LICENSE.txt",
+ "META-INF/NOTICE.txt",
+ "META-INF/NOTICE",
+ "META-INF/LICENSE",
+ "META-INF/DEPENDENCIES",
+ "META-INF/notice.txt",
+ "META-INF/license.txt",
+ "META-INF/dependencies.txt",
+ "META-INF/LGPL2.1",
+ "META-INF/maven/commons-io/commons-io/pom.xml",
+ "META-INF/maven/commons-io/commons-io/pom.properties"
+ )
+ }
+ }
+}
+
+kotlin {
+ jvmToolchain(17)
+}
+
+dependencies {
+ implementation(project(":data"))
+ implementation(project(":domain"))
+ // Android
+ implementation("androidx.core:core-splashscreen:1.0.1")
+ implementation("androidx.room:room-runtime:2.5.2")
+ implementation("androidx.room:room-ktx:2.5.2")
+ ksp("androidx.room:room-compiler:2.5.2")
+ // Compose
+ implementation("androidx.activity:activity-compose:1.7.2")
+ implementation("androidx.compose.animation:animation:1.4.3")
+ implementation("androidx.compose.compiler:compiler:1.5.1")
+ implementation("androidx.compose.material3:material3:1.1.1")
+ implementation("androidx.compose.runtime:runtime:1.4.3")
+ implementation("androidx.compose.ui:ui-tooling-preview:1.4.3")
+ implementation("androidx.lifecycle:lifecycle-viewmodel-compose:2.6.1")
+ implementation("androidx.navigation:navigation-compose:2.6.0")
+ // Utility
+ implementation("com.squareup.okhttp3:okhttp:4.10.0")
+ implementation("org.osmdroid:osmdroid-android:6.1.16")
+ debugImplementation("androidx.compose.ui:ui-tooling:1.4.3")
+ debugImplementation("androidx.compose.ui:ui-test-manifest:1.4.3")
+ debugImplementation("com.squareup.leakcanary:leakcanary-android:2.12")
+ // Test
+ testImplementation("junit:junit:4.13.2")
+ testImplementation("io.mockk:mockk:1.13.5")
+ testImplementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.7.3")
+ androidTestImplementation("androidx.compose.ui:ui-test-junit4:1.4.3")
+}
diff --git a/build.gradle b/build.gradle
deleted file mode 100644
index 5a7a9d88..00000000
--- a/build.gradle
+++ /dev/null
@@ -1,38 +0,0 @@
-buildscript {
- ext {
- gradle_plugin_version = '8.0.2'
- library_plugin_version = '7.1.2'
- ksp_version = '1.8.21-1.0.11'
- kotlin_android_version = '1.8.21'
- // Android
- splashscreen_version = '1.0.1'
- room_version = '2.5.1'
- // Compose
- activity_compose_version = '1.7.2'
- compose_version = '1.4.3'
- compose_compiler_version = '1.4.7'
- material3_version = '1.1.0'
- lifecycle_version = '2.6.1'
- navigation_version = '2.5.3'
- // Utility
- okhttp_version = '4.10.0'
- osmdroid_version = '6.1.16'
- json_version = '20230227'
- leakcanary_version = '2.11'
- // Test
- junit_version = '4.13.2'
- mockk_version = '1.13.5'
- coroutines_test_version = '1.7.1'
- }
-}
-
-plugins {
- id "com.android.application" version "$gradle_plugin_version" apply false
- id "com.android.library" version "$library_plugin_version" apply false
- id "com.google.devtools.ksp" version "$ksp_version" apply false
- id "org.jetbrains.kotlin.android" version "$kotlin_android_version" apply false
-}
-
-tasks.register('clean', Delete) {
- delete rootProject.buildDir
-}
diff --git a/build.gradle.kts b/build.gradle.kts
new file mode 100644
index 00000000..4c8a75c4
--- /dev/null
+++ b/build.gradle.kts
@@ -0,0 +1,10 @@
+plugins {
+ id("com.android.application") version "8.0.2" apply false
+ id("com.android.library") version "7.1.2" apply false
+ id("com.google.devtools.ksp") version "1.8.21-1.0.11" apply false
+ id("org.jetbrains.kotlin.android") version "1.8.21" apply false
+}
+
+tasks.register("clean", Delete::class.java) {
+ delete(rootProject.buildDir)
+}
diff --git a/data/build.gradle b/data/build.gradle
deleted file mode 100644
index e7478ddd..00000000
--- a/data/build.gradle
+++ /dev/null
@@ -1,56 +0,0 @@
-plugins {
- id "com.android.library"
- id "com.google.devtools.ksp"
- id "org.jetbrains.kotlin.android"
-}
-
-android {
- namespace "com.rtbishop.look4sat.data"
- compileSdk 33
-
- defaultConfig {
- minSdk 21
-
- testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
- }
-
- buildTypes {
- release {
- minifyEnabled false
- proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
- }
- }
- compileOptions {
- sourceCompatibility JavaVersion.VERSION_17
- targetCompatibility JavaVersion.VERSION_17
- }
- kotlinOptions {
- jvmTarget = JavaVersion.VERSION_17.toString()
- }
- testOptions {
- animationsDisabled true
- unitTests.includeAndroidResources true
- }
-}
-
-kotlin {
- jvmToolchain(17)
-}
-
-dependencies {
- implementation project(":domain")
- // Android
- implementation "androidx.core:core-ktx:1.10.1"
- implementation "androidx.room:room-runtime:$room_version"
- implementation "androidx.room:room-ktx:$room_version"
- ksp "androidx.room:room-compiler:$room_version"
- // Utility
- implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutines_test_version"
- implementation "com.squareup.okhttp3:okhttp:$okhttp_version"
- // Test
- testImplementation "junit:junit:$junit_version"
- testImplementation "io.mockk:mockk:$mockk_version"
- testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$coroutines_test_version"
- androidTestImplementation "androidx.test.ext:junit:1.1.5"
- androidTestImplementation "androidx.test.espresso:espresso-core:3.5.1"
-}
diff --git a/data/build.gradle.kts b/data/build.gradle.kts
new file mode 100644
index 00000000..e6fd0190
--- /dev/null
+++ b/data/build.gradle.kts
@@ -0,0 +1,61 @@
+@file:Suppress("UnstableApiUsage")
+
+plugins {
+ id("com.android.library")
+ id("com.google.devtools.ksp")
+ id("org.jetbrains.kotlin.android")
+}
+
+android {
+ namespace = "com.rtbishop.look4sat.data"
+ compileSdk = 33
+
+ defaultConfig {
+ minSdk = 21
+
+ testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+ }
+
+ buildTypes {
+ release {
+ isMinifyEnabled = false
+ proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
+ }
+ }
+ compileOptions {
+ sourceCompatibility = JavaVersion.VERSION_17
+ targetCompatibility = JavaVersion.VERSION_17
+ }
+ kotlinOptions {
+ jvmTarget = JavaVersion.VERSION_17.toString()
+ }
+ testOptions {
+ unitTests {
+ all { it.useJUnitPlatform() }
+ isIncludeAndroidResources = true
+ isReturnDefaultValues = true
+ }
+ }
+}
+
+kotlin {
+ jvmToolchain(17)
+}
+
+dependencies {
+ implementation(project(":domain"))
+ // Android
+ implementation("androidx.core:core-ktx:1.10.1")
+ implementation("androidx.room:room-runtime:2.5.2")
+ implementation("androidx.room:room-ktx:2.5.2")
+ ksp("androidx.room:room-compiler:2.5.2")
+ // Utility
+ implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.7.3")
+ implementation("com.squareup.okhttp3:okhttp:4.10.0")
+ // Test
+ testImplementation("junit:junit:4.13.2")
+ testImplementation("io.mockk:mockk:1.13.5")
+ testImplementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.7.3")
+ androidTestImplementation("androidx.test.ext:junit:1.1.5")
+ androidTestImplementation("androidx.test.espresso:espresso-core:3.5.1")
+}
diff --git a/domain/build.gradle b/domain/build.gradle
deleted file mode 100644
index 04873064..00000000
--- a/domain/build.gradle
+++ /dev/null
@@ -1,15 +0,0 @@
-plugins {
- id "kotlin"
-}
-
-kotlin {
- jvmToolchain(17)
-}
-
-dependencies {
- implementation "org.jetbrains.kotlinx:kotlinx-coroutines-core:$coroutines_test_version"
-
- testImplementation "junit:junit:$junit_version"
- testImplementation "io.mockk:mockk:$mockk_version"
- testImplementation "org.jetbrains.kotlinx:kotlinx-coroutines-test:$coroutines_test_version"
-}
diff --git a/domain/build.gradle.kts b/domain/build.gradle.kts
new file mode 100644
index 00000000..3736e48f
--- /dev/null
+++ b/domain/build.gradle.kts
@@ -0,0 +1,15 @@
+plugins {
+ id("kotlin")
+}
+
+kotlin {
+ jvmToolchain(17)
+}
+
+dependencies {
+ implementation("org.jetbrains.kotlinx:kotlinx-coroutines-core:1.7.3")
+
+ testImplementation("junit:junit:4.13.2")
+ testImplementation("io.mockk:mockk:1.13.5")
+ testImplementation("org.jetbrains.kotlinx:kotlinx-coroutines-test:1.7.3")
+}