Skip to content

armgit / core

Public Imported from GitHub
0

100% open-source IoT Platform - Integrate your devices, add intelligence, build custom apps

1.4 KB
Raw Blame
buildscript {
  repositories {
    mavenCentral()
  }
  dependencies {
    classpath "cz.habarta.typescript-generator:typescript-generator-gradle-plugin:$typescriptGeneratorVersion"
  }
}

plugins {
  id 'groovy'
  id 'cz.habarta.typescript-generator'
}

dependencies {
  compileOnly project(":model-util")
  implementation project(":model")
  implementation project(":agent")
  implementation libs.jacksonDatatypeJdk8
  implementation libs.jacksonDatatypeJsr310
  implementation libs.jacksonModuleParameterNames
  implementation libs.typescriptGeneratorCore
}

generateTypeScript createTSGeneratorConfigForModel("src/model.ts")

def generateTypeScriptTask = tasks.named("generateTypeScript") {
  // Work around typescript-generator exposing non-serializable configuration objects as Gradle task inputs.
  doNotTrackState("typescript-generator uses non-serializable task input types")
}

tasks.register('npmBuild', Exec) {
  mustRunAfter npmClean
  dependsOn getYarnInstallTask()
  commandLine npmCommand("yarn"), "run", "build"
}

tasks.named("build") {
  dependsOn generateTypeScriptTask, tasks.named("npmBuild")
}

tasks.named("npmBuild") {
  dependsOn generateTypeScriptTask
}

tasks.register('prepareUi') {
  dependsOn clean, npmPrepare
}

tasks.register('publishUi') {
  dependsOn clean, npmPublish
}

gradle.startParameter.excludedTaskNames += ["${project.path}:test".toString()]