Skip to content

The easy-to-use open source Business Intelligence and Embedded Analytics tool that lets everyone work with data :bar_chart:

OAuth token cleanup task (#72081)

Chris Truter398840c0a198
diff --git a/.clj-kondo/config/modules/config.edn b/.clj-kondo/config/modules/config.edn
index fd9d5293b8b..0b931435056 100644
--- a/.clj-kondo/config/modules/config.edn
+++ b/.clj-kondo/config/modules/config.edn
@@ -1378,6 +1378,8 @@
request
settings
system
+ task
+ tracing
util}}
;; TODO -- too many API namespaces
diff --git a/src/metabase/oauth_server/init.clj b/src/metabase/oauth_server/init.clj
index 6709f1b2545..ea4bae4d905 100644
--- a/src/metabase/oauth_server/init.clj
+++ b/src/metabase/oauth_server/init.clj
@@ -1,3 +1,4 @@
(ns metabase.oauth-server.init
(:require
- [metabase.oauth-server.settings]))
+ [metabase.oauth-server.settings]
+ [metabase.oauth-server.task.cleanup-expired-tokens]))
diff --git a/src/metabase/oauth_server/task/cleanup_expired_tokens.clj b/src/metabase/oauth_server/task/cleanup_expired_tokens.clj
new file mode 100644
index 00000000000..1dddaee3c0f
--- /dev/null
+++ b/src/metabase/oauth_server/task/cleanup_expired_tokens.clj
@@ -0,0 +1,48 @@
+(ns metabase.oauth-server.task.cleanup-expired-tokens
+ "Daily Quartz job that deletes expired and revoked OAuth rows."
+ (:require
+ [clojurewerkz.quartzite.jobs :as jobs]
+ [clojurewerkz.quartzite.schedule.cron :as cron]
+ [clojurewerkz.quartzite.triggers :as triggers]
+ [metabase.task.core :as task]
+ [metabase.tracing.core :as tracing]
+ [metabase.util.log :as log]
+ [toucan2.core :as t2]))
+
+(set! *warn-on-reflection* true)
+
+(defn cleanup-expired-tokens!
+ "Delete expired authorization codes/access tokens/refresh tokens, and any access/refresh rows
+ that have been explicitly revoked. Returns a map of counts of rows deleted."
+ []
+ (let [now (System/currentTimeMillis)]
+ ;; Issue expiry- and revocation-based deletes as separate statements so each can use the appropriate
+ ;; index (expiry / revoked_at). A combined `OR` predicate would prevent the planner from using either
+ ;; index and degrade into a table scan as these tables grow.
+ {:authorization-codes-expired (t2/delete! :model/OAuthAuthorizationCode :expiry [:< now])
+ :access-tokens-expired (t2/delete! :model/OAuthAccessToken :expiry [:< now])
+ :access-tokens-revoked (t2/delete! :model/OAuthAccessToken :revoked_at [:not= nil])
+ :refresh-tokens-expired (t2/delete! :model/OAuthRefreshToken :expiry [:< now])
+ :refresh-tokens-revoked (t2/delete! :model/OAuthRefreshToken :revoked_at [:not= nil])}))
+
+(task/defjob ^{:doc "Delete expired and revoked OAuth tokens and authorization codes."}
+ CleanupExpiredOAuthTokens [_]
+ (log/debug "Cleaning up expired/revoked OAuth tokens")
+ (tracing/with-span :tasks "task.oauth-server.cleanup-expired-tokens.delete" {}
+ (let [counts (cleanup-expired-tokens!)]
+ (log/infof "OAuth cleanup deleted %s" counts))))
+
+(def ^:private job-key (jobs/key "metabase.task.oauth-server.cleanup-expired-tokens.job"))
+(def ^:private trigger-key (triggers/key "metabase.task.oauth-server.cleanup-expired-tokens.trigger"))
+
+(defmethod task/init! ::CleanupExpiredOAuthTokens [_]
+ (let [job (jobs/build
+ (jobs/of-type CleanupExpiredOAuthTokens)
+ (jobs/with-identity job-key))
+ trigger (triggers/build
+ (triggers/with-identity trigger-key)
+ (triggers/start-now)
+ (triggers/with-schedule
+ ;; daily at midnight
+ (cron/cron-schedule "0 0 0 * * ? *")))]
+ (task/schedule-task! job trigger)))
diff --git a/test/metabase/oauth_server/task/cleanup_expired_tokens_test.clj b/test/metabase/oauth_server/task/cleanup_expired_tokens_test.clj
new file mode 100644
index 00000000000..7aa387e3ae3
--- /dev/null
+++ b/test/metabase/oauth_server/task/cleanup_expired_tokens_test.clj
@@ -0,0 +1,48 @@
+(ns metabase.oauth-server.task.cleanup-expired-tokens-test
+ (:require
+ [clojure.test :refer [deftest is testing]]
+ [metabase.oauth-server.task.cleanup-expired-tokens :as cleanup]
+ [metabase.test :as mt]
+ [toucan2.core :as t2]))
+
+(set! *warn-on-reflection* true)
+
+(defn- uuid [] (str (random-uuid)))
+
+(deftest cleanup-expired-tokens-test
+ (mt/with-empty-h2-app-db!
+ (let [now (System/currentTimeMillis)
+ past-ms (- now 60000)
+ future-ms (+ now 3600000)
+ client-id (uuid)
+ base {:user_id (mt/user->id :rasta)
+ :client_id client-id
+ :scope ["openid"]}
+ redirect-uri "https://example.com/cb"
+ live-code (uuid)
+ live-access (uuid)
+ live-refresh (uuid)
+ live-no-expiry-refresh (uuid)]
+ (t2/insert! :model/OAuthAuthorizationCode
+ [(merge base {:code live-code :expiry future-ms :redirect_uri redirect-uri})
+ (merge base {:code (uuid) :expiry past-ms :redirect_uri redirect-uri})])
+ (t2/insert! :model/OAuthAccessToken
+ [(merge base {:token live-access :expiry future-ms})
+ (merge base {:token (uuid) :expiry past-ms})
+ (merge base {:token (uuid) :expiry future-ms :revoked_at :%now})])
+ (t2/insert! :model/OAuthRefreshToken
+ [(merge base {:token live-refresh :expiry future-ms})
+ (merge base {:token (uuid) :expiry past-ms})
+ (merge base {:token (uuid) :expiry future-ms :revoked_at :%now})
+ (merge base {:token live-no-expiry-refresh :expiry nil})])
+ (cleanup/cleanup-expired-tokens!)
+ (let [surviving (fn [model col] (t2/select-fn-set col [model col] :client_id client-id))]
+ (testing "only the live authorization code survives"
+ (is (= #{live-code}
+ (surviving :model/OAuthAuthorizationCode :code))))
+ (testing "only the live access token survives (expired and revoked are deleted)"
+ (is (= #{live-access}
+ (surviving :model/OAuthAccessToken :token))))
+ (testing "live and null-expiry refresh tokens survive; expired and revoked are deleted"
+ (is (= #{live-refresh live-no-expiry-refresh}
+ (surviving :model/OAuthRefreshToken :token))))))))