Skip to content

Open source, privacy-first web analytics. Lightweight, cookie-free Google Analytics alternative. Self-hosted or cloud.

Move shared link form to modal (#5849)

Sanne de Vriesd7c641e6a6f3
diff --git a/extra/lib/plausible_web/live/customer_support/team/components/audit.ex b/extra/lib/plausible_web/live/customer_support/team/components/audit.ex
index 729e103c8d..937aee3a27 100644
--- a/extra/lib/plausible_web/live/customer_support/team/components/audit.ex
+++ b/extra/lib/plausible_web/live/customer_support/team/components/audit.ex
@@ -109,7 +109,6 @@ defmodule PlausibleWeb.CustomerSupport.Team.Components.Audit do
<.td actions>
<.edit_button
phx-click="reveal-audit-entry"
- icon={:magnifying_glass_plus}
phx-value-id={entry.id}
phx-target={@myself}
/>
diff --git a/lib/plausible_web/components/generic.ex b/lib/plausible_web/components/generic.ex
index 0c0d263ce6..34eac55db2 100644
--- a/lib/plausible_web/components/generic.ex
+++ b/lib/plausible_web/components/generic.ex
@@ -366,7 +366,7 @@ defmodule PlausibleWeb.Components.Generic do
attr(:href, :string, required: true)
attr(:new_tab, :boolean, default: false)
- attr(:class, :string, default: nil)
+ attr(:class, :string, default: "")
attr(:rest, :global)
attr(:method, :string, default: "get")
slot(:inner_block)
@@ -795,7 +795,7 @@ defmodule PlausibleWeb.Components.Generic do
]}
{@rest}
>
- <div :if={@actions} class="flex gap-2">
+ <div :if={@actions} class="flex gap-1">
{render_slot(@inner_block)}
</div>
<div :if={!@actions}>
@@ -864,26 +864,107 @@ defmodule PlausibleWeb.Components.Generic do
"""
end
- attr :href, :string, default: nil
- attr :icon, :atom, default: :pencil_square
+ attr :href, :string, required: false
+ attr :icon_name, :atom, required: false
+ attr :theme, :string, default: "default"
+ attr :class, :string, default: ""
+ attr :icon_class, :string, default: ""
+ attr :size, :string, default: "4"
attr :rest, :global, include: ~w(method disabled)
- def edit_button(assigns) do
+ slot :inner_block, required: false
+
+ def icon_button(assigns) do
+ icon_source =
+ case {assigns.inner_block, assigns[:icon_name]} do
+ {[], nil} ->
+ raise ArgumentError,
+ "Either `icon_name` attribute or icon inner block must be provided"
+
+ {[_ | _], icon_name} when not is_nil(icon_name) ->
+ raise ArgumentError, "Only one of `icon_name` and icon inner block must be provided"
+
+ {[_ | _], nil} ->
+ :inner_block
+
+ {[], icon_name} when not is_nil(icon_name) ->
+ :icon_name
+ end
+
+ text =
+ case assigns.theme do
+ "default" ->
+ %{
+ light: "text-indigo-700",
+ light_hover: "text-indigo-600",
+ dark: "text-indigo-500",
+ dark_hover: "text-indigo-400"
+ }
+
+ "danger" ->
+ %{
+ light: "text-red-700",
+ light_hover: "text-red-500",
+ dark: "text-red-500",
+ dark_hover: "text-red-400"
+ }
+
+ _ ->
+ raise ArgumentError, "Invalid `theme` provided"
+ end
+
+ button_class = [
+ "group/button",
+ "w-fit h-fit",
+ "p-2",
+ "hover:bg-gray-100",
+ "dark:hover:bg-gray-800",
+ "rounded-md",
+ "transition-colors",
+ "duration-150",
+ assigns.class
+ ]
+
+ icon_class = [
+ "size-#{assigns.size}",
+ text.light,
+ "group-hover/button:" <> text.light_hover,
+ "dark:" <> text.dark,
+ "dark:group-hover/button:" <> text.dark_hover,
+ "transition-colors",
+ "duration-150",
+ assigns.icon_class
+ ]
+
+ assigns =
+ assigns
+ |> assign(:icon_source, icon_source)
+ |> assign(:button_class, button_class)
+ |> assign(:icon_class, icon_class)
+
if assigns[:href] do
~H"""
- <.unstyled_link href={@href} {@rest}>
+ <.unstyled_link href={@href} class={@button_class} {@rest}>
+ <span :if={@icon_source == :inner_block}>
+ {render_slot(@inner_block, @icon_class)}
+ </span>
<.dynamic_icon
- name={@icon}
- class="size-5 text-indigo-700 hover:text-indigo-500 dark:text-indigo-500 dark:hover:text-indigo-300"
+ :if={@icon_source == :icon_name}
+ name={@icon_name}
+ class={@icon_class}
/>
</.unstyled_link>
"""
else
~H"""
- <button {@rest}>
+ <button class={@button_class} {@rest}>
+ <span :if={@icon_source == :inner_block}>
+ {render_slot(@inner_block, @icon_class)}
+ </span>
<.dynamic_icon
- name={@icon}
- class="size-5 text-indigo-700 hover:text-indigo-500 dark:text-indigo-500 dark:hover:text-indigo-300"
+ :if={@icon_source == :icon_name}
+ name={@icon_name}
+ class={@icon_class}
/>
</button>
"""
@@ -891,29 +972,45 @@ defmodule PlausibleWeb.Components.Generic do
end
attr :href, :string, default: nil
+ attr :class, :string, default: ""
+ attr :rest, :global, include: ~w(method disabled)
+
+ def edit_button(assigns) do
+ ~H"""
+ <.icon_button :let={icon_class} href={@href} class={@class} {@rest}>
+ <svg
+ xmlns="http://www.w3.org/2000/svg"
+ fill="none"
+ viewBox="0 0 24 24"
+ class={icon_class}
+ >
+ <path
+ stroke="currentColor"
+ stroke-linecap="round"
+ stroke-linejoin="round"
+ stroke-width="1.5"
+ d="m13.25 6.25 2.836-2.836a2 2 0 0 1 2.828 0l1.672 1.672a2 2 0 0 1 0 2.828L17.75 10.75m-4.5-4.5-9.914 9.914a2 2 0 0 0-.586 1.415v3.671h3.672a2 2 0 0 0 1.414-.586l9.914-9.914m-4.5-4.5 4.5 4.5"
+ />
+ </svg>
+ </.icon_button>
+ """
+ end
+
+ attr :href, :string, default: nil
+ attr :class, :string, default: ""
attr :icon, :atom, default: :trash
attr :rest, :global, include: ~w(method disabled)
def delete_button(assigns) do
- if assigns[:href] do
- ~H"""
- <.unstyled_link href={@href} {@rest}>
- <.dynamic_icon
- name={@icon}
- class="size-5 text-red-700 hover:text-red-500 dark:text-red-500 dark:hover:text-red-400"
- />
- </.unstyled_link>
- """
- else
- ~H"""
- <button {@rest}>
- <.dynamic_icon
- name={@icon}
- class="size-5 text-red-700 hover:text-red-500 dark:text-red-500 dark:hover:text-red-400"
- />
- </button>
- """
- end
+ ~H"""
+ <.icon_button
+ icon_name={@icon}
+ theme="danger"
+ class={@class}
+ href={@href}
+ {@rest}
+ />
+ """
end
attr :filter_text, :string, default: ""
diff --git a/lib/plausible_web/controllers/site_controller.ex b/lib/plausible_web/controllers/site_controller.ex
index 4c99f17d17..8f9e1f67f2 100644
--- a/lib/plausible_web/controllers/site_controller.ex
+++ b/lib/plausible_web/controllers/site_controller.ex
@@ -163,19 +163,11 @@ defmodule PlausibleWeb.SiteController do
def settings_visibility(conn, _params) do
site = conn.assigns[:site]
- shared_links =
- Repo.all(
- from(l in Plausible.Site.SharedLink,
- where:
- l.site_id == ^site.id and l.name not in ^Plausible.Sites.shared_link_special_names()
- )
- )
-
conn
|> render("settings_visibility.html",
site: site,
- shared_links: shared_links,
dogfood_page_path: "/:dashboard/settings/visibility",
+ connect_live_socket: true,
layout: {PlausibleWeb.LayoutView, "site_settings.html"}
)
end
@@ -569,94 +561,6 @@ defmodule PlausibleWeb.SiteController do
|> redirect(to: Routes.site_path(conn, :settings_email_reports, site.domain))
end
- def new_shared_link(conn, _params) do
- site = conn.assigns[:site]
- changeset = Plausible.Site.SharedLink.changeset(%Plausible.Site.SharedLink{}, %{})
-
- conn
- |> assign(:skip_plausible_tracking, true)
- |> render("new_shared_link.html",
- site: site,
- changeset: changeset
- )
- end
-
- def create_shared_link(conn, %{"shared_link" => link}) do
- site = conn.assigns[:site]
-
- case Sites.create_shared_link(site, link["name"], password: link["password"]) do
- {:ok, _created} ->
- redirect(conn, to: Routes.site_path(conn, :settings_visibility, site.domain))
-
- {:error, :upgrade_required} ->
- conn
- |> put_flash(:error, "Your current subscription plan does not include Shared Links")
- |> redirect(to: Routes.site_path(conn, :settings_visibility, site.domain))
-
- {:error, changeset} ->
- conn
- |> assign(:skip_plausible_tracking, true)
- |> render("new_shared_link.html",
- site: site,
- changeset: changeset
- )
- end
- end
-
- def edit_shared_link(conn, %{"slug" => slug}) do
- site = conn.assigns[:site]
- shared_link = Repo.get_by(Plausible.Site.SharedLink, slug: slug)
- changeset = Plausible.Site.SharedLink.changeset(shared_link, %{})
-
- conn
- |> assign(:skip_plausible_tracking, true)
- |> render("edit_shared_link.html",
- site: site,
- changeset: changeset
- )
- end
-
- def update_shared_link(conn, %{"slug" => slug, "shared_link" => params}) do
- site = conn.assigns[:site]
- shared_link = Repo.get_by(Plausible.Site.SharedLink, slug: slug)
- changeset = Plausible.Site.SharedLink.changeset(shared_link, params)
-
- case Repo.update(changeset) do
- {:ok, _updated} ->
- redirect(conn, to: Routes.site_path(conn, :settings_visibility, site.domain))
-
- {:error, changeset} ->
- conn
- |> assign(:skip_plausible_tracking, true)
- |> render("edit_shared_link.html",
- site: site,
- changeset: changeset
- )
- end
- end
-
- def delete_shared_link(conn, %{"slug" => slug}) do
- site = conn.assigns[:site]
- site_id = site.id
-
- case Repo.delete_all(
- from(l in Plausible.Site.SharedLink,
- where: l.slug == ^slug,
- where: l.site_id == ^site_id
- )
- ) do
- {1, _} ->
- conn
- |> put_flash(:success, "Shared Link deleted")
- |> redirect(to: Routes.site_path(conn, :settings_visibility, site.domain))
-
- {0, _} ->
- conn
- |> put_flash(:error, "Could not find Shared Link")
- |> redirect(to: Routes.site_path(conn, :settings_visibility, site.domain))
- end
- end
-
def forget_import(conn, %{"import_id" => import_id}) do
site = conn.assigns.site
diff --git a/lib/plausible_web/live/components/form.ex b/lib/plausible_web/live/components/form.ex
index 0a2be22ec1..314937fe6c 100644
--- a/lib/plausible_web/live/components/form.ex
+++ b/lib/plausible_web/live/components/form.ex
@@ -232,7 +232,7 @@ defmodule PlausibleWeb.Live.Components.Form do
href="javascript:void(0)"
class="absolute flex items-center text-xs font-medium text-indigo-600 dark:text-indigo-500 no-underline hover:text-indigo-700 dark:hover:text-indigo-400 top-3 right-4 transition-colors duration-150"
>
- <Heroicons.document_duplicate class="pr-1 size-5" />
+ <Heroicons.document_duplicate class="mr-1 size-4" />
<span>
COPY
</span>
diff --git a/lib/plausible_web/live/goal_settings/list.ex b/lib/plausible_web/live/goal_settings/list.ex
index 93d4457722..1153c95994 100644
--- a/lib/plausible_web/live/goal_settings/list.ex
+++ b/lib/plausible_web/live/goal_settings/list.ex
@@ -68,13 +68,14 @@ defmodule PlausibleWeb.Live.GoalSettings.List do
x-on:click={Modal.JS.preopen("goals-form-modal")}
phx-click="edit-goal"
phx-value-goal-id={goal.id}
+ class="mt-1"
id={"edit-goal-#{goal.id}"}
/>
<.edit_button
:if={goal.currency && !@revenue_goals_enabled?}
id={"edit-goal-#{goal.id}-disabled"}
disabled
- class="cursor-not-allowed"
+ class="cursor-not-allowed mt-1"
/>
<.delete_button
id={"delete-goal-#{goal.id}"}
@@ -82,6 +83,7 @@ defmodule PlausibleWeb.Live.GoalSettings.List do
phx-value-goal-id={goal.id}
phx-value-goal-name={goal.event_name}
data-confirm={delete_confirmation_text(goal)}
+ class="mt-1"
/>
</.td>
</:tbody>
diff --git a/lib/plausible_web/live/shared_link_settings.ex b/lib/plausible_web/live/shared_link_settings.ex
new file mode 100644
index 0000000000..5bd7152d28
--- /dev/null
+++ b/lib/plausible_web/live/shared_link_settings.ex
@@ -0,0 +1,184 @@
+defmodule PlausibleWeb.Live.SharedLinkSettings do
+ @moduledoc """
+ LiveView allowing listing, creating and deleting shared links.
+ """
+ use PlausibleWeb, :live_view
+
+ alias PlausibleWeb.Live.Components.Modal
+ import Ecto.Query
+
+ def mount(
+ _params,
+ %{"site_id" => site_id, "domain" => domain},
+ socket
+ ) do
+ socket =
+ socket
+ |> assign_new(:site, fn %{current_user: current_user} ->
+ current_user
+ |> Plausible.Sites.get_for_user!(domain, roles: [:owner, :admin, :editor, :super_admin])
+ end)
+ |> assign_new(:shared_links, fn %{site: site} ->
+ Plausible.Repo.all(
+ from(l in Plausible.Site.SharedLink,
+ where:
+ l.site_id == ^site.id and l.name not in ^Plausible.Sites.shared_link_special_names(),
+ order_by: [desc: l.id]
+ )
+ )
+ end)
+
+ {:ok,
+ assign(socket,
+ site_id: site_id,
+ domain: domain,
+ form_shared_link: nil
+ )}
+ end
+
+ def render(assigns) do
+ ~H"""
+ <div id="shared-link-settings-main">
+ <.flash_messages flash={@flash} />
+
+ <.live_component
+ :let={modal_unique_id}
+ module={Modal}
+ preload?={false}
+ id="shared-links-form-modal"
+ >
+ <.live_component
+ module={PlausibleWeb.Live.SharedLinkSettings.Form}
+ id={"shared-links-form-#{modal_unique_id}"}
+ context_unique_id={modal_unique_id}
+ site={@site}
+ shared_link={@form_shared_link}
+ on_save_shared_link={
+ fn shared_link, socket ->
+ send(self(), {:shared_link_added, shared_link})
+ Modal.close(socket, "shared-links-form-modal")
+ end
+ }
+ />
+ </.live_component>
+
+ <.filter_bar filtering_enabled?={false}>
+ <.button
+ id="add-shared-link-button"
+ phx-click="add-shared-link"
+ mt?={false}
+ x-data
+ x-on:click={Modal.JS.preopen("shared-links-form-modal")}
+ >
+ Add shared link
+ </.button>
+ </.filter_bar>
+
+ <p :if={Enum.empty?(@shared_links)} class="mb-8 text-center text-sm">
+ No shared links configured for this site.
+ </p>
+
+ <.table rows={@shared_links} id="shared-links-table">
+ <:thead>
+ <.th hide_on_mobile>Name</.th>
+ <.th>Link</.th>
+ <.th invisible>Actions</.th>
+ </:thead>
+ <:tbody :let={link}>
+ <.td truncate hide_on_mobile>
+ {link.name}
+ <Heroicons.lock_closed :if={link.password_hash} class="feather ml-2 mb-0.5" />
+ <Heroicons.lock_open :if={!link.password_hash} class="feather ml-2 mb-0.5" />
+ </.td>
+ <.td>
+ <.input_with_clipboard
+ name={link.slug}
+ id={link.slug}
+ value={shared_link_dest(@site, link)}
+ />
+ </.td>
+ <.td actions>
+ <.edit_button
+ class="mt-1"
+ phx-click="edit-shared-link"
+ phx-value-slug={link.slug}
+ />
+ <.delete_button
+ class="mt-1"
+ phx-click="delete-shared-link"
+ phx-value-slug={link.slug}
+ data-confirm="Are you sure you want to delete this shared link? The stats will not be accessible with this link anymore."
+ />
+ </.td>
+ </:tbody>
+ </.table>
+ </div>
+ """
+ end
+
+ def handle_event("add-shared-link", _, socket) do
+ socket = socket |> assign(form_shared_link: nil) |> Modal.open("shared-links-form-modal")
+ {:noreply, socket}
+ end
+
+ def handle_event("edit-shared-link", %{"slug" => slug}, socket) do
+ shared_link = Plausible.Repo.get_by(Plausible.Site.SharedLink, slug: slug)
+
+ socket =
+ socket |> assign(form_shared_link: shared_link) |> Modal.open("shared-links-form-modal")
+
+ {:noreply, socket}
+ end
+
+ def handle_event("delete-shared-link", %{"slug" => slug}, socket) do
+ site_id = socket.assigns.site.id
+
+ case Plausible.Repo.delete_all(
+ from(l in Plausible.Site.SharedLink,
+ where: l.slug == ^slug,
+ where: l.site_id == ^site_id
+ )
+ ) do
+ {1, _} ->
+ socket =
+ socket
+ |> put_live_flash(:success, "Shared link deleted")
+ |> assign(shared_links: Enum.reject(socket.assigns.shared_links, &(&1.slug == slug)))
+
+ {:noreply, socket}
+
+ {0, _} ->
+ socket =
+ socket
+ |> put_live_flash(:error, "Could not find Shared Link")
+
+ {:noreply, socket}
+ end
+ end
+
+ def handle_info({:shared_link_added, _shared_link}, socket) do
+ shared_links =
+ Plausible.Repo.all(
+ from(l in Plausible.Site.SharedLink,
+ where:
+ l.site_id == ^socket.assigns.site.id and
+ l.name not in ^Plausible.Sites.shared_link_special_names(),
+ order_by: [desc: l.id]
+ )
+ )
+
+ socket =
+ socket
+ |> assign(
+ shared_links: shared_links,
+ form_shared_link: nil
+ )
+ |> put_live_flash(:success, "Shared link saved")
+
+ {:noreply, socket}
+ end
+
+ defp shared_link_dest(site, link) do
+ Routes.stats_path(PlausibleWeb.Endpoint, :shared_link, site.domain, auth: link.slug)
+ end
+end
diff --git a/lib/plausible_web/live/shared_link_settings/form.ex b/lib/plausible_web/live/shared_link_settings/form.ex
new file mode 100644
index 0000000000..40a0e2b5b7
--- /dev/null
+++ b/lib/plausible_web/live/shared_link_settings/form.ex
@@ -0,0 +1,112 @@
+defmodule PlausibleWeb.Live.SharedLinkSettings.Form do
+ @moduledoc """
+ Live view for the shared link creation form
+ """
+ use PlausibleWeb, :live_component
+ use Plausible
+
+ alias Plausible.Sites
+
+ def update(assigns, socket) do
+ form =
+ (assigns.shared_link || %Plausible.Site.SharedLink{})
+ |> Plausible.Site.SharedLink.changeset(%{})
+ |> to_form()
+
+ socket =
+ socket
+ |> assign(
+ id: assigns.id,
+ context_unique_id: assigns.context_unique_id,
+ form: form,
+ site: assigns.site,
+ shared_link: assigns.shared_link,
+ on_save_shared_link: assigns.on_save_shared_link
+ )
+
+ {:ok, socket}
+ end
+
+ def render(assigns) do
+ ~H"""
+ <div id={@id}>
+ {if @shared_link, do: edit_form(assigns)}
+ {if is_nil(@shared_link), do: create_form(assigns)}
+ </div>
+ """
+ end
+
+ def edit_form(assigns) do
+ ~H"""
+ <.form :let={f} for={@form} phx-submit="save-shared-link" phx-target={@myself}>
+ <.title>Edit shared link</.title>
+
+ <.input field={f[:name]} label="Name" required="required" autocomplete="off" />
+
+ <.button type="submit" class="w-full">
+ Update shared link
+ </.button>
+ </.form>
+ """
+ end
+
+ def create_form(assigns) do
+ ~H"""
+ <.form :let={f} for={@form} phx-submit="save-shared-link" phx-target={@myself}>
+ <.title>New shared link</.title>
+ <.input field={f[:name]} label="Name" required="required" autocomplete="off" />
+ <.input
+ field={f[:password]}
+ label="Password (optional)"
+ type="password"
+ autocomplete="new-password"
+ />
+
+ <.button type="submit" class="w-full">
+ Create shared link
+ </.button>
+ </.form>
+ """
+ end
+
+ def handle_event(
+ "save-shared-link",
+ %{"shared_link" => shared_link_params},
+ %{assigns: %{shared_link: nil}} = socket
+ ) do
+ case Sites.create_shared_link(socket.assigns.site, shared_link_params["name"],
+ password: shared_link_params["password"]
+ ) do
+ {:ok, shared_link} ->
+ socket = socket.assigns.on_save_shared_link.(shared_link, socket)
+ {:noreply, socket}
+
+ {:error, :upgrade_required} ->
+ socket =
+ socket
+ |> put_flash(:error, "Your current subscription plan does not include Shared Links")
+
+ {:noreply, socket}
+
+ {:error, changeset} ->
+ {:noreply, assign(socket, form: to_form(changeset))}
+ end
+ end
+
+ def handle_event(
+ "save-shared-link",
+ %{"shared_link" => shared_link_params},
+ %{assigns: %{shared_link: %Plausible.Site.SharedLink{} = shared_link}} = socket
+ ) do
+ changeset = Plausible.Site.SharedLink.changeset(shared_link, shared_link_params)
+
+ case Plausible.Repo.update(changeset) do
+ {:ok, updated_shared_link} ->
+ socket = socket.assigns.on_save_shared_link.(updated_shared_link, socket)
+ {:noreply, socket}
+
+ {:error, changeset} ->
+ {:noreply, assign(socket, form: to_form(changeset))}
+ end
+ end
+end
diff --git a/lib/plausible_web/router.ex b/lib/plausible_web/router.ex
index 15b9cd7c24..386e849f0b 100644
--- a/lib/plausible_web/router.ex
+++ b/lib/plausible_web/router.ex
@@ -595,12 +595,6 @@ defmodule PlausibleWeb.Router do
SiteController,
:remove_traffic_change_notification_recipient
- get "/sites/:domain/shared-links/new", SiteController, :new_shared_link
- post "/sites/:domain/shared-links", SiteController, :create_shared_link
- get "/sites/:domain/shared-links/:slug/edit", SiteController, :edit_shared_link
- put "/sites/:domain/shared-links/:slug", SiteController, :update_shared_link
- delete "/sites/:domain/shared-links/:slug", SiteController, :delete_shared_link
-
get "/sites/:domain/memberships/invite", Site.MembershipController, :invite_member_form
post "/sites/:domain/memberships/invite", Site.MembershipController, :invite_member
diff --git a/lib/plausible_web/templates/site/edit_shared_link.html.heex b/lib/plausible_web/templates/site/edit_shared_link.html.heex
deleted file mode 100644
index b448597c5a..0000000000
--- a/lib/plausible_web/templates/site/edit_shared_link.html.heex
+++ /dev/null
@@ -1,14 +0,0 @@
-<.focus_box>
- <:title>Edit Shared Link</:title>
-
- <.form
- :let={f}
- for={@changeset}
- action={"/sites/#{URI.encode_www_form(@site.domain)}/shared-links/#{@changeset.data.slug}"}
- class=""
- >
- <.input type="text" field={f[:name]} label="Name" />
-
- <.button class="w-full" type="submit">Update</.button>
- </.form>
-</.focus_box>
diff --git a/lib/plausible_web/templates/site/membership/transfer_ownership_form.html.heex b/lib/plausible_web/templates/site/membership/transfer_ownership_form.html.heex
index 8a889988e6..489777e641 100644
--- a/lib/plausible_web/templates/site/membership/transfer_ownership_form.html.heex
+++ b/lib/plausible_web/templates/site/membership/transfer_ownership_form.html.heex
@@ -18,7 +18,7 @@
action={Routes.membership_path(@conn, :transfer_ownership, @site.domain)}
>
<%= if @conn.assigns[:error] do %>
- <div class="text-red-500 text-xs italic mt-4">{@conn.assigns[:error]}</div>
+ <div class="text-red-500 text-xs mt-1">{@conn.assigns[:error]}</div>
<% end %>
<div class="my-6">
diff --git a/lib/plausible_web/templates/site/new_shared_link.html.heex b/lib/plausible_web/templates/site/new_shared_link.html.heex
deleted file mode 100644
index 751def297e..0000000000
--- a/lib/plausible_web/templates/site/new_shared_link.html.heex
+++ /dev/null
@@ -1,24 +0,0 @@
-<.focus_box>
- <:title>New shared link</:title>
- <:subtitle>
- Password protection is optional. Please make sure you save it in a secure place. Once the link is created, we cannot reveal the password.
- </:subtitle>
- <.form
- :let={f}
- for={@changeset}
- action={"/sites/#{URI.encode_www_form(@site.domain)}/shared-links"}
- >
- <div class="flex flex-col gap-y-4">
- <.input field={f[:name]} label="Name" required="required" autocomplete="off" mt?={false} />
- <.input
- field={f[:password]}
- label="Password (optional)"
- type="password"
- autocomplete="new-password"
- mt?={false}
- />
-
- <.button class="w-full mt-4" type="submit" mt?={false}>Create shared link</.button>
- </div>
- </.form>
-</.focus_box>
diff --git a/lib/plausible_web/templates/site/settings_visibility.html.heex b/lib/plausible_web/templates/site/settings_visibility.html.heex
index c2aaaef11f..05bc17b596 100644
--- a/lib/plausible_web/templates/site/settings_visibility.html.heex
+++ b/lib/plausible_web/templates/site/settings_visibility.html.heex
@@ -42,49 +42,11 @@
You can share your stats privately by generating a shared link. The links are impossible to guess and you can add password protection for extra security.
</:subtitle>
- <.filter_bar filtering_enabled?={false}>
- <.button_link href={Routes.site_path(@conn, :new_shared_link, @site.domain)} mt?={false}>
- Add Shared Link
- </.button_link>
- </.filter_bar>
-
- <p :if={Enum.empty?(@shared_links)} class="mb-8 text-center text-sm">
- No Shared Links configured for this site.
- </p>
-
- <.table rows={@shared_links} id="shared-links-table">
- <:thead>
- <.th hide_on_mobile>Name</.th>
- <.th>Link</.th>
- <.th invisible>Actions</.th>
- </:thead>
- <:tbody :let={link}>
- <.td truncate hide_on_mobile>
- {link.name}
- <Heroicons.lock_closed :if={link.password_hash} class="w-6 h-6 feather ml-2" />
- <Heroicons.lock_open :if={!link.password_hash} class="w-6 h-6 feather ml-2" />
- </.td>
- <.td>
- <.input_with_clipboard
- name={link.slug}
- id={link.slug}
- value={shared_link_dest(@site, link)}
- />
- </.td>
- <.td actions>
- <.edit_button
- class="mt-2"
- href={Routes.site_path(@conn, :edit_shared_link, @site.domain, link.slug)}
- />
- <.delete_button
- class="mt-2"
- method="delete"
- href={Routes.site_path(@conn, :delete_shared_link, @site.domain, link.slug)}
- data-confirm="Are you sure you want to delete this shared link? The stats will not be accessible with this link anymore."
- />
- </.td>
- </:tbody>
- </.table>
+ <div :if={Plausible.Billing.Feature.SharedLinks.enabled?(@site)}>
+ {live_render(@conn, PlausibleWeb.Live.SharedLinkSettings,
+ session: %{"site_id" => @site.id, "domain" => @site.domain}
+ )}
+ </div>
</.tile>
<.tile
diff --git a/lib/plausible_web/templates/stats/shared_link_password.html.heex b/lib/plausible_web/templates/stats/shared_link_password.html.heex
index a2ed6ed0bf..ed5b629971 100644
--- a/lib/plausible_web/templates/stats/shared_link_password.html.heex
+++ b/lib/plausible_web/templates/stats/shared_link_password.html.heex
@@ -13,7 +13,7 @@
<.input type="password" field={f[:password]} />
<%= if @conn.assigns[:error] do %>
- <div class="text-red-500 text-xs italic mt-4">{@conn.assigns[:error]}</div>
+ <div class="text-red-500 text-xs mt-1">{@conn.assigns[:error]}</div>
<% end %>
</div>
diff --git a/test/plausible_web/controllers/site_controller_test.exs b/test/plausible_web/controllers/site_controller_test.exs
index f12c0a957b..33928903ee 100644
--- a/test/plausible_web/controllers/site_controller_test.exs
+++ b/test/plausible_web/controllers/site_controller_test.exs
@@ -685,6 +685,47 @@ defmodule PlausibleWeb.SiteControllerTest do
describe "GET /:domain/settings/visibility" do
setup [:create_user, :log_in, :create_site]
+ setup %{user: user} do
+ subscribe_to_growth_plan(user)
+ :ok
+ end
+
+ test "shows shared links section", %{conn: conn, site: site} do
+ conn = get(conn, "/#{site.domain}/settings/visibility")
+
+ resp = html_response(conn, 200)
+ assert resp =~ "Add shared link"
+ assert element_exists?(resp, ~s/button#add-shared-link-button/)
+ end
+
+ test "lists shared links with actions", %{conn: conn, site: site} do
+ link1 = insert(:shared_link, site: site, name: "Link 1")
+ link2 = insert(:shared_link, site: site, name: "Link 2")
+
+ conn = get(conn, "/#{site.domain}/settings/visibility")
+ resp = html_response(conn, 200)
+
+ assert resp =~ "Link 1"
+ assert resp =~ "Link 2"
+
+ assert element_exists?(
+ resp,
+ ~s/button[phx-click="edit-shared-link"][phx-value-slug="#{link1.slug}"]/
+ )
+
+ assert element_exists?(
+ resp,
+ ~s/button[phx-click="delete-shared-link"][phx-value-slug="#{link2.slug}"]/
+ )
+ end
+
+ test "shows message when no shared links are configured", %{conn: conn, site: site} do
+ conn = get(conn, "/#{site.domain}/settings/visibility")
+ resp = html_response(conn, 200)
+
+ assert resp =~ "No shared links configured for this site"
+ end
+
test "does not render shared links with special names", %{conn: conn, site: site} do
for special_name <- Plausible.Sites.shared_link_special_names() do
insert(:shared_link, name: special_name, site: site)
@@ -1599,141 +1640,6 @@ defmodule PlausibleWeb.SiteControllerTest do
end
end
- describe "GET /sites/:domain/shared-links/new" do
- setup [:create_user, :log_in, :create_site]
-
- test "shows form for new shared link", %{conn: conn, site: site} do
- conn = get(conn, "/sites/#{site.domain}/shared-links/new")
-
- assert html_response(conn, 200) =~ "New shared link"
- end
- end
-
- describe "POST /sites/:domain/shared-links" do
- setup [:create_user, :log_in, :create_site]
-
- test "creates shared link without password", %{conn: conn, site: site} do
- post(conn, "/sites/#{site.domain}/shared-links", %{
- "shared_link" => %{"name" => "Link name"}
- })
-
- link = Repo.one(Plausible.Site.SharedLink)
-
- refute is_nil(link.slug)
- assert is_nil(link.password_hash)
- assert link.name == "Link name"
- end
-
- test "creates shared link with password", %{conn: conn, site: site} do
- post(conn, "/sites/#{site.domain}/shared-links", %{
- "shared_link" => %{"password" => "password", "name" => "New name"}
- })
-
- link = Repo.one(Plausible.Site.SharedLink)
-
- refute is_nil(link.slug)
- refute is_nil(link.password_hash)
- assert link.name == "New name"
- end
-
- test "fails to create when subscription plan doesn't support the shared links feature", %{
- conn: conn,
- user: user,
- site: site
- } do
- subscribe_to_starter_plan(user)
-
- conn =
- post(conn, "/sites/#{site.domain}/shared-links", %{
- "shared_link" => %{"name" => "Something"}
- })
-
- assert redirected_to(conn, 302) == Routes.site_path(conn, :settings_visibility, site.domain)
-
- assert Phoenix.Flash.get(conn.assigns.flash, :error) =~
- "Your current subscription plan does not include Shared Links"
-
- refute Repo.exists?(Plausible.Site.SharedLink)
- end
-
- for special_name <- Plausible.Sites.shared_link_special_names() do
- test "fails to create with the special '#{special_name}' name intended for Plugins API",
- %{conn: conn, site: site} do
- conn =
- post(conn, "/sites/#{site.domain}/shared-links", %{
- "shared_link" => %{"name" => unquote(special_name)}
- })
-
- assert html_response(conn, 200) =~ "This name is reserved. Please choose another one"
- refute Repo.exists?(Plausible.Site.SharedLink)
- end
- end
- end
-
- describe "GET /sites/:domain/shared-links/edit" do
- setup [:create_user, :log_in, :create_site]
-
- test "shows form to edit shared link", %{conn: conn, site: site} do
- link = insert(:shared_link, site: site)
- conn = get(conn, "/sites/#{site.domain}/shared-links/#{link.slug}/edit")
-
- assert html_response(conn, 200) =~ "Edit Shared Link"
- end
- end
-
- describe "PUT /sites/:domain/shared-links/:slug" do
- setup [:create_user, :log_in, :create_site]
-
- test "can update link name", %{conn: conn, site: site} do
- link = insert(:shared_link, site: site)
-
- put(conn, "/sites/#{site.domain}/shared-links/#{link.slug}", %{
- "shared_link" => %{"name" => "Updated link name"}
- })
-
- link = Repo.one(Plausible.Site.SharedLink)
-
- assert link.name == "Updated link name"
- end
-
- for special_name <- Plausible.Sites.shared_link_special_names() do
- test "fails to change link name to #{special_name}", %{conn: conn, site: site} do
- link = insert(:shared_link, site: site)
-
- conn =
- put(conn, "/sites/#{site.domain}/shared-links/#{link.slug}", %{
- "shared_link" => %{"name" => unquote(special_name)}
- })
-
- assert html_response(conn, 200) =~ "This name is reserved. Please choose another one"
- end
- end
- end
-
- describe "DELETE /sites/:domain/shared-links/:slug" do
- setup [:create_user, :log_in, :create_site]
-
- test "deletes shared link", %{conn: conn, site: site} do
- link = insert(:shared_link, site: site)
-
- conn = delete(conn, "/sites/#{site.domain}/shared-links/#{link.slug}")
-
- refute Repo.one(Plausible.Site.SharedLink)
- assert redirected_to(conn, 302) =~ "/#{URI.encode_www_form(site.domain)}/settings"
- assert Phoenix.Flash.get(conn.assigns.flash, :success) == "Shared Link deleted"
- end
-
- test "fails to delete shared link from the outside", %{conn: conn, site: site} do
- other_site = insert(:site)
- link = insert(:shared_link, site: other_site)
-
- conn = delete(conn, "/sites/#{site.domain}/shared-links/#{link.slug}")
-
- assert Repo.one(Plausible.Site.SharedLink)
- assert html_response(conn, 404)
- end
- end
-
describe "DELETE /:domain/settings/:forget_import/:import_id" do
setup [:create_user, :log_in, :create_site, :create_legacy_site_import]
diff --git a/test/plausible_web/live/shared_link_settings/form_test.exs b/test/plausible_web/live/shared_link_settings/form_test.exs
new file mode 100644
index 0000000000..4a1926e237
--- /dev/null
+++ b/test/plausible_web/live/shared_link_settings/form_test.exs
@@ -0,0 +1,212 @@
+defmodule PlausibleWeb.Live.SharedLinkSettings.FormTest do
+ use PlausibleWeb.ConnCase, async: true
+ use Plausible.Teams.Test
+ import Phoenix.LiveViewTest
+ import Plausible.Test.Support.HTML
+
+ describe "Shared link form" do
+ setup [:create_user, :log_in, :create_site]
+
+ setup %{user: user, site: site} do
+ subscribe_to_growth_plan(user)
+ {:ok, session: %{"site_id" => site.id, "domain" => site.domain}}
+ end
+
+ test "renders form fields for creating a shared link", %{
+ conn: conn,
+ session: session
+ } do
+ lv = get_liveview(conn, session)
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+ html = render(lv)
+
+ assert html =~ "New shared link"
+ assert element_exists?(html, ~s|input[name="shared_link[name]"]|)
+ assert element_exists?(html, ~s|input[name="shared_link[password]"][type="password"]|)
+ assert element_exists?(html, ~s|button[type="submit"]|)
+ end
+
+ test "renders error on empty submission", %{conn: conn, session: session} do
+ lv = get_liveview(conn, session)
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+
+ html = lv |> find_form() |> render_submit()
+
+ assert html =~ "can&#39;t be blank"
+ end
+
+ test "creates a shared link without password", %{conn: conn, site: site, session: session} do
+ lv = get_liveview(conn, session)
+ refute render(lv) =~ "My Shared Link"
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "My Shared Link"}})
+
+ html = render(lv)
+ assert html =~ "My Shared Link"
+ assert html =~ "Shared link saved"
+
+ shared_link =
+ Plausible.Repo.get_by(Plausible.Site.SharedLink, name: "My Shared Link", site_id: site.id)
+
+ assert shared_link
+ refute shared_link.password_hash
+ end
+
+ test "creates a shared link with password", %{conn: conn, site: site, session: session} do
+ lv = get_liveview(conn, session)
+ refute render(lv) =~ "Protected Link"
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "Protected Link", password: "secret123"}})
+
+ html = render(lv)
+ assert html =~ "Protected Link"
+ assert html =~ "Shared link saved"
+
+ shared_link =
+ Plausible.Repo.get_by(Plausible.Site.SharedLink, name: "Protected Link", site_id: site.id)
+
+ assert shared_link
+ assert shared_link.password_hash
+ end
+
+ test "renders form fields for editing a shared link", %{
+ conn: conn,
+ site: site,
+ session: session
+ } do
+ shared_link = insert(:shared_link, site: site, name: "Existing Link")
+
+ lv = get_liveview(conn, session)
+
+ lv
+ |> element(~s/button[phx-click="edit-shared-link"][phx-value-slug="#{shared_link.slug}"]/)
+ |> render_click()
+
+ html = render(lv)
+ assert html =~ "Edit shared link"
+ assert element_exists?(html, ~s|input[name="shared_link[name]"]|)
+ assert html =~ ~s|value="#{shared_link.name}"|
+ end
+
+ test "updates a shared link name", %{conn: conn, site: site, session: session} do
+ shared_link = insert(:shared_link, site: site, name: "Original Name")
+
+ lv = get_liveview(conn, session)
+
+ lv
+ |> element(~s/button[phx-click="edit-shared-link"][phx-value-slug="#{shared_link.slug}"]/)
+ |> render_click()
+
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "Updated Name"}})
+
+ html = render(lv)
+ assert html =~ "Updated Name"
+ assert html =~ "Shared link saved"
+ refute html =~ "Original Name"
+
+ updated = Plausible.Repo.get!(Plausible.Site.SharedLink, shared_link.id)
+ assert updated.name == "Updated Name"
+ assert updated.id == shared_link.id
+ end
+
+ test "updates a shared link password", %{conn: conn, site: site, session: session} do
+ shared_link = insert(:shared_link, site: site, name: "Test Link", password: "old_password")
+
+ lv = get_liveview(conn, session)
+
+ lv
+ |> element(~s/button[phx-click="edit-shared-link"][phx-value-slug="#{shared_link.slug}"]/)
+ |> render_click()
+
+ old_hash = shared_link.password_hash
+
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "Test Link", password: "new_password123"}})
+
+ _html = render(lv)
+
+ updated = Plausible.Repo.get!(Plausible.Site.SharedLink, shared_link.id)
+ assert updated.password_hash != old_hash
+ assert updated.password_hash
+ end
+
+ test "removes password when password field is left empty on update", %{
+ conn: conn,
+ site: site,
+ session: session
+ } do
+ shared_link = insert(:shared_link, site: site, name: "Test Link", password: "old_password")
+
+ lv = get_liveview(conn, session)
+
+ lv
+ |> element(~s/button[phx-click="edit-shared-link"][phx-value-slug="#{shared_link.slug}"]/)
+ |> render_click()
+
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "Test Link", password: ""}})
+
+ _html = render(lv)
+
+ updated = Plausible.Repo.get!(Plausible.Site.SharedLink, shared_link.id)
+ refute updated.password_hash
+ end
+
+ test "renders error when shared link name is invalid", %{
+ conn: conn,
+ session: session
+ } do
+ lv = get_liveview(conn, session)
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+
+ html = lv |> find_form() |> render_submit(%{shared_link: %{name: ""}})
+
+ assert html =~ "can&#39;t be blank"
+ end
+
+ test "shows upgrade required error when subscription doesn't include Shared Links", %{
+ conn: conn,
+ site: site,
+ session: session
+ } do
+ site.team |> Plausible.Teams.Team.end_trial() |> Plausible.Repo.update!()
+ insert(:starter_subscription, team: site.team)
+
+ lv = get_liveview(conn, session)
+
+ lv |> element("button#add-shared-link-button") |> render_click()
+
+ html =
+ lv
+ |> find_form()
+ |> render_submit(%{shared_link: %{name: "Test Link"}})
+
+ assert html =~ "New shared link" or
+ html =~ "Your current subscription plan does not include Shared Links"
+ end
+ end
+
+ defp get_liveview(conn, session) do
+ {:ok, lv, _html} = live_isolated(conn, PlausibleWeb.Live.SharedLinkSettings, session: session)
+ lv
+ end
+
+ defp find_form(lv) do
+ lv |> element("#shared-links-form-modalseq0 form")
+ end
+end
diff --git a/test/plausible_web/live/shared_link_settings_test.exs b/test/plausible_web/live/shared_link_settings_test.exs
new file mode 100644
index 0000000000..aec1b35aff
--- /dev/null
+++ b/test/plausible_web/live/shared_link_settings_test.exs
@@ -0,0 +1,108 @@
+defmodule PlausibleWeb.Live.SharedLinkSettingsTest do
+ use PlausibleWeb.ConnCase, async: true
+ use Plausible.Teams.Test
+ import Phoenix.LiveViewTest
+ import Plausible.Test.Support.HTML
+
+ describe "SharedLinkSettings LiveView" do
+ setup [:create_user, :log_in, :create_site]
+
+ setup %{user: user, site: site} do
+ subscribe_to_growth_plan(user)
+ {:ok, session: %{"site_id" => site.id, "domain" => site.domain}}
+ end
+
+ test "allows shared link deletion", %{conn: conn, site: site, session: session} do
+ link1 = insert(:shared_link, site: site, name: "Link 1")
+ link2 = insert(:shared_link, site: site, name: "Link 2")
+
+ lv = get_liveview(conn, session)
+ html = render(lv)
+
+ assert html =~ "Link 1"
+ assert html =~ "Link 2"
+
+ html =
+ lv
+ |> element(~s/button[phx-click="delete-shared-link"][phx-value-slug="#{link1.slug}"]/)
+ |> render_click()
+
+ refute html =~ "Link 1"
+ assert html =~ "Link 2"
+ assert html =~ "Shared link deleted"
+
+ # Verify it's actually deleted from database
+ refute Plausible.Repo.get_by(Plausible.Site.SharedLink, slug: link1.slug)
+ assert Plausible.Repo.get_by(Plausible.Site.SharedLink, slug: link2.slug)
+ end
+
+ test "shows success message when link is deleted", %{conn: conn, site: site, session: session} do
+ link = insert(:shared_link, site: site, name: "Test Link")
+
+ lv = get_liveview(conn, session)
+
+ html =
+ lv
+ |> element(~s/button[phx-click="delete-shared-link"][phx-value-slug="#{link.slug}"]/)
+ |> render_click()
+
+ assert html =~ "Shared link deleted"
+ refute html =~ "Test Link"
+ end
+
+ test "shows error message when trying to delete non-existent link (race condition)", %{
+ conn: conn,
+ site: site,
+ session: session
+ } do
+ # Simulate race condition: link exists when page loads, but is deleted
+ # by another user/process before we click delete
+ link = insert(:shared_link, site: site, name: "Test Link")
+
+ lv = get_liveview(conn, session)
+
+ html = render(lv)
+ assert html =~ "Test Link"
+
+ Plausible.Repo.delete!(link)
+
+ html =
+ lv
+ |> element(~s/button[phx-click="delete-shared-link"][phx-value-slug="#{link.slug}"]/)
+ |> render_click()
+
+ assert html =~ "Could not find Shared Link"
+ end
+
+ test "displays shared links with password indicators", %{
+ conn: conn,
+ site: site,
+ session: session
+ } do
+ _link_with_password =
+ insert(:shared_link, site: site, name: "Protected", password: "secret")
+
+ _link_without_password = insert(:shared_link, site: site, name: "Public")
+
+ lv = get_liveview(conn, session)
+ html = render(lv)
+
+ assert html =~ "Protected"
+ assert html =~ "Public"
+ # Check for lock icons
+ assert element_exists?(html, ~s|svg|)
+ end
+
+ test "displays empty state when no shared links", %{conn: conn, session: session} do
+ lv = get_liveview(conn, session)
+ html = render(lv)
+
+ assert html =~ "No shared links configured for this site"
+ end
+ end
+
+ defp get_liveview(conn, session) do
+ {:ok, lv, _html} = live_isolated(conn, PlausibleWeb.Live.SharedLinkSettings, session: session)
+ lv
+ end
+end