Skip to content

Open source, privacy-first web analytics. Lightweight, cookie-free Google Analytics alternative. Self-hosted or cloud.

Add endpoints for managing custom props in Sites API (#5733)

Adrian Gruntkowski457cc41c07de
diff --git a/extra/lib/plausible_web/controllers/api/external_sites_controller.ex b/extra/lib/plausible_web/controllers/api/external_sites_controller.ex
index 220e8dd149..169205ff50 100644
--- a/extra/lib/plausible_web/controllers/api/external_sites_controller.ex
+++ b/extra/lib/plausible_web/controllers/api/external_sites_controller.ex
@@ -8,6 +8,7 @@ defmodule PlausibleWeb.Api.ExternalSitesController do
alias Plausible.Sites
alias Plausible.Goal
alias Plausible.Goals
+ alias Plausible.Props
alias Plausible.Teams
alias PlausibleWeb.Api.Helpers, as: H
@@ -445,6 +446,86 @@ defmodule PlausibleWeb.Api.ExternalSitesController do
end
end
+ def custom_props_index(conn, params) do
+ user = conn.assigns.current_user
+ team = conn.assigns.current_team
+
+ with {:ok, site_id} <- expect_param_key(params, "site_id"),
+ {:ok, site} <- find_site(user, team, site_id, [:owner, :admin, :editor, :viewer]) do
+ properties =
+ (site.allowed_event_props || [])
+ |> Enum.sort()
+ |> Enum.map(fn prop -> %{property: prop} end)
+
+ json(conn, %{custom_properties: properties})
+ else
+ {:error, :site_not_found} ->
+ H.not_found(conn, "Site could not be found")
+
+ {:missing, "site_id"} ->
+ H.bad_request(conn, "Parameter `site_id` is required to list custom properties")
+ end
+ end
+
+ def add_custom_prop(conn, params) do
+ user = conn.assigns.current_user
+ team = conn.assigns.current_team
+
+ with {:ok, site_id} <- expect_param_key(params, "site_id"),
+ {:ok, property} <- expect_param_key(params, "property"),
+ {:ok, site} <- find_site(user, team, site_id, [:owner, :admin, :editor]),
+ {:ok, _} <- Props.allow(site, property) do
+ json(conn, %{"created" => true})
+ else
+ {:error, :site_not_found} ->
+ H.not_found(conn, "Site could not be found")
+
+ {:missing, param} ->
+ H.bad_request(conn, "Parameter `#{param}` is required to create a custom property")
+
+ {:error, changeset} ->
+ %{allowed_event_props: [error | _]} =
+ Ecto.Changeset.traverse_errors(changeset, fn {_msg, opts} ->
+ cond do
+ opts[:type] == :list and opts[:validation] == :length ->
+ "Can't add any more custom properties"
+
+ opts[:type] == :string and opts[:validation] == :length ->
+ "Parameter `property` is too long"
+
+ true ->
+ "Parameter `property` is invalid"
+ end
+ end)
+
+ H.bad_request(conn, error)
+ end
+ end
+
+ def delete_custom_prop(conn, params) do
+ user = conn.assigns.current_user
+ team = conn.assigns.current_team
+
+ with {:ok, site_id} <- expect_param_key(params, "site_id"),
+ {:ok, property} <- expect_param_key(params, "property"),
+ # Property name is extracted from route URL via wildcard,
+ # which returns a list.
+ property = Path.join(property),
+ {:ok, site} <- find_site(user, team, site_id, [:owner, :admin, :editor]),
+ {:ok, _} <- Props.disallow(site, property) do
+ json(conn, %{"deleted" => true})
+ else
+ {:error, :site_not_found} ->
+ H.not_found(conn, "Site could not be found")
+
+ {:missing, param} ->
+ H.bad_request(conn, "Parameter `#{param}` is required to delete a custom property")
+
+ e ->
+ H.bad_request(conn, "Something went wrong: #{inspect(e)}")
+ end
+ end
+
defp pagination_meta(meta) do
%{
after: meta.after,
diff --git a/lib/plausible/props.ex b/lib/plausible/props.ex
index be74acb324..b462a3a522 100644
--- a/lib/plausible/props.ex
+++ b/lib/plausible/props.ex
@@ -120,7 +120,11 @@ defmodule Plausible.Props do
|> Ecto.Changeset.validate_change(:allowed_event_props, fn field, allowed_props ->
if Enum.all?(allowed_props, &valid?/1),
do: [],
- else: [{field, "must be between 1 and #{@max_prop_key_length} characters"}]
+ else: [
+ {field,
+ {"must be between 1 and #{@max_prop_key_length} characters",
+ validation: :length, type: :string}}
+ ]
end)
end
diff --git a/lib/plausible_web/router.ex b/lib/plausible_web/router.ex
index 555646e52f..13c07e08f8 100644
--- a/lib/plausible_web/router.ex
+++ b/lib/plausible_web/router.ex
@@ -337,6 +337,7 @@ defmodule PlausibleWeb.Router do
scope assigns: %{api_context: :site} do
get "/goals", ExternalSitesController, :goals_index
+ get "/custom-props", ExternalSitesController, :custom_props_index
get "/guests", ExternalSitesController, :guests_index
get "/:site_id", ExternalSitesController, :get_site
end
@@ -353,6 +354,10 @@ defmodule PlausibleWeb.Router do
put "/goals", ExternalSitesController, :find_or_create_goal
delete "/goals/:goal_id", ExternalSitesController, :delete_goal
+ put "/custom-props", ExternalSitesController, :add_custom_prop
+ # Property name can contain forward slashes, hence we match on wildcard here
+ delete "/custom-props/*property", ExternalSitesController, :delete_custom_prop
+
put "/guests", ExternalSitesController, :find_or_create_guest
delete "/guests/:email", ExternalSitesController, :delete_guest
diff --git a/test/plausible/props_test.exs b/test/plausible/props_test.exs
index 20bacfedd0..9bd749f4e5 100644
--- a/test/plausible/props_test.exs
+++ b/test/plausible/props_test.exs
@@ -54,17 +54,23 @@ defmodule Plausible.PropsTest do
long_prop = String.duplicate("a", 301)
assert {:error, changeset} = Plausible.Props.allow(site, long_prop)
- assert {"must be between 1 and 300 characters", []} == changeset.errors[:allowed_event_props]
+
+ assert {"must be between 1 and 300 characters", [validation: :length, type: :string]} ==
+ changeset.errors[:allowed_event_props]
end
test "allow/2 fails when prop key is empty" do
site = new_site()
assert {:error, changeset} = Plausible.Props.allow(site, "")
- assert {"must be between 1 and 300 characters", []} == changeset.errors[:allowed_event_props]
+
+ assert {"must be between 1 and 300 characters", [validation: :length, type: :string]} ==
+ changeset.errors[:allowed_event_props]
assert {:error, changeset} = Plausible.Props.allow(site, " ")
- assert {"must be between 1 and 300 characters", []} == changeset.errors[:allowed_event_props]
+
+ assert {"must be between 1 and 300 characters", [validation: :length, type: :string]} ==
+ changeset.errors[:allowed_event_props]
end
test "allow/2 does not fail when prop key is already in the list" do
diff --git a/test/plausible_web/controllers/api/external_sites_controller_test.exs b/test/plausible_web/controllers/api/external_sites_controller_test.exs
index d3f1f61ba6..13204dbb77 100644
--- a/test/plausible_web/controllers/api/external_sites_controller_test.exs
+++ b/test/plausible_web/controllers/api/external_sites_controller_test.exs
@@ -475,6 +475,159 @@ defmodule PlausibleWeb.Api.ExternalSitesControllerTest do
end
end
+ describe "PUT /api/v1/sites/custom-props" do
+ setup :create_site
+
+ test "can add a custom property to a site", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ res = json_response(conn, 200)
+
+ assert res["created"] == true
+
+ assert Repo.reload!(site).allowed_event_props == ["prop1"]
+ end
+
+ test "can add a custom prop using old site_id after domain change", %{
+ conn: conn,
+ site: site
+ } do
+ old_domain = site.domain
+ new_domain = "new.example.com"
+
+ Plausible.Site.Domain.change(site, new_domain)
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: old_domain,
+ property: "prop1"
+ })
+
+ res = json_response(conn, 200)
+
+ assert res["created"] == true
+
+ assert Repo.reload!(site).allowed_event_props == ["prop1"]
+ end
+
+ test "is idempotent", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ assert %{"created" => true} = json_response(conn, 200)
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ assert %{"created" => true} = json_response(conn, 200)
+
+ assert Repo.reload!(site).allowed_event_props == ["prop1"]
+ end
+
+ test "fails to add a custom prop with too long name", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: String.duplicate("a", Plausible.Props.max_prop_key_length() + 1)
+ })
+
+ assert %{"error" => "Parameter `property` is too long"} = json_response(conn, 400)
+ end
+
+ test "fails to add a custom prop when props list is too long", %{conn: conn, site: site} do
+ max_props = Plausible.Props.max_props()
+
+ Enum.reduce(1..max_props, site, fn idx, site ->
+ {:ok, site} = Plausible.Props.allow(site, "prop#{idx}")
+ site
+ end)
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop#{max_props + 1}"
+ })
+
+ assert %{"error" => "Can't add any more custom properties"} = json_response(conn, 400)
+ end
+
+ test "fails when team does not match team-scoped key", %{conn: conn, user: user, site: site} do
+ another_team = new_user() |> subscribe_to_business_plan() |> team_of()
+ add_member(another_team, user: user, role: :admin)
+ api_key = insert(:api_key, user: user, team: another_team, scopes: ["sites:provision:*"])
+ conn = Plug.Conn.put_req_header(conn, "authorization", "Bearer #{api_key.key}")
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ res = json_response(conn, 404)
+ assert res["error"] == "Site could not be found"
+ end
+
+ test "returns 400 when site id missing", %{conn: conn} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ property: "prop1"
+ })
+
+ res = json_response(conn, 400)
+ assert res["error"] == "Parameter `site_id` is required to create a custom property"
+ end
+
+ test "returns 404 when site id is non existent", %{conn: conn} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ property: "prop1",
+ site_id: "bad"
+ })
+
+ res = json_response(conn, 404)
+ assert res["error"] == "Site could not be found"
+ end
+
+ @tag :capture_log
+ test "returns 404 when api key owner does not have permissions to create a goal", %{
+ conn: conn,
+ user: user
+ } do
+ site = new_site()
+
+ add_guest(site, user: user, role: :viewer)
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ res = json_response(conn, 404)
+ assert res["error"] == "Site could not be found"
+ end
+
+ test "returns 400 when property missing", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain
+ })
+
+ res = json_response(conn, 400)
+ assert res["error"] == "Parameter `property` is required to create a custom property"
+ end
+ end
+
describe "PUT /api/v1/sites/goals" do
setup :create_site
@@ -675,6 +828,141 @@ defmodule PlausibleWeb.Api.ExternalSitesControllerTest do
end
end
+ describe "DELETE /api/v1/sites/custom-props/:property" do
+ setup :create_site
+
+ test "deletes a custom property", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ assert %{"created" => true} = json_response(conn, 200)
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1", %{
+ site_id: site.domain
+ })
+
+ assert json_response(conn, 200) == %{"deleted" => true}
+
+ assert Repo.reload!(site).allowed_event_props == []
+ end
+
+ test "deletes a custom property with slash in name", %{conn: conn, site: site} do
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1/key/with/slashes"
+ })
+
+ assert %{"created" => true} = json_response(conn, 200)
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1/key/with/slashes", %{
+ site_id: site.domain
+ })
+
+ assert json_response(conn, 200) == %{"deleted" => true}
+
+ assert Repo.reload!(site).allowed_event_props == []
+ end
+
+ test "deletes a custom prop using old site_id after domain change", %{
+ conn: conn,
+ site: site
+ } do
+ old_domain = site.domain
+ new_domain = "new.example.com"
+
+ Plausible.Site.Domain.change(site, new_domain)
+
+ conn =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: new_domain,
+ property: "prop1"
+ })
+
+ assert %{"created" => true} = json_response(conn, 200)
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1", %{
+ site_id: old_domain
+ })
+
+ assert json_response(conn, 200) == %{"deleted" => true}
+ assert Repo.reload!(site).allowed_event_props == []
+ end
+
+ test "fails when team does not match team-scoped key", %{conn: conn, user: user, site: site} do
+ conn1 =
+ put(conn, "/api/v1/sites/custom-props", %{
+ site_id: site.domain,
+ property: "prop1"
+ })
+
+ assert %{"created" => true} = json_response(conn1, 200)
+
+ another_team = new_user() |> subscribe_to_business_plan() |> team_of()
+ add_member(another_team, user: user, role: :admin)
+ api_key = insert(:api_key, user: user, team: another_team, scopes: ["sites:provision:*"])
+ conn = Plug.Conn.put_req_header(conn, "authorization", "Bearer #{api_key.key}")
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1", %{
+ site_id: site.domain
+ })
+
+ res = json_response(conn, 404)
+ assert res["error"] == "Site could not be found"
+ end
+
+ test "handles non-existent custom prop gracefully", %{conn: conn, site: site} do
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/none", %{
+ site_id: site.domain
+ })
+
+ assert json_response(conn, 200) == %{"deleted" => true}
+ end
+
+ @tag :capture_log
+ test "cannot delete a custom prop belongs to a site that the user does not own", %{
+ conn: conn,
+ user: user
+ } do
+ site = new_site()
+ add_guest(site, user: user, role: :viewer)
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1", %{
+ site_id: site.domain
+ })
+
+ assert json_response(conn, 404) == %{"error" => "Site could not be found"}
+ end
+
+ test "cannot access with a bad API key scope", %{conn: conn, site: site, user: user} do
+ {:ok, site} = Plausible.Props.allow(site, "prop1")
+ api_key = insert(:api_key, user: user, scopes: ["stats:read:*"])
+
+ conn =
+ conn
+ |> Plug.Conn.put_req_header("authorization", "Bearer #{api_key.key}")
+
+ conn =
+ delete(conn, "/api/v1/sites/custom-props/prop1", %{
+ site_id: site.domain
+ })
+
+ assert json_response(conn, 401) == %{
+ "error" =>
+ "Invalid API key. Please make sure you're using a valid API key with access to the resource you've requested."
+ }
+ end
+ end
+
describe "DELETE /api/v1/sites/goals/:goal_id" do
setup :create_site
@@ -1296,6 +1584,103 @@ defmodule PlausibleWeb.Api.ExternalSitesControllerTest do
end
end
+ describe "GET /api/v1/custom-props" do
+ setup :create_site
+
+ test "returns empty when there are no custom props for site", %{conn: conn, site: site} do
+ conn = get(conn, "/api/v1/sites/custom-props?site_id=" <> site.domain)
+
+ assert json_response(conn, 200) == %{"custom_properties" => []}
+ end
+
+ test "returns custom props when present", %{conn: conn, site: site} do
+ {:ok, site} = Plausible.Props.allow(site, "prop1")
+ {:ok, site} = Plausible.Props.allow(site, "prop2")
+ Plausible.Props.allow(site, "prop3")
+
+ conn = get(conn, "/api/v1/sites/custom-props?site_id=" <> site.domain)
+
+ assert json_response(conn, 200) == %{
+ "custom_properties" => [
+ %{"property" => "prop1"},
+ %{"property" => "prop2"},
+ %{"property" => "prop3"}
+ ]
+ }
+ end
+
+ @tag :capture_log
+ test "returns custom props for site where user is viewer", %{site: site} do
+ viewer = new_user()
+ add_guest(site, user: viewer, role: :viewer)
+
+ {:ok, site} = Plausible.Props.allow(site, "prop1")
+
+ api_key = insert(:api_key, user: viewer, scopes: ["sites:provision:*"])
+ conn = Plug.Conn.put_req_header(build_conn(), "authorization", "Bearer #{api_key.key}")
+
+ conn = get(conn, "/api/v1/sites/custom-props?site_id=" <> site.domain)
+
+ assert %{"custom_properties" => [%{"property" => "prop1"}]} = json_response(conn, 200)
+ end
+
+ test "lists custom props for user with read-only scope", %{
+ conn: conn,
+ user: user,
+ site: site
+ } do
+ {:ok, site} = Plausible.Props.allow(site, "prop1")
+ api_key = insert(:api_key, user: user, scopes: ["stats:read:*"])
+
+ conn =
+ conn
+ |> Plug.Conn.put_req_header("authorization", "Bearer #{api_key.key}")
+ |> get("/api/v1/sites/custom-props?site_id=" <> site.domain)
+
+ assert %{"custom_properties" => [%{"property" => "prop1"}]} = json_response(conn, 200)
+ end
+
+ test "fails when team does not match team-scoped key", %{conn: conn, user: user, site: site} do
+ another_team = new_user() |> subscribe_to_business_plan() |> team_of()
+ add_member(another_team, user: user, role: :admin)
+ api_key = insert(:api_key, user: user, team: another_team, scopes: ["sites:provision:*"])
+ conn = Plug.Conn.put_req_header(conn, "authorization", "Bearer #{api_key.key}")
+
+ _goal = insert(:goal, %{site: site, page_path: "/login"})
+
+ conn = get(conn, "/api/v1/sites/custom-props?site_id=" <> site.domain)
+
+ res = json_response(conn, 404)
+ assert res["error"] == "Site could not be found"
+ end
+
+ test "returns error when `site_id` parameter is missing", %{conn: conn} do
+ conn = get(conn, "/api/v1/sites/custom-props")
+
+ assert json_response(conn, 400) == %{
+ "error" => "Parameter `site_id` is required to list custom properties"
+ }
+ end
+
+ test "returns error when `site_id` parameter is invalid", %{conn: conn} do
+ conn = get(conn, "/api/v1/sites/custom-props=does.not.exist")
+
+ assert json_response(conn, 404) == %{
+ "error" => "Site could not be found"
+ }
+ end
+
+ test "returns error when user is not a member of the site", %{conn: conn} do
+ site = insert(:site)
+
+ conn = get(conn, "/api/v1/sites/custom-props=" <> site.domain)
+
+ assert json_response(conn, 404) == %{
+ "error" => "Site could not be found"
+ }
+ end
+ end
+
describe "GET /api/v1/goals" do
setup :create_site