Skip to content

The easy-to-use open source Business Intelligence and Embedded Analytics tool that lets everyone work with data :bar_chart:

Respect Metabot permission mode when resolving access (#80468)

Chris Truter6482f14a5884
diff --git a/enterprise/backend/src/metabase_enterprise/metabot/api/permissions.clj b/enterprise/backend/src/metabase_enterprise/metabot/api/permissions.clj
index 78f07b5cfb4..f6ac8773752 100644
--- a/enterprise/backend/src/metabase_enterprise/metabot/api/permissions.clj
+++ b/enterprise/backend/src/metabase_enterprise/metabot/api/permissions.clj
@@ -7,8 +7,8 @@
[metabase.api.macros :as api.macros]
[metabase.api.routes.common :refer [+auth]]
[metabase.metabot.scope :as scope]
- [metabase.permissions.core :as perms]
- [metabase.util :as u]
+ [metabase.settings.core :as setting]
+ [metabase.util.i18n :refer [tru]]
[toucan2.core :as t2]))
(def ^:private perm-type-enum
@@ -84,20 +84,44 @@
:perm_value perm-value-kw})))))
(permissions-response))
+(defn- switch-mode!
+ "Switch permission modes and delete rows hidden by the destination mode in a single transaction.
+
+ The setting is written last. If the transaction fails, the settings cache is reloaded because the setting write
+ updates it in place; otherwise, this node could continue using the rolled-back mode."
+ [advanced?]
+ (try
+ (t2/with-transaction [_conn]
+ (t2/delete! :model/MetabotPermissions {:where (metabot-perms/hidden-groups-clause advanced?)})
+ (metabot-settings/metabot-advanced-permissions! advanced?))
+ (catch Throwable e
+ (setting/restore-cache!)
+ (throw e))))
+
+(defn- check-mode-switchable!
+ "Throw a 400 when [[metabot-settings/metabot-advanced-permissions]] is forced by an environment variable.
+ Writing the setting would then have no effect, while the associated row deletions would leave the instance in a
+ state that neither mode describes."
+ []
+ (api/check-400 (not (setting/env-var-value :metabot-advanced-permissions))
+ (tru "The permission mode is set by the MB_METABOT_ADVANCED_PERMISSIONS environment variable.")))
+
(api.macros/defendpoint :post "/advanced" :- permissions-response-schema
- "Switch to advanced group-level permissions. Removes any custom permissions from the All Users group."
+ "Switch to group-level permissions. Removes the permissions of All Users and All tenant users, so nobody has
+ access until they are in a group that grants it."
[]
(api/check-superuser)
- (t2/delete! :model/MetabotPermissions :group_id (u/the-id (perms/all-users-group)))
- (metabot-settings/metabot-advanced-permissions! true)
+ (check-mode-switchable!)
+ (switch-mode! true)
(permissions-response))
(api.macros/defendpoint :delete "/advanced" :- permissions-response-schema
- "Switch back to simple permissions. Removes any custom permissions from all specific groups, keeping only Admins and All Users."
+ "Switch back to simple permissions. Removes the permissions of every group other than Administrators, All Users
+ and All tenant users."
[]
(api/check-superuser)
- (t2/delete! :model/MetabotPermissions :group_id [:not-in [(u/the-id (perms/admin-group)) (u/the-id (perms/all-users-group))]])
- (metabot-settings/metabot-advanced-permissions! false)
+ (check-mode-switchable!)
+ (switch-mode! false)
(permissions-response))
(def ^{:arglists '([request respond raise])} routes
diff --git a/enterprise/backend/src/metabase_enterprise/metabot/models/metabot_permissions.clj b/enterprise/backend/src/metabase_enterprise/metabot/models/metabot_permissions.clj
index 1e22635126e..557a9dde09f 100644
--- a/enterprise/backend/src/metabase_enterprise/metabot/models/metabot_permissions.clj
+++ b/enterprise/backend/src/metabase_enterprise/metabot/models/metabot_permissions.clj
@@ -3,6 +3,8 @@
(:require
[metabase.metabot.scope :as scope]
[metabase.models.interface :as mi]
+ [metabase.permissions.core :as perms]
+ [metabase.util :as u]
[methodical.core :as methodical]
[toucan2.core :as t2]))
@@ -16,6 +18,28 @@
{:perm_type mi/transform-keyword
:perm_value mi/transform-keyword})
+(defn- default-group-ids
+ "Return the IDs of groups visible only in simple mode: All Users and, on tenant instances, All tenant users."
+ []
+ [(u/the-id (perms/all-users-group)) (u/the-id (perms/all-external-users-group))])
+
+(defn visible-groups-clause
+ "Return a HoneySQL predicate that matches groups visible in the admin UI for the mode selected by `advanced?`.
+
+ Simple mode shows Administrators, All Users, and All tenant users. Group-level mode shows all other groups."
+ [advanced?]
+ (if advanced?
+ [:not-in :group_id (default-group-ids)]
+ [:in :group_id (conj (default-group-ids) (u/the-id (perms/admin-group)))]))
+
+(defn hidden-groups-clause
+ "Return a HoneySQL predicate that matches groups hidden in the admin UI for the mode selected by `advanced?`.
+
+ This is the complement of `visible-groups-clause`. Rows that match this predicate are deleted when switching
+ modes."
+ [advanced?]
+ [:not (visible-groups-clause advanced?)])
+
(defn permissions-for-group
"Returns the full set of permissions for a group, filling in defaults for any missing perm types."
[group-id stored-perms]
diff --git a/enterprise/backend/src/metabase_enterprise/metabot/permissions.clj b/enterprise/backend/src/metabase_enterprise/metabot/permissions.clj
index 7ded0de1fa2..7102877f804 100644
--- a/enterprise/backend/src/metabase_enterprise/metabot/permissions.clj
+++ b/enterprise/backend/src/metabase_enterprise/metabot/permissions.clj
@@ -1,26 +1,37 @@
(ns metabase-enterprise.metabot.permissions
"Enterprise implementation of metabot permission resolution.
- Resolves per-group permissions from the database, taking the most permissive
- value across all of a user's groups."
+ Resolves per-group permissions from the database, taking the most permissive value across the user's groups
+ that the active permission mode shows."
(:require
+ [metabase-enterprise.metabot.models.metabot-permissions :as metabot-perms]
+ [metabase-enterprise.metabot.settings :as metabot-settings]
[metabase.metabot.scope :as scope]
[metabase.premium-features.core :refer [defenterprise]]
[toucan2.core :as t2]))
(defenterprise resolve-user-permissions
- "Resolve the effective metabot permissions for a user by taking the most
- permissive value across all their groups. Returns a map of perm-type → value,
- with defaults filled in for any unset permission types."
+ "Resolve the effective metabot permissions for a user by taking the most permissive value across the groups
+ the active permission mode shows. Returns a map of perm-type → value, with defaults filled in for any unset
+ permission types."
:feature :ai-controls
[user-id]
(if-not user-id
scope/all-yes-permissions
(let [stored (t2/select :model/MetabotPermissions
- {:where [:in :group_id
- ^:allow-subquery
- {:select [:group_id]
- :from [(t2/table-name :model/PermissionsGroupMembership)]
- :where [:= :user_id user-id]}]})
+ {:where [:and
+ [:in :group_id
+ ^:allow-subquery
+ {:select [:group_id]
+ :from [(t2/table-name :model/PermissionsGroupMembership)]
+ :where [:= :user_id user-id]}]
+ ;; Ignore permission rows for groups hidden by the active mode. An unseen
+ ;; :yes would otherwise override every visible :no (#80394). Mode switches
+ ;; delete these rows, but serialization imports and API writes for hidden
+ ;; groups can recreate them. A mode change through `PUT /api/setting` can
+ ;; leave them behind. They can also remain on instances that switched modes
+ ;; before this fix.
+ (metabot-perms/visible-groups-clause
+ (metabot-settings/metabot-advanced-permissions))]})
by-type (group-by :perm_type stored)]
(reduce-kv
(fn [acc perm-type default-value]
diff --git a/enterprise/backend/test/metabase_enterprise/metabot/api/permissions_test.clj b/enterprise/backend/test/metabase_enterprise/metabot/api/permissions_test.clj
index e15058cc2c5..78d5c369691 100644
--- a/enterprise/backend/test/metabase_enterprise/metabot/api/permissions_test.clj
+++ b/enterprise/backend/test/metabase_enterprise/metabot/api/permissions_test.clj
@@ -87,17 +87,18 @@
(filter #(= (:group_id %) group-id)))]
(is (= all-perm-types (set (map :perm_type perms))))))))))
-(deftest ^:parallel user-permissions-with-custom-group-test
+(deftest user-permissions-with-custom-group-test
(mt/with-premium-features #{:ai-controls}
(testing "GET /api/metabot/permissions/user-permissions"
- (testing "user in group with custom permissions gets those values"
- (mt/with-temp [:model/PermissionsGroup {gid :id} {:name "Test Metabot Perms Group"}
- :model/PermissionsGroupMembership _ {:group_id gid :user_id (mt/user->id :rasta)}
- :model/MetabotPermissions _ {:group_id gid
- :perm_type :permission/metabot-sql-generation
- :perm_value :yes}]
- (let [perms (:permissions (mt/user-http-request :rasta :get 200 "metabot/permissions/user-permissions"))]
- (is (= "yes" (:metabot-sql-generation perms)))))))))
+ (testing "in group-level mode a user in a group with custom permissions gets those values"
+ (mt/with-temporary-setting-values [metabot-advanced-permissions true]
+ (mt/with-temp [:model/PermissionsGroup {gid :id} {:name "Test Metabot Perms Group"}
+ :model/PermissionsGroupMembership _ {:group_id gid :user_id (mt/user->id :rasta)}
+ :model/MetabotPermissions _ {:group_id gid
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :yes}]
+ (let [perms (:permissions (mt/user-http-request :rasta :get 200 "metabot/permissions/user-permissions"))]
+ (is (= "yes" (:metabot-sql-generation perms))))))))))
(deftest ^:parallel admin-endpoints-require-ai-controls-feature-test
(testing "admin endpoints return 402 without :ai-controls feature"
@@ -112,13 +113,11 @@
(mt/assert-has-premium-feature-error "AI Controls"
(mt/user-http-request :crowberto :delete 402 "ee/ai-controls/permissions/advanced")))))
-(defn- do-with-metabot-permissions-snapshot
+(defn- do-with-metabot-permissions-snapshot!
"Snapshot all rows in `metabot_permissions` before `thunk`, and restore them afterwards.
- The POST/DELETE `/advanced` endpoints delete rows outside any `with-temp` scope, which wipes the
- migration-seeded rows for magic groups (all-internal-users, data-analyst, all-external-users) for
- the rest of the test run. Other tests (e.g. `resolve-user-permissions-default-test`) depend on
- those seed rows, so we snapshot and restore them here."
+ `DELETE /advanced` deletes rows outside any `with-temp` scope, which would wipe the migration-seeded rows
+ for the data-analyst magic group for the rest of the test run."
[thunk]
(let [snapshot (t2/select :model/MetabotPermissions)]
(try
@@ -132,7 +131,14 @@
(defmacro ^:private with-metabot-permissions-snapshot
"Wrap `body` in a snapshot/restore of the `metabot_permissions` table."
[& body]
- `(do-with-metabot-permissions-snapshot (fn [] ~@body)))
+ `(do-with-metabot-permissions-snapshot! (fn [] ~@body)))
+
+(defn- group-perm-values
+ "The `perm_value`s a permissions response reports for `group-id`, as a perm_type → perm_value map."
+ [response group-id]
+ (into {} (comp (filter #(= (:group_id %) group-id))
+ (map (juxt :perm_type :perm_value)))
+ (:permissions response)))
(deftest enable-advanced-permissions-test
(mt/with-premium-features #{:ai-controls}
@@ -140,34 +146,31 @@
(testing "requires superuser"
(is (= "You don't have permissions to do that."
(mt/user-http-request :rasta :post 403 "ee/ai-controls/permissions/advanced"))))
- (testing "removes All Users group custom permissions and returns full permissions"
+ (testing "removes the rows of every group outside group-level mode and keeps the rest"
(with-metabot-permissions-snapshot
- (let [all-users-id (u/the-id (perms/all-users-group))]
- ;; Pre-clean any leftover rows for the magic All Users group to avoid unique-constraint violations.
- (t2/delete! :model/MetabotPermissions :group_id all-users-id)
+ (t2/delete! :model/MetabotPermissions)
+ (let [all-users-id (u/the-id (perms/all-users-group))
+ all-external-id (u/the-id (perms/all-external-users-group))]
(mt/with-temporary-setting-values [metabot-advanced-permissions false]
- (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Other Group"}
- :model/MetabotPermissions _ {:group_id all-users-id
- :perm_type :permission/metabot-sql-generation
- :perm_value :yes}
- :model/MetabotPermissions _ {:group_id group-id
- :perm_type :permission/metabot-nlq
- :perm_value :yes}]
+ (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Other Group"}
+ :model/MetabotPermissions _ {:group_id all-users-id
+ :perm_type :permission/metabot
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id all-external-id
+ :perm_type :permission/metabot
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot-nlq
+ :perm_value :yes}]
(let [response (mt/user-http-request :crowberto :post 200 "ee/ai-controls/permissions/advanced")]
- (is (map? response))
- (is (contains? response :permissions))
- (is (true? (:advanced response))
- "Response should reflect advanced=true after enabling")
- (is (true? (metabot-settings/metabot-advanced-permissions))
- "metabot-advanced-permissions setting should flip to true")
- (is (= 0 (t2/count :model/MetabotPermissions :group_id all-users-id))
- "All Users custom permissions should be removed")
- (is (= 1 (t2/count :model/MetabotPermissions :group_id group-id))
- "Other group permissions should be untouched")
- (let [all-users-perms (->> (:permissions response)
- (filter #(= (:group_id %) all-users-id)))]
- (is (every? #(= "no" (:perm_value %)) all-users-perms)
- "All Users permissions in response should reflect defaults (no)")))))))))))
+ (is (=? {:advanced true} response))
+ (is (true? (metabot-settings/metabot-advanced-permissions)))
+ (is (= {group-id :permission/metabot-nlq}
+ (t2/select-fn->fn :group_id :perm_type :model/MetabotPermissions))
+ "only the groups group-level mode shows keep their rows")
+ (is (=? {"permission/metabot" "no"} (group-perm-values response all-users-id)))
+ (is (=? {"permission/metabot" "no"} (group-perm-values response all-external-id)))
+ (is (=? {"permission/metabot-nlq" "yes"} (group-perm-values response group-id))))))))))))
(deftest disable-advanced-permissions-test
(mt/with-premium-features #{:ai-controls}
@@ -175,27 +178,66 @@
(testing "requires superuser"
(is (= "You don't have permissions to do that."
(mt/user-http-request :rasta :delete 403 "ee/ai-controls/permissions/advanced"))))
- (testing "removes custom permissions from specific groups only, preserving All Users"
+ (testing "removes the rows of every group outside simple mode and keeps the rest"
(with-metabot-permissions-snapshot
- (let [all-users-id (u/the-id (perms/all-users-group))]
- ;; Pre-clean any leftover rows for the magic All Users group to avoid unique-constraint violations.
- (t2/delete! :model/MetabotPermissions :group_id all-users-id)
+ (t2/delete! :model/MetabotPermissions)
+ (let [all-users-id (u/the-id (perms/all-users-group))
+ all-external-id (u/the-id (perms/all-external-users-group))
+ data-analyst-id (u/the-id (perms/data-analyst-group))]
(mt/with-temporary-setting-values [metabot-advanced-permissions true]
- (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Specific Group"}
- :model/MetabotPermissions _ {:group_id all-users-id
- :perm_type :permission/metabot-nlq
- :perm_value :yes}
- :model/MetabotPermissions _ {:group_id group-id
- :perm_type :permission/metabot-sql-generation
- :perm_value :yes}]
+ (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Specific Group"}
+ :model/MetabotPermissions _ {:group_id all-users-id
+ :perm_type :permission/metabot-nlq
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id all-external-id
+ :perm_type :permission/metabot
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id data-analyst-id
+ :perm_type :permission/metabot
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :yes}]
(let [response (mt/user-http-request :crowberto :delete 200 "ee/ai-controls/permissions/advanced")]
- (is (map? response))
- (is (contains? response :permissions))
- (is (false? (:advanced response))
- "Response should reflect advanced=false after disabling")
- (is (false? (metabot-settings/metabot-advanced-permissions))
- "metabot-advanced-permissions setting should flip to false")
- (is (= 0 (t2/count :model/MetabotPermissions :group_id group-id))
- "Specific group custom permissions should be removed")
- (is (= 1 (t2/count :model/MetabotPermissions :group_id all-users-id))
- "All Users custom permissions should be untouched"))))))))))
+ (is (=? {:advanced false} response))
+ (is (false? (metabot-settings/metabot-advanced-permissions)))
+ (is (= {all-users-id :permission/metabot-nlq
+ all-external-id :permission/metabot}
+ (t2/select-fn->fn :group_id :perm_type :model/MetabotPermissions))
+ "only the simple-mode groups keep their rows")
+ (is (=? {"permission/metabot-sql-generation" "no"} (group-perm-values response group-id))))))))))))
+
+(deftest mode-switch-is-atomic-test
+ (mt/with-premium-features #{:ai-controls}
+ (testing "a mode switch that fails part way through leaves both the mode and the rows alone"
+ (with-metabot-permissions-snapshot
+ (mt/with-temporary-setting-values [metabot-advanced-permissions true]
+ (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Specific Group"}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot
+ :perm_value :yes}]
+ ;; Write the setting for real before throwing, so the failure has to undo the settings cache too.
+ (mt/with-dynamic-fn-redefs [metabot-settings/metabot-advanced-permissions!
+ (fn [advanced?]
+ ((mt/original-fn #'metabot-settings/metabot-advanced-permissions!) advanced?)
+ (throw (ex-info "boom" {})))]
+ (mt/user-http-request :crowberto :delete 500 "ee/ai-controls/permissions/advanced"))
+ (is (true? (metabot-settings/metabot-advanced-permissions))
+ "the cached mode goes back to the one the database still holds")
+ (is (t2/exists? :model/MetabotPermissions :group_id group-id)
+ "the rows the switch would have deleted are rolled back with it")))))))
+
+(deftest mode-switch-rejected-under-env-var-test
+ (mt/with-premium-features #{:ai-controls}
+ (testing "the /advanced endpoints refuse to switch modes while an env var forces the setting"
+ (with-metabot-permissions-snapshot
+ (mt/with-temp [:model/PermissionsGroup {group-id :id} {:name "Specific Group"}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot
+ :perm_value :yes}]
+ (mt/with-temp-env-var-value! [mb-metabot-advanced-permissions "true"]
+ (let [msg "The permission mode is set by the MB_METABOT_ADVANCED_PERMISSIONS environment variable."]
+ (is (= msg (mt/user-http-request :crowberto :delete 400 "ee/ai-controls/permissions/advanced")))
+ (is (= msg (mt/user-http-request :crowberto :post 400 "ee/ai-controls/permissions/advanced"))))
+ (is (t2/exists? :model/MetabotPermissions :group_id group-id)
+ "no rows are deleted by the refused switch")))))))
diff --git a/enterprise/backend/test/metabase_enterprise/metabot/permissions_test.clj b/enterprise/backend/test/metabase_enterprise/metabot/permissions_test.clj
index dd9a7e83d45..594c12664c5 100644
--- a/enterprise/backend/test/metabase_enterprise/metabot/permissions_test.clj
+++ b/enterprise/backend/test/metabase_enterprise/metabot/permissions_test.clj
@@ -2,7 +2,10 @@
(:require
[clojure.test :refer [deftest is testing]]
[metabase.metabot.scope :as scope]
- [metabase.test :as mt]))
+ [metabase.permissions.core :as perms]
+ [metabase.test :as mt]
+ [metabase.util :as u]
+ [toucan2.core :as t2]))
(deftest resolve-user-permissions-default-test
(mt/with-premium-features #{:ai-controls}
@@ -18,41 +21,86 @@
(deftest resolve-user-permissions-stored-test
(mt/with-premium-features #{:ai-controls}
- (testing "user in group with stored permissions gets those values"
- (mt/with-temp [:model/User {user-id :id} {}
- :model/PermissionsGroup {group-id :id} {:name "SQL Group"}
- :model/PermissionsGroupMembership _ {:user_id user-id
- :group_id group-id}
- :model/MetabotPermissions _ {:group_id group-id
- :perm_type :permission/metabot-sql-generation
- :perm_value :yes}]
- (let [perms (scope/resolve-user-permissions user-id)]
- (is (= :yes (:permission/metabot-sql-generation perms)))
- ;; all-internal-users magic group has :yes for nql from migration
- (is (= :yes (:permission/metabot-nlq perms))))))))
+ (testing "in group-level mode a user in a group with stored permissions gets those values"
+ (mt/with-temporary-setting-values [metabot-advanced-permissions true]
+ (mt/with-temp [:model/User {user-id :id} {}
+ :model/PermissionsGroup {group-id :id} {:name "SQL Group"}
+ :model/PermissionsGroupMembership _ {:user_id user-id
+ :group_id group-id}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :yes}]
+ (is (= {:permission/metabot-sql-generation :yes
+ :permission/metabot-nlq :no}
+ (select-keys (scope/resolve-user-permissions user-id)
+ [:permission/metabot-sql-generation :permission/metabot-nlq]))))))))
(deftest resolve-user-permissions-most-permissive-test
(mt/with-premium-features #{:ai-controls}
(testing "most permissive wins across multiple groups"
- (mt/with-temp [:model/User {user-id :id} {}
- :model/PermissionsGroup {group-a :id} {:name "Group A"}
- :model/PermissionsGroup {group-b :id} {:name "Group B"}
- :model/PermissionsGroupMembership _ {:user_id user-id :group_id group-a}
- :model/PermissionsGroupMembership _ {:user_id user-id :group_id group-b}
- :model/MetabotPermissions _ {:group_id group-a
- :perm_type :permission/metabot-sql-generation
- :perm_value :no}
- :model/MetabotPermissions _ {:group_id group-b
- :perm_type :permission/metabot-sql-generation
- :perm_value :yes}
- :model/MetabotPermissions _ {:group_id group-a
- :perm_type :permission/metabot-nlq
- :perm_value :no}
- :model/MetabotPermissions _ {:group_id group-b
- :perm_type :permission/metabot-nlq
- :perm_value :yes}]
- (let [perms (scope/resolve-user-permissions user-id)]
- (is (= :yes (:permission/metabot-sql-generation perms))
- ":yes wins over :no for sql-generation")
- (is (= :yes (:permission/metabot-nlq perms))
- ":yes wins over :no for nql"))))))
+ (mt/with-temporary-setting-values [metabot-advanced-permissions true]
+ (mt/with-temp [:model/User {user-id :id} {}
+ :model/PermissionsGroup {group-a :id} {:name "Group A"}
+ :model/PermissionsGroup {group-b :id} {:name "Group B"}
+ :model/PermissionsGroupMembership _ {:user_id user-id :group_id group-a}
+ :model/PermissionsGroupMembership _ {:user_id user-id :group_id group-b}
+ :model/MetabotPermissions _ {:group_id group-a
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :no}
+ :model/MetabotPermissions _ {:group_id group-b
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id group-a
+ :perm_type :permission/metabot-nlq
+ :perm_value :no}
+ :model/MetabotPermissions _ {:group_id group-b
+ :perm_type :permission/metabot-nlq
+ :perm_value :yes}]
+ (is (=? {:permission/metabot-sql-generation :yes
+ :permission/metabot-nlq :yes}
+ (scope/resolve-user-permissions user-id))))))))
+
+(defn- do-with-empty-metabot-permissions!
+ "Run `thunk` with the `metabot_permissions` table emptied, restoring the migration-seeded rows afterwards."
+ [thunk]
+ (let [snapshot (t2/select :model/MetabotPermissions)]
+ (t2/delete! :model/MetabotPermissions)
+ (try
+ (thunk)
+ (finally
+ (t2/delete! :model/MetabotPermissions)
+ (when (seq snapshot)
+ (t2/insert! :model/MetabotPermissions
+ (map #(select-keys % [:group_id :perm_type :perm_value]) snapshot)))))))
+
+(deftest resolve-user-permissions-mode-scoping-test
+ (mt/with-premium-features #{:ai-controls}
+ (do-with-empty-metabot-permissions!
+ (fn []
+ (let [all-users-id (u/the-id (perms/all-users-group))
+ data-analyst-id (u/the-id (perms/data-analyst-group))]
+ (mt/with-temp [:model/User {user-id :id} {}
+ :model/PermissionsGroup {group-id :id} {:name "Custom Group"}
+ :model/PermissionsGroupMembership _ {:user_id user-id :group_id group-id}
+ :model/PermissionsGroupMembership _ {:user_id user-id :group_id data-analyst-id}
+ :model/MetabotPermissions _ {:group_id all-users-id
+ :perm_type :permission/metabot
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id data-analyst-id
+ :perm_type :permission/metabot-nlq
+ :perm_value :yes}
+ :model/MetabotPermissions _ {:group_id group-id
+ :perm_type :permission/metabot-sql-generation
+ :perm_value :yes}]
+ (testing "simple mode resolves only the groups it shows, so hidden All Users :no cannot be overridden"
+ (mt/with-temporary-setting-values [metabot-advanced-permissions false]
+ (is (=? {:permission/metabot :yes
+ :permission/metabot-nlq :no
+ :permission/metabot-sql-generation :no}
+ (scope/resolve-user-permissions user-id)))))
+ (testing "group-level mode ignores the All Users rows it hides and resolves every other group"
+ (mt/with-temporary-setting-values [metabot-advanced-permissions true]
+ (is (=? {:permission/metabot :no
+ :permission/metabot-nlq :yes
+ :permission/metabot-sql-generation :yes}
+ (scope/resolve-user-permissions user-id)))))))))))