Skip to content

armgit / dbx

Public Imported from GitHub
0

25 MB lightweight cross-platform database client for 100+ databases, including MySQL, PostgreSQL, SQLite, Redis, MongoDB, DuckDB, SQL Server, and Dameng. Built-in AI, MCP Server, CLI, desktop and Docker. | 轻量级跨平台数据库管理工具,支持 MySQL、PostgreSQL、SQLite、Redis、MongoDB、达梦等 100+ 数据库,提供桌面端、Docker、CLI、内置 AI 助手和 MCP。

1.6 KB
Raw Blame
plugins {
    id 'java'
    id 'com.gradleup.shadow'
}

configure([project(':common'), project(':test-support')]) {
    if (name == 'test-support') {
        apply plugin: 'java-library'
    } else {
        apply plugin: 'java'
    }

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    dependencies {
        testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.4'
    }

    tasks.withType(Test).configureEach {
        useJUnitPlatform()
    }
}

dependencies {
    implementation project(':common')
    implementation 'com.zaxxer:HikariCP:7.0.2'
    runtimeOnly 'org.slf4j:slf4j-nop:2.0.17'

    // Bundled driver example:
    // implementation 'com.example:example-jdbc:1.2.3'

    // External driver example:
    // implementation fileTree(dir: 'libs', include: ['*.jar'])

    testImplementation 'org.junit.jupiter:junit-jupiter:5.11.4'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.11.4'
    testImplementation project(':test-support')
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

tasks.named('shadowJar') {
    archiveBaseName = 'dbx-agent-template'
    archiveClassifier = ''
    manifest {
        attributes(
            'Agent-Label': 'Template DB',
            // Add this only when users must provide the JDBC driver jar:
            // 'Agent-External-Driver': 'true',
            'Main-Class': 'com.dbx.agent.template.TemplateAgent'
        )
    }
}

tasks.named('test') {
    useJUnitPlatform()
}