Skip to content

Open source, privacy-first web analytics. Lightweight, cookie-free Google Analytics alternative. Self-hosted or cloud.

Implement automatic re-login on SSO session expiration (#5525)

Adrian Gruntkowski7490828e71c2
diff --git a/extra/lib/plausible_web/controllers/sso_controller.ex b/extra/lib/plausible_web/controllers/sso_controller.ex
index ad5e19ae23..e650bc8fad 100644
--- a/extra/lib/plausible_web/controllers/sso_controller.ex
+++ b/extra/lib/plausible_web/controllers/sso_controller.ex
@@ -20,7 +20,7 @@ defmodule PlausibleWeb.SSOController do
redirect(conn, to: Routes.auth_path(conn, :login_form, return_to: params["return_to"]))
_ ->
- render(conn, "login_form.html")
+ render(conn, "login_form.html", autosubmit: params["autosubmit"] != nil)
end
end
diff --git a/extra/lib/plausible_web/plugs/handle_expired_session.ex b/extra/lib/plausible_web/plugs/handle_expired_session.ex
new file mode 100644
index 0000000000..230c5a9f1f
--- /dev/null
+++ b/extra/lib/plausible_web/plugs/handle_expired_session.ex
@@ -0,0 +1,64 @@
+defmodule Plausible.Plugs.HandleExpiredSession do
+ @moduledoc """
+ Plug for handling expired session. Must be added after `AuthPlug`.
+ """
+
+ use Plausible
+
+ import Plug.Conn
+
+ alias PlausibleWeb.Router.Helpers, as: Routes
+
+ def init(_) do
+ []
+ end
+
+ def call(conn, []) do
+ maybe_trigger_login(conn, conn.assigns[:expired_session])
+ end
+
+ defp maybe_trigger_login(conn, nil), do: conn
+
+ defp maybe_trigger_login(conn, user_session) do
+ if Plausible.Users.type(user_session.user) == :sso do
+ Plausible.Auth.UserSessions.revoke_by_id(user_session.user, user_session.id)
+ trigger_sso_login(conn, user_session.user.email)
+ else
+ conn
+ end
+ end
+
+ defp trigger_sso_login(%{method: "GET"} = conn, email) do
+ return_to =
+ if conn.query_string && String.length(conn.query_string) > 0 do
+ conn.request_path <> "?" <> conn.query_string
+ else
+ conn.request_path
+ end
+
+ conn
+ |> Phoenix.Controller.redirect(
+ to:
+ Routes.sso_path(conn, :login_form,
+ prefer: "manual",
+ email: email,
+ autosubmit: true,
+ return_to: return_to
+ )
+ )
+ |> halt()
+ end
+
+ defp trigger_sso_login(conn, email) do
+ conn
+ |> Phoenix.Controller.redirect(
+ to:
+ Routes.sso_path(conn, :login_form,
+ prefer: "manual",
+ email: email,
+ autosubmit: true
+ )
+ )
+ |> halt()
+ end
+end
diff --git a/extra/lib/plausible_web/templates/sso/login_form.html.heex b/extra/lib/plausible_web/templates/sso/login_form.html.heex
index 3234d9a44a..14c4a08bdf 100644
--- a/extra/lib/plausible_web/templates/sso/login_form.html.heex
+++ b/extra/lib/plausible_web/templates/sso/login_form.html.heex
@@ -9,7 +9,12 @@
</p>
<% end %>
</:subtitle>
- <.form :let={f} for={@conn} action={Routes.sso_path(@conn, :login)}>
+ <script :if={@autosubmit}>
+ document.addEventListener("DOMContentLoaded", function () {
+ document.getElementById("sso-login-form").submit();
+ });
+ </script>
+ <.form :let={f} id="sso-login-form" for={@conn} action={Routes.sso_path(@conn, :login)}>
<div class="my-4 mt-8">
<.input
type="email"
diff --git a/lib/plausible/auth/user_sessions.ex b/lib/plausible/auth/user_sessions.ex
index e822742f8c..2a79f06968 100644
--- a/lib/plausible/auth/user_sessions.ex
+++ b/lib/plausible/auth/user_sessions.ex
@@ -33,7 +33,10 @@ defmodule Plausible.Auth.UserSessions do
end
end
- @spec get_by_token(String.t()) :: {:ok, Auth.UserSession.t()} | {:error, :not_found}
+ @spec get_by_token(String.t()) ::
+ {:ok, Auth.UserSession.t()}
+ | {:error, :not_found}
+ | {:error, :expired, Auth.UserSession.t()}
def get_by_token(token) do
now = NaiveDateTime.utc_now(:second)
@@ -50,14 +53,18 @@ defmodule Plausible.Auth.UserSessions do
left_join: o in assoc(t, :owners),
left_lateral_join: ts in subquery(last_team_subscription_query),
on: true,
- where: us.token == ^token and us.timeout_at > ^now,
+ where: us.token == ^token,
order_by: t.id,
preload: [user: {u, team_memberships: {tm, team: {t, subscription: ts, owners: o}}}]
)
case Repo.one(token_query) do
%Auth.UserSession{} = user_session ->
- {:ok, user_session}
+ if NaiveDateTime.compare(user_session.timeout_at, now) == :gt do
+ {:ok, user_session}
+ else
+ {:error, :expired, user_session}
+ end
nil ->
{:error, :not_found}
diff --git a/lib/plausible/teams/policy.ex b/lib/plausible/teams/policy.ex
index e35d3912ce..c077a744fb 100644
--- a/lib/plausible/teams/policy.ex
+++ b/lib/plausible/teams/policy.ex
@@ -13,6 +13,7 @@ defmodule Plausible.Teams.Policy do
@update_fields [:sso_default_role, :sso_session_timeout_minutes]
@default_timeout_minutes 6 * 60
+ @min_timeout_minutes 30
@max_timeout_minutes 12 * 60
@type t() :: %__MODULE__{}
@@ -50,8 +51,8 @@ defmodule Plausible.Teams.Policy do
|> cast(params, @update_fields)
|> validate_required(@update_fields)
|> validate_number(:sso_session_timeout_minutes,
- greater_than: 0,
- less_than: @max_timeout_minutes
+ greater_than_or_equal_to: @min_timeout_minutes,
+ less_than_or_equal_to: @max_timeout_minutes
)
end
diff --git a/lib/plausible_web/plugs/auth_plug.ex b/lib/plausible_web/plugs/auth_plug.ex
index e7deb35e16..7ae4f4cca0 100644
--- a/lib/plausible_web/plugs/auth_plug.ex
+++ b/lib/plausible_web/plugs/auth_plug.ex
@@ -75,6 +75,9 @@ defmodule PlausibleWeb.AuthPlug do
|> assign(:teams, teams)
|> assign(:more_teams?, teams_count > 3)
+ {:error, :session_expired, user_session} ->
+ assign(conn, :expired_session, user_session)
+
_ ->
conn
end
diff --git a/lib/plausible_web/router.ex b/lib/plausible_web/router.ex
index cf01875cf5..399b96a0f7 100644
--- a/lib/plausible_web/router.ex
+++ b/lib/plausible_web/router.ex
@@ -12,6 +12,7 @@ defmodule PlausibleWeb.Router do
plug PlausibleWeb.Plugs.NoRobots
on_ee(do: nil, else: plug(PlausibleWeb.FirstLaunchPlug, redirect_to: "/register"))
plug PlausibleWeb.AuthPlug
+ on_ee(do: plug(Plausible.Plugs.HandleExpiredSession))
on_ee(do: plug(Plausible.Plugs.SSOTeamAccess))
plug PlausibleWeb.Plugs.UserSessionTouch
end
@@ -25,6 +26,7 @@ defmodule PlausibleWeb.Router do
plug PlausibleWeb.Plugs.NoRobots
on_ee(do: nil, else: plug(PlausibleWeb.FirstLaunchPlug, redirect_to: "/register"))
plug PlausibleWeb.AuthPlug
+ on_ee(do: plug(Plausible.Plugs.HandleExpiredSession))
plug PlausibleWeb.Plugs.UserSessionTouch
end
end
diff --git a/lib/plausible_web/user_auth.ex b/lib/plausible_web/user_auth.ex
index 04536d3b8f..48c782efbc 100644
--- a/lib/plausible_web/user_auth.ex
+++ b/lib/plausible_web/user_auth.ex
@@ -96,7 +96,9 @@ defmodule PlausibleWeb.UserAuth do
end
@spec get_user_session(Plug.Conn.t() | map()) ::
- {:ok, Auth.UserSession.t()} | {:error, :no_valid_token | :session_not_found}
+ {:ok, Auth.UserSession.t()}
+ | {:error, :no_valid_token | :session_not_found}
+ | {:error, :session_expired, Auth.UserSession.t()}
def get_user_session(%Plug.Conn{assigns: %{current_user_session: user_session}}) do
{:ok, user_session}
end
@@ -106,6 +108,7 @@ defmodule PlausibleWeb.UserAuth do
case Auth.UserSessions.get_by_token(token) do
{:ok, session} -> {:ok, session}
{:error, :not_found} -> {:error, :session_not_found}
+ {:error, :expired, user_session} -> {:error, :session_expired, user_session}
end
end
end
diff --git a/test/plausible/auth/user_sessions_test.exs b/test/plausible/auth/user_sessions_test.exs
index dae8844b48..78de13222b 100644
--- a/test/plausible/auth/user_sessions_test.exs
+++ b/test/plausible/auth/user_sessions_test.exs
@@ -54,6 +54,47 @@ defmodule Plausible.Auth.UserSessionsTest do
end
end
+ describe "get_by_token/1" do
+ setup do
+ user = new_user()
+
+ session =
+ user
+ |> Auth.UserSession.new_session("A Device")
+ |> Repo.insert!()
+
+ {:ok, user: user, session: session}
+ end
+
+ test "fetches token by session", %{session: session, user: user} do
+ user |> subscribe_to_growth_plan()
+ team = team_of(user)
+ assert {:ok, fetched} = UserSessions.get_by_token(session.token)
+
+ assert fetched.id == session.id
+ assert fetched.user.id == user.id
+ assert [ownership] = fetched.user.team_memberships
+ assert ownership.role == :owner
+ assert ownership.team.id == team.id
+ assert ownership.team.subscription.id
+ assert [owner] = ownership.team.owners
+ assert owner.id == user.id
+ end
+
+ test "returns not found when no matching session found" do
+ assert {:error, :not_found} = UserSessions.get_by_token(Ecto.UUID.generate())
+ end
+
+ test "returns expired when the matching session is expired", %{session: session} do
+ now = NaiveDateTime.utc_now(:second)
+ in_the_past = NaiveDateTime.add(now, -1, :hour)
+ session = session |> Ecto.Changeset.change(timeout_at: in_the_past) |> Repo.update!()
+
+ assert {:error, :expired, expired_session} = UserSessions.get_by_token(session.token)
+ assert expired_session.id == session.id
+ end
+ end
+
describe "touch/1,2" do
setup do
user = new_user()
diff --git a/test/plausible_web/controllers/sso_controller_test.exs b/test/plausible_web/controllers/sso_controller_test.exs
index b03eb4c229..5d6106fb40 100644
--- a/test/plausible_web/controllers/sso_controller_test.exs
+++ b/test/plausible_web/controllers/sso_controller_test.exs
@@ -63,6 +63,24 @@ defmodule PlausibleWeb.SSOControllerTest do
assert text_of_attr(html, "input[name=return_to]", "value") == ""
end
+ test "renders autosubmit js snippet when instructed", %{conn: conn} do
+ conn =
+ get(
+ conn,
+ Routes.sso_path(conn, :login_form,
+ prefer: "sso",
+ email: "[email protected]",
+ autosubmit: true
+ )
+ )
+
+ assert html = html_response(conn, 200)
+
+ assert html =~ "Enter your Single Sign-on email"
+ assert text_of_attr(html, "input[name=email]", "value") == "[email protected]"
+ assert html =~ ~s|document.getElementById("sso-login-form").submit()|
+ end
+
test "passes return_to parameter to form", %{conn: conn} do
conn = get(conn, Routes.sso_path(conn, :login_form, return_to: "/sites", prefer: "sso"))
diff --git a/test/plausible_web/plugs/auth_plug_test.exs b/test/plausible_web/plugs/auth_plug_test.exs
index 53bd4cb4e5..d4a97ee3c1 100644
--- a/test/plausible_web/plugs/auth_plug_test.exs
+++ b/test/plausible_web/plugs/auth_plug_test.exs
@@ -160,4 +160,20 @@ defmodule PlausibleWeb.AuthPlugTest do
assert is_nil(updated_user.last_team_identifier)
refute get_session(conn, "current_team_id")
end
+
+ test "assigns expired session for further subsequent processing", %{conn: conn} do
+ now = NaiveDateTime.utc_now(:second)
+ in_the_past = NaiveDateTime.add(now, -1, :hour)
+ {:ok, user_session} = PlausibleWeb.UserAuth.get_user_session(conn)
+ user_session |> Ecto.Changeset.change(timeout_at: in_the_past) |> Plausible.Repo.update!()
+
+ conn =
+ conn
+ |> Plug.Adapters.Test.Conn.conn(:get, "/", %{})
+ |> AuthPlug.call(%{})
+
+ refute conn.assigns[:current_user]
+ refute conn.assigns[:current_team]
+ assert conn.assigns[:expired_session].id == user_session.id
+ end
end
diff --git a/test/plausible_web/plugs/handle_expired_session_test.exs b/test/plausible_web/plugs/handle_expired_session_test.exs
new file mode 100644
index 0000000000..37752bdb44
--- /dev/null
+++ b/test/plausible_web/plugs/handle_expired_session_test.exs
@@ -0,0 +1,78 @@
+defmodule Plausible.Plugs.HandleExpiredSessionTest do
+ use PlausibleWeb.ConnCase, async: true
+ use Plausible
+
+ on_ee do
+ use Plausible.Teams.Test
+
+ alias Plausible.Auth.UserSessions
+ alias Plausible.Plugs.HandleExpiredSession
+ alias Plausible.Repo
+
+ alias PlausibleWeb.Router.Helpers, as: Routes
+
+ test "passes through when there's no expired_session" do
+ conn = HandleExpiredSession.call(build_conn(), [])
+ refute conn.halted
+ end
+
+ test "passes through when the expired session belongs to standard user" do
+ user = new_user()
+ in_the_past = NaiveDateTime.add(NaiveDateTime.utc_now(:second), -1, :hour)
+ session = UserSessions.create!(user, "Unknown", timeout_at: in_the_past)
+
+ conn =
+ build_conn()
+ |> assign(:expired_session, session)
+ |> HandleExpiredSession.call([])
+
+ refute conn.halted
+ assert Repo.reload(session)
+ end
+
+ test "halts and redirects to login for expired session of SSO user with return" do
+ user = new_user(type: :sso)
+ in_the_past = NaiveDateTime.add(NaiveDateTime.utc_now(:second), -1, :hour)
+ session = UserSessions.create!(user, "Unknown", timeout_at: in_the_past)
+
+ conn =
+ build_conn(:get, "/some/url", %{with: "param"})
+ |> assign(:expired_session, session)
+ |> HandleExpiredSession.call([])
+
+ assert conn.halted
+
+ assert redirected_to(conn, 302) ==
+ Routes.sso_path(conn, :login_form,
+ prefer: "manual",
+ email: user.email,
+ autosubmit: true,
+ return_to: "/some/url?with=param"
+ )
+
+ refute Repo.reload(session)
+ end
+
+ test "halts and redirects to login without redirect if request method other than GET" do
+ user = new_user(type: :sso)
+ in_the_past = NaiveDateTime.add(NaiveDateTime.utc_now(:second), -1, :hour)
+ session = UserSessions.create!(user, "Unknown", timeout_at: in_the_past)
+
+ conn =
+ build_conn(:post, "/some/url")
+ |> assign(:expired_session, session)
+ |> HandleExpiredSession.call([])
+
+ assert conn.halted
+
+ assert redirected_to(conn, 302) ==
+ Routes.sso_path(conn, :login_form,
+ prefer: "manual",
+ email: user.email,
+ autosubmit: true
+ )
+
+ refute Repo.reload(session)
+ end
+ end
+end
diff --git a/test/plausible_web/user_auth_test.exs b/test/plausible_web/user_auth_test.exs
index fbf5dd4673..db10c11d91 100644
--- a/test/plausible_web/user_auth_test.exs
+++ b/test/plausible_web/user_auth_test.exs
@@ -293,10 +293,7 @@ defmodule PlausibleWeb.UserAuthTest do
assert {:error, :no_valid_token} = UserAuth.get_user_session(%{"current_user_id" => 123})
end
- test "returns error on missing session", %{
- conn: conn,
- user: user
- } do
+ test "returns error on missing session", %{conn: conn, user: user} do
%{sessions: [user_session]} = Repo.preload(user, :sessions)
Repo.delete!(user_session)
@@ -305,6 +302,16 @@ defmodule PlausibleWeb.UserAuthTest do
assert {:error, :session_not_found} =
UserAuth.get_user_session(%{"user_token" => user_session.token})
end
+
+ test "returns error on expired session", %{conn: conn} do
+ now = NaiveDateTime.utc_now(:second)
+ in_the_past = NaiveDateTime.add(now, -1, :hour)
+ {:ok, user_session} = UserAuth.get_user_session(conn)
+ user_session |> Ecto.Changeset.change(timeout_at: in_the_past) |> Repo.update!()
+
+ assert {:error, :session_expired, expired_session} = UserAuth.get_user_session(conn)
+ assert expired_session.id == user_session.id
+ end
end
describe "set_logged_in_cookie/1" do