Skip to content

A lightweight WebAssembly runtime that is fast, secure, and standards-compliant

cranelift(x64): reuse shared i32 sums in addressing mode (#14607)

Theo Butler24814d8b6c3d
diff --git a/cranelift/codegen/src/isa/x64/inst.isle b/cranelift/codegen/src/isa/x64/inst.isle
index c571d34993..813d8b38a5 100644
--- a/cranelift/codegen/src/isa/x64/inst.isle
+++ b/cranelift/codegen/src/isa/x64/inst.isle
@@ -580,7 +580,17 @@
(decl amode_imm_reg (MemFlagsData Value Offset32) Amode)
(rule amode_imm_reg_base 0 (amode_imm_reg flags base offset)
(Amode.ImmReg offset base flags))
-(rule amode_imm_reg_iadd 1 (amode_imm_reg flags (iadd _ x y) offset)
+
+;; Only fold an `i32` sum into the amode if it has a transitively unique use.
+;; This accounts for uses on loop backedges that lowering has not seen yet,
+;; and avoids extending the live ranges of `x` and `y`.
+;;
+;; For `i64` sums, allow folding even with multiple uses. Loads/stores can
+;; use base+index directly, avoiding extra temporaries for shared addresses.
+(rule amode_imm_reg_iadd_i32 1 (amode_imm_reg flags base @ (iadd $I32 x y) offset)
+ (if-let _ (is_sinkable_inst base))
+ (amode_imm_reg_reg_shift flags x y offset))
+(rule amode_imm_reg_iadd_i64 1 (amode_imm_reg flags (iadd $I64 x y) offset)
(amode_imm_reg_reg_shift flags x y offset))
(attr amode_imm_reg_reg_shift (veri chain))
diff --git a/cranelift/filetests/filetests/isa/x64/lea-shared-iadd.clif b/cranelift/filetests/filetests/isa/x64/lea-shared-iadd.clif
new file mode 100644
index 0000000000..621a931ab3
--- /dev/null
+++ b/cranelift/filetests/filetests/isa/x64/lea-shared-iadd.clif
@@ -0,0 +1,105 @@
+test compile precise-output
+target x86_64
+
+function %shared_i32(i32, i32) -> i32, i32 {
+block0(v0: i32, v1: i32):
+ v2 = iadd v0, v1
+ v3 = iconst.i32 100
+ v4 = iadd v2, v3
+ return v2, v4
+}
+
+; VCode:
+; pushq %rbp
+; movq %rsp, %rbp
+; block0:
+; leal (%rdi, %rsi), %eax
+; leal 0x64(%rax), %edx
+; movq %rbp, %rsp
+; popq %rbp
+; retq
+;
+; Disassembled:
+; block0: ; offset 0x0
+; pushq %rbp
+; movq %rsp, %rbp
+; block1: ; offset 0x4
+; leal (%rdi, %rsi), %eax
+; leal 0x64(%rax), %edx
+; movq %rbp, %rsp
+; popq %rbp
+; retq
+
+function %shared_i32_loop(i32, i32, i8) -> i32 {
+block0(v0: i32, v1: i32, v2: i8):
+ jump block1(v0)
+block1(v3: i32):
+ v4 = iadd v3, v1
+ brif v2, block1(v4), block2
+block2:
+ v5 = iconst.i32 100
+ v6 = iadd v4, v5
+ return v6
+}
+
+; VCode:
+; pushq %rbp
+; movq %rsp, %rbp
+; block0:
+; jmp label1
+; block1:
+; leal (%rdi, %rsi), %edi
+; testb %dl, %dl
+; jnz label2; j label3
+; block2:
+; jmp label1
+; block3:
+; leal 0x64(%rdi), %eax
+; movq %rbp, %rsp
+; popq %rbp
+; retq
+;
+; Disassembled:
+; block0: ; offset 0x0
+; pushq %rbp
+; movq %rsp, %rbp
+; block1: ; offset 0x4
+; addl %esi, %edi
+; testb %dl, %dl
+; jne 4
+; block2: ; offset 0xe
+; leal 0x64(%rdi), %eax
+; movq %rbp, %rsp
+; popq %rbp
+; retq
+
+function %shared_i64_address(i64, i64) -> i32, i32 {
+block0(v0: i64, v1: i64):
+ v2 = iadd v0, v1
+ v3 = load.i32 notrap v2
+ v4 = iconst.i64 4
+ v5 = iadd v2, v4
+ v6 = load.i32 notrap v5
+ return v3, v6
+}
+
+; VCode:
+; pushq %rbp
+; movq %rsp, %rbp
+; block0:
+; movl (%rdi, %rsi), %eax
+; movl 4(%rdi, %rsi), %edx
+; movq %rbp, %rsp
+; popq %rbp
+; retq
+;
+; Disassembled:
+; block0: ; offset 0x0
+; pushq %rbp
+; movq %rsp, %rbp
+; block1: ; offset 0x4
+; movl (%rdi, %rsi), %eax
+; movl 4(%rdi, %rsi), %edx
+; movq %rbp, %rsp
+; popq %rbp
+; retq