100% open-source IoT Platform - Integrate your devices, add intelligence, build custom apps
Java asset-managementbuildingdashboarddataplatformdevice-managementedge-computingenergyenergy-managementenergy-monitorfleet-managementfleet-telematicsiotiot-applicationiot-platformmodbusmqttmqtt-brokerota-updaterules-enginesmartcity
plugins {
id 'java'
id 'maven-publish'
id 'signing'
}
sourceSets {
main {
output.dir(layout.buildDirectory.dir("classes/main"), builtBy: "generateSources")
}
}
configurations {
sources
}
dependencies {
sources libs.swaggerUi
}
base {
archivesName = "openremote-${project.name}"
}
java {
withJavadocJar()
withSourcesJar()
}
publishing {
publications {
maven(MavenPublication) {
group = "io.openremote.ui"
artifactId = "openremote-${project.name}"
from components.java
pom {
name = 'OpenRemote Swagger UI'
description = 'Provides a Swagger UI configured for use with OpenRemote'
url = 'https://github.com/openremote/core'
licenses {
license {
name = 'GNU Affero General Public License v3.0'
url = 'https://www.gnu.org/licenses/agpl-3.0.en.html'
}
}
developers {
developer {
id = 'developers'
name = 'Developers'
email = '[email protected]'
organization = 'OpenRemote'
organizationUrl = 'https://openremote.io'
}
}
scm {
connection = 'scm:git:git://github.com/openremote/core.git'
developerConnection = 'scm:git:ssh://github.com:openremote/core.git'
url = 'https://github.com/openremote/core/tree/main'
}
}
}
}
repositories {
maven {
if (!version.endsWith('-LOCAL')) {
credentials {
username = findProperty("publishUsername")
password = findProperty("publishPassword")
}
}
url = version.endsWith('-LOCAL') ? layout.buildDirectory.dir('repo') : version.endsWith('-SNAPSHOT') ? findProperty("snapshotsRepoUrl") : findProperty("releasesRepoUrl")
}
}
}
signing {
def signingKey = findProperty("signingKey")
def signingPassword = findProperty("signingPassword")
if (signingKey && signingPassword) {
useInMemoryPgpKeys(signingKey, signingPassword)
sign publishing.publications.maven
}
}
tasks.register('generateSources', Copy) {
// Copy Swagger UI resources from the WebJars dependency
from zipTree(configurations.sources.singleFile).matching {
include "META-INF/resources/webjars/swagger-ui/${libs.versions.swaggerUi.get()}/*"
exclude('**/favicon*.png')
exclude('**/index.html')
exclude('**/swagger-initializer.js')
}
// Flatten the hierarchy by setting the path of all files to their respective basename
eachFile {
path = name
}
// Flattening the hierarchy leaves empty directories, do not copy those
includeEmptyDirs = false
into layout.buildDirectory.dir("classes/main/org/openremote/web/${project.name}")
// Copy OpenRemote customizations
from fileTree(projectDir) {
exclude 'build.gradle'
exclude 'build/**'
exclude 'bin/**'
}
into layout.buildDirectory.dir("classes/main/org/openremote/web/${project.name}")
}
tasks.register('installDist', Copy) {
dependsOn generateSources
mustRunAfter ":manager:installDist"
from layout.buildDirectory.dir("classes/main/org/openremote/web/${project.name}")
into project(':manager').layout.buildDirectory.dir("install/manager/web/${project.name}")
}
jar.dependsOn(generateSources)
gradle.startParameter.excludedTaskNames += ["${project.path}:test".toString()]