Skip to content

Play your Steam library's Windows games on a jailbroken PS5.

C++
2.7 KB
Raw Blame
foreach(required APP_DIR BOILERPLATE ASSETS_DIR FONTS_DIR PARAM_SOURCE PARAM_DEST TITLE_ID TITLE_NAME APP_VERSION)
	if(NOT DEFINED ${required})
		message(FATAL_ERROR "${required} is required")
	endif()
endforeach()

file(REMOVE_RECURSE "${APP_DIR}")
file(MAKE_DIRECTORY "${APP_DIR}/sce_sys" "${APP_DIR}/sce_module" "${APP_DIR}/assets/fonts")
file(COPY "${CMAKE_CURRENT_LIST_DIR}/../sce_sys/icon0.png"
	"${CMAKE_CURRENT_LIST_DIR}/../sce_sys/pic0.dds"
	"${CMAKE_CURRENT_LIST_DIR}/../sce_sys/pic1.dds"
	"${BOILERPLATE}/sce_sys/snd0.at9" DESTINATION "${APP_DIR}/sce_sys")
file(COPY "${ASSETS_DIR}/" DESTINATION "${APP_DIR}/assets")
file(COPY "${FONTS_DIR}/" DESTINATION "${APP_DIR}/assets/fonts")
file(COPY "${CMAKE_CURRENT_LIST_DIR}/../assets/branding/generic-title-icon.png" DESTINATION "${APP_DIR}/assets")

file(READ "${PARAM_SOURCE}" param)
string(JSON param SET "${param}" titleId "\"${TITLE_ID}\"")
string(SUBSTRING "${TITLE_ID}" 4 5 concept_id)
string(JSON param SET "${param}" conceptId "\"${concept_id}\"")
string(JSON param SET "${param}" contentId "\"UP9000-${TITLE_ID}_00-PLAYDENLAUNCHER1\"")
string(JSON param SET "${param}" localizedParameters en-US titleName "\"${TITLE_NAME}\"")
# The package version follows the project version: major.minor.patch as MM.mmm.ppp (0.2.0 is 00.002.000), so
# every release has its own value and later releases sort higher.
if(NOT APP_VERSION MATCHES "^([0-9]+)\\.([0-9]+)\\.([0-9]+)$")
	message(FATAL_ERROR "APP_VERSION must be major.minor.patch, got '${APP_VERSION}'")
endif()
set(version_parts "${CMAKE_MATCH_1}" "${CMAKE_MATCH_2}" "${CMAKE_MATCH_3}")
set(version_widths 2 3 3)
set(content_version "")
foreach(index RANGE 2)
	list(GET version_parts ${index} part)
	list(GET version_widths ${index} width)
	string(LENGTH "${part}" length)
	if(length GREATER width)
		message(FATAL_ERROR "APP_VERSION ${APP_VERSION} does not fit the package version format MM.mmm.ppp")
	endif()
	math(EXPR pad "${width} - ${length}")
	string(REPEAT "0" ${pad} zeros)
	if(content_version STREQUAL "")
		set(content_version "${zeros}${part}")
	else()
		set(content_version "${content_version}.${zeros}${part}")
	endif()
endforeach()
string(JSON param SET "${param}" contentVersion "\"${content_version}\"")
string(JSON attribute3 GET "${param}" attribute3)
math(EXPR attribute3 "(${attribute3} & ~0x80040) | 0x80040")
string(JSON param SET "${param}" attribute3 "${attribute3}")
file(WRITE "${PARAM_DEST}" "${param}\n")

if(PROBE_CA_BUNDLE)
 file(MAKE_DIRECTORY "${APP_DIR}/probe")
 file(COPY "${PROBE_CA_BUNDLE}" DESTINATION "${APP_DIR}/probe")
endif()

# The PS5 field stays numeric; the updater and log bundle use the full release version.
file(WRITE "${APP_DIR}/playden-version" "${FULL_VERSION}\n")