Skip to content

Open source, privacy-first web analytics. Lightweight, cookie-free Google Analytics alternative. Self-hosted or cloud.

1.0 KB
Raw Blame
defmodule Plausible.Teams.Membership do
  @moduledoc """
  Team membership schema
  """

  use Ecto.Schema

  import Ecto.Changeset

  @roles [:guest, :viewer, :editor, :admin, :owner, :billing]

  @type t() :: %__MODULE__{}

  @type role() :: unquote(Enum.reduce(@roles, &{:|, [], [&1, &2]}))

  schema "team_memberships" do
    field :role, Ecto.Enum, values: @roles
    field :is_autocreated, :boolean, default: false

    belongs_to :user, Plausible.Auth.User
    belongs_to :team, Plausible.Teams.Team

    has_many :guest_memberships, Plausible.Teams.GuestMembership, foreign_key: :team_membership_id

    timestamps()
  end

  def roles(), do: @roles

  @spec roles!([atom()]) :: [role()]
  def roles!(roles) do
    case roles -- roles() do
      [] -> roles
      unknown -> raise ArgumentError, "unknown roles: #{inspect(unknown)}"
    end
  end

  def changeset(team, user, role) do
    %__MODULE__{}
    |> change()
    |> put_change(:role, role)
    |> put_assoc(:team, team)
    |> put_assoc(:user, user)
  end
end