Skip to content

Lightpanda: the headless browser designed for AI and automation

input: run every text edit through one gated applyEdit

Adrià Arrufat4f4d7f1ec2d5
diff --git a/src/browser/actions.zig b/src/browser/actions.zig
index d4740acdd..23d96cf1f 100644
--- a/src/browser/actions.zig
+++ b/src/browser/actions.zig
@@ -193,27 +193,26 @@ pub fn fill(node: *DOMNode, text: []const u8, frame: *Frame) !void {
/// its picker would. `change` fires right away: nothing commits it on blur.
fn fillControl(ctl: anytype, text: []const u8, frame: *Frame) !void {
const el = ctl.asElement();
- if (!ctl.acceptsTextEntry() or !Frame.user_input.acceptsEdit(el)) {
- return error.InvalidNodeType;
- }
-
if (ctl.tracksSelection()) {
- try ctl.select(frame);
- const edited = Frame.user_input.insertInto(frame, ctl, text) catch |err| {
+ const result = Frame.user_input.applyEdit(frame, ctl, .{ .replace = text }, .{}) catch |err| {
lp.log.debug(.app, "fill insert failed", .{ .err = err });
return error.ActionFailed;
};
- if (!edited) {
- return error.ActionFailed;
- }
- } else {
- ctl.setUserValue(text, frame) catch |err| {
- lp.log.debug(.app, "fill setValue failed", .{ .err = err });
- return error.ActionFailed;
+ return switch (result) {
+ .done => dispatchTrusted(el, "change", frame),
+ .refused => error.InvalidNodeType,
+ .cancelled => error.ActionFailed,
};
- try dispatchTrusted(el, "input", frame);
}
- try dispatchTrusted(el, "change", frame);
+
+ if (!ctl.acceptsTextEntry() or !Frame.user_input.acceptsEdit(el)) {
+ return error.InvalidNodeType;
+ }
+ ctl.setUserValue(text, frame) catch |err| {
+ lp.log.debug(.app, "fill setValue failed", .{ .err = err });
+ return error.ActionFailed;
+ };
+ return dispatchInputAndChangeEvents(el, frame);
}
pub const ScrollResult = struct {
diff --git a/src/browser/frame/user_input.zig b/src/browser/frame/user_input.zig
index d4b12ce9e..5348cae4b 100644
--- a/src/browser/frame/user_input.zig
+++ b/src/browser/frame/user_input.zig
@@ -916,19 +916,9 @@ pub fn typeChar(frame: *Frame, target: *Element, keypress: *KeyboardEvent, text:
if (is_enter) {
return frame.submitForm(input.asElement(), input.getForm(frame), .{});
}
- _ = try insertInto(frame, input, text);
- return;
- }
-
- if (target.is(Element.Html.TextArea)) |textarea| {
- if (is_enter) {
- if (acceptsEdit(textarea.asElement()) and try allowEdit(frame, textarea.asElement(), null, "\n", "insertLineBreak")) {
- try textarea.innerInsert("\n", frame);
- }
- return;
- }
- _ = try insertInto(frame, textarea, text);
- return;
+ _ = try applyEdit(frame, input, .{ .insert = text }, .{});
+ } else if (target.is(Element.Html.TextArea)) |textarea| {
+ _ = try applyEdit(frame, textarea, if (is_enter) .line_break else .{ .insert = text }, .{});
}
}
@@ -986,24 +976,48 @@ fn editKey(frame: *Frame, keyboard_event: *KeyboardEvent, ctl: anytype, key: Key
return ctl.moveCaret(move, keyboard_event.getShiftKey(), frame);
}
- if ((key == .Backspace or key == .Delete) and acceptsEdit(ctl.asElement())) {
- const forward = key == .Delete;
- if (!keyboard_event.asEvent().getIsTrusted() or try allowEdit(frame, ctl.asElement(), null, null, deleteInputType(forward))) {
- try ctl.innerDelete(forward, frame);
- }
+ if (key == .Backspace or key == .Delete) {
+ const edit: Edit = .{ .delete = if (key == .Delete) .forward else .backward };
+ _ = try applyEdit(frame, ctl, edit, .{ .beforeinput = keyboard_event.asEvent().getIsTrusted() });
}
}
-/// Returns whether the edit happened.
-pub fn insertInto(frame: *Frame, ctl: anytype, text: []const u8) !bool {
- if (!ctl.acceptsTextEntry() or !acceptsEdit(ctl.asElement())) {
- return false;
+pub const Edit = union(enum) {
+ insert: []const u8,
+ /// Selects the whole value first, as typing over a select-all does.
+ replace: []const u8,
+ line_break,
+ delete: enum { backward, forward },
+};
+
+pub const EditResult = enum { done, refused, cancelled };
+
+/// A text edit as the user makes it: refused on a readonly or disabled
+/// control, cancellable through beforeinput.
+pub fn applyEdit(frame: *Frame, ctl: anytype, edit: Edit, opts: struct { beforeinput: bool = true }) !EditResult {
+ const el = ctl.asElement();
+ if (!ctl.acceptsTextEntry() or !acceptsEdit(el)) {
+ return .refused;
}
- if (!try allowEdit(frame, ctl.asElement(), text, text, "insertText")) {
- return false;
+ if (edit == .replace) {
+ try ctl.select(frame);
+ }
+ if (opts.beforeinput) {
+ const allowed = switch (edit) {
+ .insert, .replace => |text| try allowEdit(frame, el, text, text, "insertText"),
+ .line_break => try allowEdit(frame, el, null, "\n", "insertLineBreak"),
+ .delete => |dir| try allowEdit(frame, el, null, null, if (dir == .forward) "deleteContentForward" else "deleteContentBackward"),
+ };
+ if (!allowed) {
+ return .cancelled;
+ }
+ }
+ switch (edit) {
+ .insert, .replace => |text| try ctl.innerInsert(text, .text, frame),
+ .line_break => try ctl.innerInsert("\n", .line_break, frame),
+ .delete => |dir| try ctl.innerDelete(dir == .forward, frame),
}
- try ctl.innerInsert(text, frame);
- return true;
+ return .done;
}
pub fn acceptsEdit(el: *Element) bool {
@@ -1033,10 +1047,6 @@ fn caretMove(key: KeyboardEvent.Key, ctl: anytype) ?@TypeOf(ctl.*).CaretMove {
};
}
-fn deleteInputType(forward: bool) []const u8 {
- return if (forward) "deleteContentForward" else "deleteContentBackward";
-}
-
// pre-edit events for a trusted key's default action, can cancel the edit
// (i.e. by returning false)
fn allowEdit(frame: *Frame, target: *Element, before_data: ?[]const u8, text_data: ?[]const u8, input_type: []const u8) !bool {
@@ -1211,9 +1221,9 @@ pub fn insertText(frame: *Frame, v: []const u8) !void {
const html_element = frame.document._active_element orelse return;
if (html_element.is(Element.Html.Input)) |input| {
- _ = try insertInto(frame, input, v);
+ _ = try applyEdit(frame, input, .{ .insert = v }, .{});
} else if (html_element.is(Element.Html.TextArea)) |textarea| {
- _ = try insertInto(frame, textarea, v);
+ _ = try applyEdit(frame, textarea, .{ .insert = v }, .{});
}
}
diff --git a/src/browser/webapi/element/text_entry.zig b/src/browser/webapi/element/text_entry.zig
index 3264dc0a2..85e9b54f3 100644
--- a/src/browser/webapi/element/text_entry.zig
+++ b/src/browser/webapi/element/text_entry.zig
@@ -69,58 +69,45 @@ pub fn TextEntry(comptime T: type) type {
try frame._event_manager.dispatch(self.asElement().asEventTarget(), event);
}
- pub fn innerInsert(self: *T, str: []const u8, frame: *Frame) !void {
- const arena = frame.arena;
+ pub const Insertion = enum {
+ text,
+ line_break,
+
+ fn inputType(self: Insertion) []const u8 {
+ return switch (self) {
+ .text => "insertText",
+ .line_break => "insertLineBreak",
+ };
+ }
+ };
- switch (howSelected(self)) {
- .full => {
- // fully selected, replace the content.
- const new_value = try arena.dupe(u8, str);
- try self.setUserValue(new_value, frame);
- // the sanitized value can be shorter than what was inserted
- const new_len: u32 = @intCast(self.getValue().len);
- self._selection_start = new_len;
- self._selection_end = new_len;
- self._selection_direction = .none;
- try dispatchSelectionChangeEvent(self, frame);
- },
- .partial => |range| {
- // partially selected, replace the selected content.
- const current_value = self.getValue();
- const before = current_value[0..range[0]];
- const remaining = current_value[range[1]..];
-
- const new_value = try std.mem.concat(
- arena,
- u8,
- &.{ before, str, remaining },
- );
- try self.setUserValue(new_value, frame);
-
- const new_pos: u32 = @intCast(@min(range[0] + str.len, self.getValue().len));
- self._selection_start = new_pos;
- self._selection_end = new_pos;
- self._selection_direction = .none;
- try dispatchSelectionChangeEvent(self, frame);
- },
- .none => {
- // nothing selected, insert at the caret. Controls without
- // a caret (e.g. date) append.
- const current_value = self.getValue();
- const caret = if (tracksSelection(self)) @min(self._selection_start, current_value.len) else current_value.len;
- const new_value = try std.mem.concat(arena, u8, &.{ current_value[0..caret], str, current_value[caret..] });
- try self.setUserValue(new_value, frame);
- if (tracksSelection(self)) {
- // the sanitized value can be shorter than what was inserted
- const new_pos: u32 = @intCast(@min(caret + str.len, self.getValue().len));
- self._selection_start = new_pos;
- self._selection_end = new_pos;
- self._selection_direction = .none;
- try dispatchSelectionChangeEvent(self, frame);
- }
+ pub fn innerInsert(self: *T, str: []const u8, kind: Insertion, frame: *Frame) !void {
+ const current_value = self.getValue();
+ const value_len: u32 = @intCast(current_value.len);
+ const start: u32, const end: u32 = switch (howSelected(self)) {
+ .full => .{ 0, value_len },
+ .partial => |range| range,
+ .none => blk: {
+ // Controls without a caret (e.g. date) append.
+ const caret = if (tracksSelection(self)) @min(self._selection_start, value_len) else value_len;
+ break :blk .{ caret, caret };
},
+ };
+
+ const scratch = try frame.getArena(.small, "TextEntry.innerInsert");
+ defer scratch.release();
+ const new_value = try std.mem.concat(scratch.allocator(), u8, &.{ current_value[0..start], str, current_value[end..] });
+ try self.setUserValue(new_value, frame);
+
+ if (tracksSelection(self)) {
+ // the sanitized value can be shorter than what was inserted
+ const new_pos: u32 = @intCast(@min(start + str.len, self.getValue().len));
+ self._selection_start = new_pos;
+ self._selection_end = new_pos;
+ self._selection_direction = .none;
+ try dispatchSelectionChangeEvent(self, frame);
}
- try dispatchInputEvent(self, str, "insertText", frame);
+ try dispatchInputEvent(self, if (kind == .text) str else null, kind.inputType(), frame);
}
// forward == delete
@@ -161,7 +148,9 @@ pub fn TextEntry(comptime T: type) type {
},
}
- const new_value = try std.mem.concat(frame.arena, u8, &.{
+ const scratch = try frame.getArena(.small, "TextEntry.innerDelete");
+ defer scratch.release();
+ const new_value = try std.mem.concat(scratch.allocator(), u8, &.{
current_value[0..start],
current_value[@min(end, value_len)..],
});
diff --git a/src/server/cdp/domains/input.zig b/src/server/cdp/domains/input.zig
index 3e0864d21..d2ae6327f 100644
--- a/src/server/cdp/domains/input.zig
+++ b/src/server/cdp/domains/input.zig
@@ -1632,6 +1632,7 @@ test "cdp.input: dispatchKeyEvent text-less keyDown then char types once" {
\\document.body.appendChild(ta);
\\ta.value = 'one';
\\ta.focus();
+ \\ta.addEventListener('input', (e) => window.taInput = e.inputType + ':' + e.data);
, null);
try ctx.processMessage(.{ .id = 6, .method = "Input.dispatchKeyEvent", .params = .{ .type = "keyDown", .key = "Enter", .code = "Enter" } });
try ctx.expectSentResult(null, .{ .id = 6 });
@@ -1639,7 +1640,14 @@ test "cdp.input: dispatchKeyEvent text-less keyDown then char types once" {
try ctx.expectSentResult(null, .{ .id = 7 });
try ctx.processMessage(.{ .id = 8, .method = "Input.dispatchKeyEvent", .params = .{ .type = "keyUp", .key = "Enter", .code = "Enter" } });
try ctx.expectSentResult(null, .{ .id = 8 });
- try testing.expect((try ls.local.compileAndRun("ta.value === 'one\\n'", null)).isTrue());
+ try testing.expect((try ls.local.compileAndRun("ta.value === 'one\\n' && window.taInput === 'insertLineBreak:null'", null)).isTrue());
+
+ // A readonly control keeps its value; the keys themselves still fire.
+ _ = try ls.local.compileAndRun("ta.readOnly = true; window.taInput = null;", null);
+ try ctx.processMessage(.{ .id = 9, .method = "Input.dispatchKeyEvent", .params = .{ .type = "keyDown", .key = "x", .text = "x" } });
+ try ctx.processMessage(.{ .id = 10, .method = "Input.dispatchKeyEvent", .params = .{ .type = "keyDown", .key = "Backspace", .code = "Backspace" } });
+ try ctx.processMessage(.{ .id = 11, .method = "Input.insertText", .params = .{ .text = "y" } });
+ try testing.expect((try ls.local.compileAndRun("ta.value === 'one\\n' && window.taInput === null", null)).isTrue());
}
test "cdp.input: dispatchKeyEvent char honors keypress and beforeinput vetoes" {