Skip to content

armgit / core

Public Imported from GitHub
0

100% open-source IoT Platform - Integrate your devices, add intelligence, build custom apps

1.6 KB
Raw Blame
pluginManagement {
  resolutionStrategy {
    eachPlugin {
      if (requested.id.toString() == "io.openremote.com.cherryperry.gradle-file-encrypt") {
        useModule("com.github.openremote:GradleFileEncrypt:$requested.version")
      }
    }
  }

  repositories {
    gradlePluginPortal()
    maven {
      url = "https://jitpack.io"
    }
  }
}

// TODO: These plugins remain here because project.gradle imports their classes,
// and version-catalog aliases cannot be used in settings.gradle. Move the related
// configuration into convention plugins/build logic so their versions can be
// managed through libs.versions.toml.
plugins {
  id 'com.diffplug.spotless' version "$spotlessVersion" apply false
  id 'cz.habarta.typescript-generator' version "$typescriptGeneratorVersion" apply false
  id 'org.jetbrains.gradle.plugin.idea-ext' version "$ideaExtPluginVersion" apply false
}

rootProject.name = "openremote"

// Include sub-projects dynamically, every directory with a build.gradle (and no .buildignore)
fileTree(
        dir: rootDir,
        include: "**/build.gradle",
        excludes: [
          ".git/**",
          "**/.git/**",
          ".gradle/**",
          "**/.gradle/**",
          "**/build/**",
          "**/node_modules/**",
          "**/generic_app/**",
          "**/dist/**",
          "**/lib/**"
        ]
        )
        .filter { it.parentFile != rootDir }
        .filter { !new File(it.parentFile, ".buildignore").exists() }
        .each {
          include it.parentFile.canonicalPath
                  .replace(rootDir.canonicalPath, "")
                  .replace("\\", ":")
                  .replace("/", ":")
        }