Skip to content

A lightweight WebAssembly runtime that is fast, secure, and standards-compliant

Cranelift: add mid-end opt rules (#14327)

Hyunbin Kimc07af319ce85
diff --git a/cranelift/codegen/src/opts/arithmetic.isle b/cranelift/codegen/src/opts/arithmetic.isle
index a516468820..68e9cb9cdb 100644
--- a/cranelift/codegen/src/opts/arithmetic.isle
+++ b/cranelift/codegen/src/opts/arithmetic.isle
@@ -624,3 +624,7 @@
;; x /u (1 << y) --> x >>u y
(rule (simplify_skeleton (udiv x (ishl ty (iconst_u ty 1) y)))
(ushr ty x y))
+
+;; x %u (1 << k) --> x & ((1 << k) - 1).
+(rule (simplify_skeleton (urem x divisor @ (ishl ty (iconst_u ty 1) k)))
+ (band ty x (isub ty divisor (iconst_u ty 1))))
diff --git a/cranelift/codegen/src/opts/extends.isle b/cranelift/codegen/src/opts/extends.isle
index 8126004631..21598dd23b 100644
--- a/cranelift/codegen/src/opts/extends.isle
+++ b/cranelift/codegen/src/opts/extends.isle
@@ -96,3 +96,9 @@
;; Select narrowest type
(rule (simplify (ireduce ty (ireduce cty x))) (ireduce ty x))
+
+;; uextend(x) <u uextend(y) --> x <u y.
+(rule (simplify (ult rty
+ (uextend ty x @ (value_type (ty_int narrow)))
+ (uextend ty y @ (value_type narrow))))
+ (ult rty x y))
diff --git a/cranelift/codegen/src/opts/icmp.isle b/cranelift/codegen/src/opts/icmp.isle
index edd225e1da..4dbb8d8f16 100644
--- a/cranelift/codegen/src/opts/icmp.isle
+++ b/cranelift/codegen/src/opts/icmp.isle
@@ -545,3 +545,63 @@
;; rotl(x, k) == rotl(y, k) --> x == y.
(rule (simplify (eq ty (rotl cty x k) (rotl cty y k)))
(subsume (eq ty x y)))
+
+;; (x >=s 0) & (x <s N) --> x <u N, 0 < N < 2^(B - 1).
+(rule (simplify (band rty
+ (sge rty x (all_zero ty))
+ (slt rty x n @ (iconst_s (ty_int ty) limit))))
+ (if-let true (i64_gt limit 0))
+ (ult rty x n))
+(rule (simplify (band rty
+ (slt rty x n @ (iconst_s (ty_int ty) limit))
+ (sge rty x (all_zero ty))))
+ (if-let true (i64_gt limit 0))
+ (ult rty x n))
+
+;; x == ((x + (y >>u (B - k))) & -2^k) --> (x & (2^k - 1)) == 0.
+(rule (simplify (eq rty x
+ (band (ty_int ty)
+ (iadd ty x (ushr ty y (iconst_u _ shift)))
+ (iconst_s ty mask))))
+ (if-let true (i64_is_negative_power_of_two mask))
+ (if-let bits (i64_trailing_zeros mask))
+ (if-let true (u32_lt bits (ty_bits ty)))
+ (if-let true (u64_eq (u64_and shift (ty_shift_mask ty))
+ (u64_sub (ty_bits_u64 ty) bits)))
+ (subsume (eq rty (band ty x (iconst_s ty (i64_wrapping_sub (i64_wrapping_neg mask) 1)))
+ (all_zero ty))))
+(rule (simplify (eq rty x
+ (band (ty_int ty)
+ (iadd ty (ushr ty y (iconst_u _ shift)) x)
+ (iconst_s ty mask))))
+ (if-let true (i64_is_negative_power_of_two mask))
+ (if-let bits (i64_trailing_zeros mask))
+ (if-let true (u32_lt bits (ty_bits ty)))
+ (if-let true (u64_eq (u64_and shift (ty_shift_mask ty))
+ (u64_sub (ty_bits_u64 ty) bits)))
+ (subsume (eq rty (band ty x (iconst_s ty (i64_wrapping_sub (i64_wrapping_neg mask) 1)))
+ (all_zero ty))))
+(rule (simplify (eq rty
+ (band (ty_int ty)
+ (iadd ty x (ushr ty y (iconst_u _ shift)))
+ (iconst_s ty mask))
+ x))
+ (if-let true (i64_is_negative_power_of_two mask))
+ (if-let bits (i64_trailing_zeros mask))
+ (if-let true (u32_lt bits (ty_bits ty)))
+ (if-let true (u64_eq (u64_and shift (ty_shift_mask ty))
+ (u64_sub (ty_bits_u64 ty) bits)))
+ (subsume (eq rty (band ty x (iconst_s ty (i64_wrapping_sub (i64_wrapping_neg mask) 1)))
+ (all_zero ty))))
+(rule (simplify (eq rty
+ (band (ty_int ty)
+ (iadd ty (ushr ty y (iconst_u _ shift)) x)
+ (iconst_s ty mask))
+ x))
+ (if-let true (i64_is_negative_power_of_two mask))
+ (if-let bits (i64_trailing_zeros mask))
+ (if-let true (u32_lt bits (ty_bits ty)))
+ (if-let true (u64_eq (u64_and shift (ty_shift_mask ty))
+ (u64_sub (ty_bits_u64 ty) bits)))
+ (subsume (eq rty (band ty x (iconst_s ty (i64_wrapping_sub (i64_wrapping_neg mask) 1)))
+ (all_zero ty))))
diff --git a/cranelift/codegen/src/opts/shifts.isle b/cranelift/codegen/src/opts/shifts.isle
index 1b63a44eab..06e8350e79 100644
--- a/cranelift/codegen/src/opts/shifts.isle
+++ b/cranelift/codegen/src/opts/shifts.isle
@@ -329,3 +329,16 @@
(rule (simplify (sshr ty (iconst_s ty -1) x)) (subsume (iconst_s ty -1)))
(rule (simplify (rotl ty (iconst_s ty -1) x)) (subsume (iconst_s ty -1)))
(rule (simplify (rotr ty (iconst_s ty -1) x)) (subsume (iconst_s ty -1)))
+
+;; x << (k & (B - 1)) --> x << k.
+(rule (simplify (ishl ty x (band _ k (iconst_u _ mask))))
+ (if-let mask (ty_shift_mask ty))
+ (ishl ty x k))
+;; x >>u (k & (B - 1)) --> x >>u k.
+(rule (simplify (ushr ty x (band _ k (iconst_u _ mask))))
+ (if-let mask (ty_shift_mask ty))
+ (ushr ty x k))
+;; x >>s (k & (B - 1)) --> x >>s k.
+(rule (simplify (sshr ty x (band _ k (iconst_u _ mask))))
+ (if-let mask (ty_shift_mask ty))
+ (sshr ty x k))
diff --git a/cranelift/codegen/src/spec/opt.isle b/cranelift/codegen/src/spec/opt.isle
index 60f1896bd1..a525505f12 100644
--- a/cranelift/codegen/src/spec/opt.isle
+++ b/cranelift/codegen/src/spec/opt.isle
@@ -122,6 +122,7 @@
;; Pure constant-folding helpers on 64-bit immediates.
(spec (i64_wrapping_neg x) (provide (= result (bvneg x))))
+(spec (i64_wrapping_sub x y) (provide (= result (bvsub x y))))
(spec (u64_lt x y) (provide (= result (bvult x y))))
(spec (imm64 x) (provide (= result x)))
@@ -431,6 +432,10 @@
(concat (extract 47 40 n)
(concat (extract 55 48 n) (extract 63 56 n)))))))))))
(spec (u64_lt_eq x y) (provide (= result (bvule x y))))
+(spec (u32_lt x y) (provide (= result (bvult x y))))
+(spec (u64_is_power_of_two x)
+ (provide (= result (and (not (= x #x0000000000000000))
+ (= (bvand x (bvsub x #x0000000000000001)) #x0000000000000000)))))
(spec (u64_checked_rem x y)
(match (not (bv_is_zero! y)))
(provide (= result (bvurem x y))))
@@ -449,7 +454,10 @@
(match (not (bv_is_zero! result)))
(provide (= x result)))
(spec (i64_lt x y) (provide (= result (bvslt x y))))
+(spec (i64_gt x y) (provide (= result (if (bvsgt x y) true false))))
(spec (i64_gt_eq x y) (provide (= result (bvsge x y))))
+(spec (i64_trailing_zeros x)
+ (provide (= result (extract 31 0 (clz (rev x))))))
;;;; Type-derived signed bounds ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; Signed min/max of `ty` in the low bits: `(i64::{MIN,MAX} as u64) >> (64-bits)`.
diff --git a/cranelift/filetests/filetests/egraph/arithmetic-precise.clif b/cranelift/filetests/filetests/egraph/arithmetic-precise.clif
index c7d3142d1d..d8538950aa 100644
--- a/cranelift/filetests/filetests/egraph/arithmetic-precise.clif
+++ b/cranelift/filetests/filetests/egraph/arithmetic-precise.clif
@@ -634,3 +634,91 @@ block0(v0: i32x4):
; v1 = vconst.i32x4 const0
; return v1 ; v1 = const0
; }
+
+function %urem_shifted_1_i8(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = iconst.i8 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+
+; function %urem_shifted_1_i8(i8, i8) -> i8 fast {
+; block0(v0: i8, v1: i8):
+; v2 = iconst.i8 1
+; v3 = ishl v2, v1 ; v2 = 1
+; v5 = isub v3, v2 ; v2 = 1
+; v6 = band v0, v5
+; v4 -> v6
+; return v6
+; }
+
+function %urem_shifted_1_i16(i16, i16) -> i16 {
+block0(v0: i16, v1: i16):
+ v2 = iconst.i16 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+
+; function %urem_shifted_1_i16(i16, i16) -> i16 fast {
+; block0(v0: i16, v1: i16):
+; v2 = iconst.i16 1
+; v3 = ishl v2, v1 ; v2 = 1
+; v5 = isub v3, v2 ; v2 = 1
+; v6 = band v0, v5
+; v4 -> v6
+; return v6
+; }
+
+function %urem_shifted_1_i32(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+
+; function %urem_shifted_1_i32(i32, i32) -> i32 fast {
+; block0(v0: i32, v1: i32):
+; v2 = iconst.i32 1
+; v3 = ishl v2, v1 ; v2 = 1
+; v5 = isub v3, v2 ; v2 = 1
+; v6 = band v0, v5
+; v4 -> v6
+; return v6
+; }
+
+function %urem_shifted_1_i64(i64, i64) -> i64 {
+block0(v0: i64, v1: i64):
+ v2 = iconst.i64 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+
+; function %urem_shifted_1_i64(i64, i64) -> i64 fast {
+; block0(v0: i64, v1: i64):
+; v2 = iconst.i64 1
+; v3 = ishl v2, v1 ; v2 = 1
+; v5 = isub v3, v2 ; v2 = 1
+; v6 = band v0, v5
+; v4 -> v6
+; return v6
+; }
+
+function %urem_shifted_2_i32(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 2
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+
+; function %urem_shifted_2_i32(i32, i32) -> i32 fast {
+; block0(v0: i32, v1: i32):
+; v2 = iconst.i32 2
+; v3 = ishl v2, v1 ; v2 = 2
+; v4 = urem v0, v3
+; return v4
+; }
diff --git a/cranelift/filetests/filetests/egraph/extends.clif b/cranelift/filetests/filetests/egraph/extends.clif
index 54c14fcb80..dfb5e96905 100644
--- a/cranelift/filetests/filetests/egraph/extends.clif
+++ b/cranelift/filetests/filetests/egraph/extends.clif
@@ -258,3 +258,50 @@ block0(v0: i64):
; check: v4 = sextend.i128 v0
; check: return v4
+
+function %ult_uextend_i8_i32(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = uextend.i32 v0
+ v3 = uextend.i32 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; check: icmp ult v0, v1
+
+function %ult_uextend_i16_i64(i16, i16) -> i8 {
+block0(v0: i16, v1: i16):
+ v2 = uextend.i64 v0
+ v3 = uextend.i64 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; check: icmp ult v0, v1
+
+function %ult_uextend_i32_i64(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = uextend.i64 v0
+ v3 = uextend.i64 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; check: icmp ult v0, v1
+
+function %ult_uextend_i64_i128(i64, i64) -> i8 {
+block0(v0: i64, v1: i64):
+ v2 = uextend.i128 v0
+ v3 = uextend.i128 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; check: icmp ult v0, v1
+
+function %ult_uextend_different_input_types(i8, i16) -> i8 {
+block0(v0: i8, v1: i16):
+ v2 = uextend.i32 v0
+ v3 = uextend.i32 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; check: uextend.i32 v0
+; check: uextend.i32 v1
+; check: icmp ult v2, v3
diff --git a/cranelift/filetests/filetests/egraph/i128-opts.clif b/cranelift/filetests/filetests/egraph/i128-opts.clif
index 66d6adf3b6..33e96ec52f 100644
--- a/cranelift/filetests/filetests/egraph/i128-opts.clif
+++ b/cranelift/filetests/filetests/egraph/i128-opts.clif
@@ -154,6 +154,6 @@ block0:
v1 = uextend.i128 v0
v2 = icmp ult v1, v1
return v2
- ; check: v3 = iconst.i8 0
+ ; check: v4 = iconst.i8 0
; check: return
}
diff --git a/cranelift/filetests/filetests/egraph/icmp.clif b/cranelift/filetests/filetests/egraph/icmp.clif
index 2f09c3c10c..a6f50c828a 100644
--- a/cranelift/filetests/filetests/egraph/icmp.clif
+++ b/cranelift/filetests/filetests/egraph/icmp.clif
@@ -881,3 +881,408 @@ block0(v0: i32x4):
; v5 = vconst.i32x4 const1
; return v5 ; v5 = const1
; }
+
+function %signed_bounds_i8_limit100(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 0
+ v2 = iconst.i8 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_i8_limit100(i8) -> i8 fast {
+; block0(v0: i8):
+; v2 = iconst.i8 100
+; v6 = icmp ult v0, v2 ; v2 = 100
+; return v6
+; }
+
+function %signed_bounds_i32_limit100(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_i32_limit100(i32) -> i8 fast {
+; block0(v0: i32):
+; v2 = iconst.i32 100
+; v6 = icmp ult v0, v2 ; v2 = 100
+; return v6
+; }
+
+function %signed_bounds_i64_limit100(i64) -> i8 {
+block0(v0: i64):
+ v1 = iconst.i64 0
+ v2 = iconst.i64 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v4, v3
+ return v5
+}
+
+; function %signed_bounds_i64_limit100(i64) -> i8 fast {
+; block0(v0: i64):
+; v2 = iconst.i64 100
+; v6 = icmp ult v0, v2 ; v2 = 100
+; return v6
+; }
+
+function %signed_bounds_i32_limitneg1(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 -1
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_i32_limitneg1(i32) -> i8 fast {
+; block0(v0: i32):
+; v1 = iconst.i32 0
+; v3 = icmp sge v0, v1 ; v1 = 0
+; v2 = iconst.i32 -1
+; v4 = icmp slt v0, v2 ; v2 = -1
+; v5 = band v3, v4
+; return v5
+; }
+
+function %signed_bounds_i8_limit128(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 0
+ v2 = iconst.i8 128
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_i8_limit128(i8) -> i8 fast {
+; block0(v0: i8):
+; v1 = iconst.i8 0
+; return v1 ; v1 = 0
+; }
+
+function %signed_bounds_i32_limit0(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 0
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_i32_limit0(i32) -> i8 fast {
+; block0(v0: i32):
+; v6 = iconst.i8 0
+; return v6 ; v6 = 0
+; }
+
+function %signed_bounds_variable_limit(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 0
+ v3 = icmp sge v0, v2
+ v4 = icmp slt v0, v1
+ v5 = band v3, v4
+ return v5
+}
+
+; function %signed_bounds_variable_limit(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v2 = iconst.i32 0
+; v3 = icmp sge v0, v2 ; v2 = 0
+; v4 = icmp slt v0, v1
+; v5 = band v3, v4
+; return v5
+; }
+
+function %srem_zero_i8_divisor8(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 8
+ v2 = srem v0, v1
+ v3 = iconst.i8 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i8_divisor8(i8) -> i8 fast {
+; block0(v0: i8):
+; v14 = iconst.i8 7
+; v15 = band v0, v14 ; v14 = 7
+; v3 = iconst.i8 0
+; v16 = icmp eq v15, v3 ; v3 = 0
+; return v16
+; }
+
+function %srem_zero_i16_divisor8(i16) -> i8 {
+block0(v0: i16):
+ v1 = iconst.i16 8
+ v2 = srem v0, v1
+ v3 = iconst.i16 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i16_divisor8(i16) -> i8 fast {
+; block0(v0: i16):
+; v14 = iconst.i16 7
+; v15 = band v0, v14 ; v14 = 7
+; v3 = iconst.i16 0
+; v16 = icmp eq v15, v3 ; v3 = 0
+; return v16
+; }
+
+function %srem_zero_i32_divisor2(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 2
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i32_divisor2(i32) -> i8 fast {
+; block0(v0: i32):
+; v14 = iconst.i32 1
+; v15 = band v0, v14 ; v14 = 1
+; v5 = iconst.i32 0
+; v16 = icmp eq v15, v5 ; v5 = 0
+; return v16
+; }
+
+function %srem_zero_i32_divisor8(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i32_divisor8(i32) -> i8 fast {
+; block0(v0: i32):
+; v14 = iconst.i32 7
+; v15 = band v0, v14 ; v14 = 7
+; v3 = iconst.i32 0
+; v16 = icmp eq v15, v3 ; v3 = 0
+; return v16
+; }
+
+function %srem_zero_i64_divisor64(i64) -> i8 {
+block0(v0: i64):
+ v1 = iconst.i64 64
+ v2 = srem v0, v1
+ v3 = iconst.i64 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i64_divisor64(i64) -> i8 fast {
+; block0(v0: i64):
+; v14 = iconst.i64 63
+; v15 = band v0, v14 ; v14 = 63
+; v3 = iconst.i64 0
+; v16 = icmp eq v15, v3 ; v3 = 0
+; return v16
+; }
+
+function %srem_zero_i32_divisorneg8(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 -8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i32_divisorneg8(i32) -> i8 fast {
+; block0(v0: i32):
+; v13 = iconst.i32 7
+; v14 = band v0, v13 ; v13 = 7
+; v3 = iconst.i32 0
+; v15 = icmp eq v14, v3 ; v3 = 0
+; return v15
+; }
+
+function %srem_zero_i32_divisor7(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 7
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+
+; function %srem_zero_i32_divisor7(i32) -> i8 fast {
+; block0(v0: i32):
+; v5 = iconst.i32 -1840700269
+; v6 = smulhi v0, v5 ; v5 = -1840700269
+; v7 = iadd v6, v0
+; v8 = iconst.i32 2
+; v9 = sshr v7, v8 ; v8 = 2
+; v10 = iconst.i32 31
+; v11 = ushr v9, v10 ; v10 = 31
+; v12 = iadd v9, v11
+; v1 = iconst.i32 7
+; v13 = imul v12, v1 ; v1 = 7
+; v15 = icmp eq v0, v13
+; return v15
+; }
+
+function %srem_zero_shared_remainder(i32) -> i32, i8 {
+block0(v0: i32):
+ v1 = iconst.i32 8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v2, v4
+}
+
+; function %srem_zero_shared_remainder(i32) -> i32, i8 fast {
+; block0(v0: i32):
+; v5 = iconst.i32 2
+; v6 = sshr v0, v5 ; v5 = 2
+; v7 = iconst.i32 29
+; v8 = ushr v6, v7 ; v7 = 29
+; v9 = iadd v0, v8
+; v10 = iconst.i32 -8
+; v11 = band v9, v10 ; v10 = -8
+; v12 = isub v0, v11
+; v2 -> v12
+; v14 = iconst.i32 7
+; v15 = band v0, v14 ; v14 = 7
+; v3 = iconst.i32 0
+; v16 = icmp eq v15, v3 ; v3 = 0
+; return v12, v16
+; }
+
+function %rounding_eq_add0_eq0_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+
+; function %rounding_eq_add0_eq0_shift29_mask8(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v8 = iconst.i32 7
+; v9 = band v0, v8 ; v8 = 7
+; v10 = iconst.i32 0
+; v11 = icmp eq v9, v10 ; v10 = 0
+; return v11
+; }
+
+function %rounding_eq_add1_eq0_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v3, v0
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+
+; function %rounding_eq_add1_eq0_shift29_mask8(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v8 = iconst.i32 7
+; v9 = band v0, v8 ; v8 = 7
+; v10 = iconst.i32 0
+; v11 = icmp eq v9, v10 ; v10 = 0
+; return v11
+; }
+
+function %rounding_eq_add0_eq1_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v6, v0
+ return v7
+}
+
+; function %rounding_eq_add0_eq1_shift29_mask8(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v8 = iconst.i32 7
+; v9 = band v0, v8 ; v8 = 7
+; v10 = iconst.i32 0
+; v11 = icmp eq v9, v10 ; v10 = 0
+; return v11
+; }
+
+function %rounding_eq_add1_eq1_shift61_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 61
+ v3 = ushr v1, v2
+ v4 = iadd v3, v0
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v6, v0
+ return v7
+}
+
+; function %rounding_eq_add1_eq1_shift61_mask8(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v11 = iconst.i32 7
+; v12 = band v0, v11 ; v11 = 7
+; v13 = iconst.i32 0
+; v14 = icmp eq v12, v13 ; v13 = 0
+; return v14
+; }
+
+function %rounding_eq_add0_eq0_shift28_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 28
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+
+; function %rounding_eq_add0_eq0_shift28_mask8(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v2 = iconst.i32 28
+; v3 = ushr v1, v2 ; v2 = 28
+; v4 = iadd v0, v3
+; v5 = iconst.i32 -8
+; v6 = band v4, v5 ; v5 = -8
+; v7 = icmp eq v0, v6
+; return v7
+; }
+
+function %rounding_eq_add0_eq0_shift29_mask12(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -12
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+
+; function %rounding_eq_add0_eq0_shift29_mask12(i32, i32) -> i8 fast {
+; block0(v0: i32, v1: i32):
+; v2 = iconst.i32 29
+; v3 = ushr v1, v2 ; v2 = 29
+; v4 = iadd v0, v3
+; v5 = iconst.i32 -12
+; v6 = band v4, v5 ; v5 = -12
+; v7 = icmp eq v0, v6
+; return v7
+; }
diff --git a/cranelift/filetests/filetests/egraph/shifts.clif b/cranelift/filetests/filetests/egraph/shifts.clif
index 6667bc7f62..12ac2bd95a 100644
--- a/cranelift/filetests/filetests/egraph/shifts.clif
+++ b/cranelift/filetests/filetests/egraph/shifts.clif
@@ -693,3 +693,77 @@ block0(v0: i32, v1: i32, v2: i32):
; check: v7 = ishl v6, v2
; check: return v7
}
+
+function %ishl_masked_count_i8_i8_mask7(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = iconst.i8 7
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: ishl v0, v1
+
+function %ishl_masked_count_i32_i32_mask31(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 31
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: ishl v0, v1
+
+function %ishl_masked_count_i64_i8_mask63(i64, i8) -> i64 {
+block0(v0: i64, v1: i8):
+ v2 = iconst.i8 63
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: ishl v0, v1
+
+function %ishl_masked_count_i128_i32_mask127(i128, i32) -> i128 {
+block0(v0: i128, v1: i32):
+ v2 = iconst.i32 127
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: ishl v0, v1
+
+function %ushr_masked_count_i64_i32_mask63(i64, i32) -> i64 {
+block0(v0: i64, v1: i32):
+ v2 = iconst.i32 63
+ v3 = band v1, v2
+ v4 = ushr v0, v3
+ return v4
+}
+; check: ushr v0, v1
+
+function %sshr_masked_count_i32_i8_mask31(i32, i8) -> i32 {
+block0(v0: i32, v1: i8):
+ v2 = iconst.i8 31
+ v3 = band v1, v2
+ v4 = sshr v0, v3
+ return v4
+}
+; check: sshr v0, v1
+
+function %ishl_masked_count_i64_i32_mask31(i64, i32) -> i64 {
+block0(v0: i64, v1: i32):
+ v2 = iconst.i32 31
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: band v1, v2
+; check: ishl v0, v3
+
+;; The mask is determined by the lane width, not the total vector width.
+function %ishl_masked_count_i32x4(i32x4, i32) -> i32x4 {
+block0(v0: i32x4, v1: i32):
+ v2 = iconst.i32 31
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; check: ishl v0, v1
diff --git a/cranelift/filetests/filetests/runtests/extend.clif b/cranelift/filetests/filetests/runtests/extend.clif
index 063197ea76..6a3474a333 100644
--- a/cranelift/filetests/filetests/runtests/extend.clif
+++ b/cranelift/filetests/filetests/runtests/extend.clif
@@ -13,6 +13,20 @@ target pulley32be
target pulley64
target pulley64be
+set opt_level=speed
+target aarch64
+target s390x
+target x86_64
+target riscv64
+target riscv64 has_zba
+target riscv64 has_zbb
+target riscv64 has_zbkb
+target riscv64 has_c has_zcb
+target pulley32
+target pulley32be
+target pulley64
+target pulley64be
+
;;;; basic uextend
function %uextend8_16(i8) -> i16 {
@@ -248,3 +262,66 @@ block0(v0: i64):
; run: %nested_ireduce_i64_i8(0) == 0
; run: %nested_ireduce_i64_i8(-1) == -1
; run: %nested_ireduce_i64_i8(0x1234_5678_9abc_def0) == 0xf0
+
+function %ult_uextend_i8_i32(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = uextend.i32 v0
+ v3 = uextend.i32 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; run: %ult_uextend_i8_i32(0, 0) == 0
+; run: %ult_uextend_i8_i32(0, 255) == 1
+; run: %ult_uextend_i8_i32(255, 0) == 0
+; run: %ult_uextend_i8_i32(127, 128) == 1
+; run: %ult_uextend_i8_i32(128, 127) == 0
+
+function %ult_uextend_i16_i64(i16, i16) -> i8 {
+block0(v0: i16, v1: i16):
+ v2 = uextend.i64 v0
+ v3 = uextend.i64 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; run: %ult_uextend_i16_i64(0, 0) == 0
+; run: %ult_uextend_i16_i64(0, 65535) == 1
+; run: %ult_uextend_i16_i64(65535, 0) == 0
+; run: %ult_uextend_i16_i64(32767, 32768) == 1
+; run: %ult_uextend_i16_i64(32768, 32767) == 0
+
+function %ult_uextend_i32_i64(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = uextend.i64 v0
+ v3 = uextend.i64 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; run: %ult_uextend_i32_i64(0, 0) == 0
+; run: %ult_uextend_i32_i64(0, 4294967295) == 1
+; run: %ult_uextend_i32_i64(4294967295, 0) == 0
+; run: %ult_uextend_i32_i64(2147483647, 2147483648) == 1
+; run: %ult_uextend_i32_i64(2147483648, 2147483647) == 0
+
+function %ult_uextend_i64_i128(i64, i64) -> i8 {
+block0(v0: i64, v1: i64):
+ v2 = uextend.i128 v0
+ v3 = uextend.i128 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; run: %ult_uextend_i64_i128(0, 0) == 0
+; run: %ult_uextend_i64_i128(0, 18446744073709551615) == 1
+; run: %ult_uextend_i64_i128(18446744073709551615, 0) == 0
+; run: %ult_uextend_i64_i128(9223372036854775807, 9223372036854775808) == 1
+; run: %ult_uextend_i64_i128(9223372036854775808, 9223372036854775807) == 0
+
+function %ult_uextend_different_input_types(i8, i16) -> i8 {
+block0(v0: i8, v1: i16):
+ v2 = uextend.i32 v0
+ v3 = uextend.i32 v1
+ v4 = icmp ult v2, v3
+ return v4
+}
+; run: %ult_uextend_different_input_types(255, 256) == 1
+; run: %ult_uextend_different_input_types(255, 254) == 0
+; run: %ult_uextend_different_input_types(128, 32768) == 1
diff --git a/cranelift/filetests/filetests/runtests/icmp.clif b/cranelift/filetests/filetests/runtests/icmp.clif
index 06dfac638a..e658aaa50e 100644
--- a/cranelift/filetests/filetests/runtests/icmp.clif
+++ b/cranelift/filetests/filetests/runtests/icmp.clif
@@ -10,6 +10,17 @@ target pulley32be
target pulley64
target pulley64be
+set opt_level=speed
+target aarch64
+target s390x
+target x86_64
+target riscv64
+target riscv64 has_c has_zcb
+target pulley32
+target pulley32be
+target pulley64
+target pulley64be
+
; This test is also a regression test for aarch64.
; We were not correctly handling the fact that the rhs constant value
; overflows its type when viewed as a signed value, and thus encoding the wrong
@@ -260,3 +271,112 @@ block0(v0: i32, v1: i32):
}
; run: %ne_ineg(7, 7) == 0
; run: %ne_ineg(7, 3) == 1
+
+function %signed_bounds_i8_limit100(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 0
+ v2 = iconst.i8 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_i8_limit100(-1) == 0
+; run: %signed_bounds_i8_limit100(-128) == 0
+; run: %signed_bounds_i8_limit100(0) == 1
+; run: %signed_bounds_i8_limit100(99) == 1
+; run: %signed_bounds_i8_limit100(100) == 0
+; run: %signed_bounds_i8_limit100(127) == 0
+
+function %signed_bounds_i32_limit100(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_i32_limit100(-1) == 0
+; run: %signed_bounds_i32_limit100(-2147483648) == 0
+; run: %signed_bounds_i32_limit100(0) == 1
+; run: %signed_bounds_i32_limit100(99) == 1
+; run: %signed_bounds_i32_limit100(100) == 0
+; run: %signed_bounds_i32_limit100(2147483647) == 0
+
+function %signed_bounds_i64_limit100(i64) -> i8 {
+block0(v0: i64):
+ v1 = iconst.i64 0
+ v2 = iconst.i64 100
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v4, v3
+ return v5
+}
+; run: %signed_bounds_i64_limit100(-1) == 0
+; run: %signed_bounds_i64_limit100(-9223372036854775808) == 0
+; run: %signed_bounds_i64_limit100(0) == 1
+; run: %signed_bounds_i64_limit100(99) == 1
+; run: %signed_bounds_i64_limit100(100) == 0
+; run: %signed_bounds_i64_limit100(9223372036854775807) == 0
+
+function %signed_bounds_i32_limitneg1(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 -1
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_i32_limitneg1(-1) == 0
+; run: %signed_bounds_i32_limitneg1(-2147483648) == 0
+; run: %signed_bounds_i32_limitneg1(0) == 0
+; run: %signed_bounds_i32_limitneg1(99) == 0
+; run: %signed_bounds_i32_limitneg1(100) == 0
+; run: %signed_bounds_i32_limitneg1(2147483647) == 0
+
+function %signed_bounds_i8_limit128(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 0
+ v2 = iconst.i8 128
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_i8_limit128(-1) == 0
+; run: %signed_bounds_i8_limit128(-128) == 0
+; run: %signed_bounds_i8_limit128(0) == 0
+; run: %signed_bounds_i8_limit128(99) == 0
+; run: %signed_bounds_i8_limit128(100) == 0
+; run: %signed_bounds_i8_limit128(127) == 0
+
+function %signed_bounds_i32_limit0(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 0
+ v2 = iconst.i32 0
+ v3 = icmp sge v0, v1
+ v4 = icmp slt v0, v2
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_i32_limit0(-1) == 0
+; run: %signed_bounds_i32_limit0(-2147483648) == 0
+; run: %signed_bounds_i32_limit0(0) == 0
+; run: %signed_bounds_i32_limit0(99) == 0
+; run: %signed_bounds_i32_limit0(100) == 0
+; run: %signed_bounds_i32_limit0(2147483647) == 0
+
+function %signed_bounds_variable_limit(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 0
+ v3 = icmp sge v0, v2
+ v4 = icmp slt v0, v1
+ v5 = band v3, v4
+ return v5
+}
+; run: %signed_bounds_variable_limit(0, -1) == 0
+; run: %signed_bounds_variable_limit(-1, -1) == 0
+; run: %signed_bounds_variable_limit(0, 1) == 1
+; run: %signed_bounds_variable_limit(100, 100) == 0
diff --git a/cranelift/filetests/filetests/runtests/shifts.clif b/cranelift/filetests/filetests/runtests/shifts.clif
index e32abaaf10..1981dbddd7 100644
--- a/cranelift/filetests/filetests/runtests/shifts.clif
+++ b/cranelift/filetests/filetests/runtests/shifts.clif
@@ -11,6 +11,18 @@ target pulley32be
target pulley64
target pulley64be
+set opt_level=speed
+target aarch64
+target x86_64
+target x86_64 has_bmi2
+target s390x
+target riscv64
+target riscv64 has_c has_zcb
+target pulley32
+target pulley32be
+target pulley64
+target pulley64be
+
function %ishl_i64_i64(i64, i64) -> i64 {
block0(v0: i64, v1: i64):
v2 = ishl.i64 v0, v1
@@ -1170,3 +1182,81 @@ block0(v0: i32, v1: i32, v2: i32):
; run: %bxor_ushr_rt(0, 0, 0) == 0
; run: %bxor_ushr_rt(0x12345678, 0x9abcdef0, 4) == 0x08888888
; run: %bxor_ushr_rt(0x12345678, 0x9abcdef0, 32) == 0x88888888
+
+function %ishl_masked_count_i8_i8_mask7(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = iconst.i8 7
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; run: %ishl_masked_count_i8_i8_mask7(1, 0) == 0x1
+; run: %ishl_masked_count_i8_i8_mask7(1, 7) == 0x80
+; run: %ishl_masked_count_i8_i8_mask7(3, 8) == 0x3
+; run: %ishl_masked_count_i8_i8_mask7(-1, 9) == 0xfe
+; run: %ishl_masked_count_i8_i8_mask7(-128, 255) == 0x0
+
+function %ishl_masked_count_i32_i32_mask31(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 31
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; run: %ishl_masked_count_i32_i32_mask31(1, 0) == 0x1
+; run: %ishl_masked_count_i32_i32_mask31(1, 31) == 0x80000000
+; run: %ishl_masked_count_i32_i32_mask31(3, 32) == 0x3
+; run: %ishl_masked_count_i32_i32_mask31(-1, 33) == 0xfffffffe
+; run: %ishl_masked_count_i32_i32_mask31(-128, 4294967295) == 0x0
+
+function %ishl_masked_count_i64_i8_mask63(i64, i8) -> i64 {
+block0(v0: i64, v1: i8):
+ v2 = iconst.i8 63
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; run: %ishl_masked_count_i64_i8_mask63(1, 0) == 0x1
+; run: %ishl_masked_count_i64_i8_mask63(1, 63) == 0x8000000000000000
+; run: %ishl_masked_count_i64_i8_mask63(3, 64) == 0x3
+; run: %ishl_masked_count_i64_i8_mask63(-1, 65) == 0xfffffffffffffffe
+; run: %ishl_masked_count_i64_i8_mask63(-128, 255) == 0x0
+
+function %ushr_masked_count_i64_i32_mask63(i64, i32) -> i64 {
+block0(v0: i64, v1: i32):
+ v2 = iconst.i32 63
+ v3 = band v1, v2
+ v4 = ushr v0, v3
+ return v4
+}
+; run: %ushr_masked_count_i64_i32_mask63(1, 0) == 0x1
+; run: %ushr_masked_count_i64_i32_mask63(1, 63) == 0x0
+; run: %ushr_masked_count_i64_i32_mask63(3, 64) == 0x3
+; run: %ushr_masked_count_i64_i32_mask63(-1, 65) == 0x7fffffffffffffff
+; run: %ushr_masked_count_i64_i32_mask63(-128, 4294967295) == 0x1
+
+function %sshr_masked_count_i32_i8_mask31(i32, i8) -> i32 {
+block0(v0: i32, v1: i8):
+ v2 = iconst.i8 31
+ v3 = band v1, v2
+ v4 = sshr v0, v3
+ return v4
+}
+; run: %sshr_masked_count_i32_i8_mask31(1, 0) == 0x1
+; run: %sshr_masked_count_i32_i8_mask31(1, 31) == 0x0
+; run: %sshr_masked_count_i32_i8_mask31(3, 32) == 0x3
+; run: %sshr_masked_count_i32_i8_mask31(-1, 33) == 0xffffffff
+; run: %sshr_masked_count_i32_i8_mask31(-128, 255) == 0xffffffff
+
+function %ishl_masked_count_i64_i32_mask31(i64, i32) -> i64 {
+block0(v0: i64, v1: i32):
+ v2 = iconst.i32 31
+ v3 = band v1, v2
+ v4 = ishl v0, v3
+ return v4
+}
+; run: %ishl_masked_count_i64_i32_mask31(1, 0) == 0x1
+; run: %ishl_masked_count_i64_i32_mask31(1, 63) == 0x80000000
+; run: %ishl_masked_count_i64_i32_mask31(3, 64) == 0x3
+; run: %ishl_masked_count_i64_i32_mask31(-1, 65) == 0xfffffffffffffffe
+; run: %ishl_masked_count_i64_i32_mask31(-128, 4294967295) == 0xffffffc000000000
diff --git a/cranelift/filetests/filetests/runtests/srem_opts.clif b/cranelift/filetests/filetests/runtests/srem_opts.clif
index a59e923ec8..383898361e 100644
--- a/cranelift/filetests/filetests/runtests/srem_opts.clif
+++ b/cranelift/filetests/filetests/runtests/srem_opts.clif
@@ -414,3 +414,236 @@ block0(v0: i64):
; run: %srem_imm_prime_i64(-1000) == -30
; run: %srem_imm_prime_i64(96) == 96
; run: %srem_imm_prime_i64(-96) == -96
+
+function %srem_zero_i8_divisor8(i8) -> i8 {
+block0(v0: i8):
+ v1 = iconst.i8 8
+ v2 = srem v0, v1
+ v3 = iconst.i8 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i8_divisor8(0) == 1
+; run: %srem_zero_i8_divisor8(8) == 1
+; run: %srem_zero_i8_divisor8(-8) == 1
+; run: %srem_zero_i8_divisor8(9) == 0
+; run: %srem_zero_i8_divisor8(-9) == 0
+; run: %srem_zero_i8_divisor8(-128) == 1
+; run: %srem_zero_i8_divisor8(127) == 0
+
+function %srem_zero_i16_divisor8(i16) -> i8 {
+block0(v0: i16):
+ v1 = iconst.i16 8
+ v2 = srem v0, v1
+ v3 = iconst.i16 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i16_divisor8(0) == 1
+; run: %srem_zero_i16_divisor8(8) == 1
+; run: %srem_zero_i16_divisor8(-8) == 1
+; run: %srem_zero_i16_divisor8(9) == 0
+; run: %srem_zero_i16_divisor8(-9) == 0
+; run: %srem_zero_i16_divisor8(-32768) == 1
+; run: %srem_zero_i16_divisor8(32767) == 0
+
+function %srem_zero_i32_divisor2(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 2
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i32_divisor2(0) == 1
+; run: %srem_zero_i32_divisor2(2) == 1
+; run: %srem_zero_i32_divisor2(-2) == 1
+; run: %srem_zero_i32_divisor2(3) == 0
+; run: %srem_zero_i32_divisor2(-3) == 0
+; run: %srem_zero_i32_divisor2(-2147483648) == 1
+; run: %srem_zero_i32_divisor2(2147483647) == 0
+
+function %srem_zero_i32_divisor8(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i32_divisor8(0) == 1
+; run: %srem_zero_i32_divisor8(8) == 1
+; run: %srem_zero_i32_divisor8(-8) == 1
+; run: %srem_zero_i32_divisor8(9) == 0
+; run: %srem_zero_i32_divisor8(-9) == 0
+; run: %srem_zero_i32_divisor8(-2147483648) == 1
+; run: %srem_zero_i32_divisor8(2147483647) == 0
+
+function %srem_zero_i64_divisor64(i64) -> i8 {
+block0(v0: i64):
+ v1 = iconst.i64 64
+ v2 = srem v0, v1
+ v3 = iconst.i64 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i64_divisor64(0) == 1
+; run: %srem_zero_i64_divisor64(64) == 1
+; run: %srem_zero_i64_divisor64(-64) == 1
+; run: %srem_zero_i64_divisor64(65) == 0
+; run: %srem_zero_i64_divisor64(-65) == 0
+; run: %srem_zero_i64_divisor64(-9223372036854775808) == 1
+; run: %srem_zero_i64_divisor64(9223372036854775807) == 0
+
+function %srem_zero_i32_divisorneg8(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 -8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i32_divisorneg8(0) == 1
+; run: %srem_zero_i32_divisorneg8(-8) == 1
+; run: %srem_zero_i32_divisorneg8(8) == 1
+; run: %srem_zero_i32_divisorneg8(-7) == 0
+; run: %srem_zero_i32_divisorneg8(-9) == 0
+; run: %srem_zero_i32_divisorneg8(-2147483648) == 1
+; run: %srem_zero_i32_divisorneg8(2147483647) == 0
+
+function %srem_zero_i32_divisor7(i32) -> i8 {
+block0(v0: i32):
+ v1 = iconst.i32 7
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v4
+}
+; run: %srem_zero_i32_divisor7(0) == 1
+; run: %srem_zero_i32_divisor7(7) == 1
+; run: %srem_zero_i32_divisor7(-7) == 1
+; run: %srem_zero_i32_divisor7(8) == 0
+; run: %srem_zero_i32_divisor7(-8) == 0
+; run: %srem_zero_i32_divisor7(-2147483648) == 0
+; run: %srem_zero_i32_divisor7(2147483647) == 0
+
+function %srem_zero_shared_remainder(i32) -> i32, i8 {
+block0(v0: i32):
+ v1 = iconst.i32 8
+ v2 = srem v0, v1
+ v3 = iconst.i32 0
+ v4 = icmp eq v2, v3
+ return v2, v4
+}
+; run: %srem_zero_shared_remainder(9) == [1, 0]
+; run: %srem_zero_shared_remainder(-9) == [-1, 0]
+; run: %srem_zero_shared_remainder(-8) == [0, 1]
+; run: %srem_zero_shared_remainder(-2147483648) == [0, 1]
+
+function %rounding_eq_add0_eq0_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+; run: %rounding_eq_add0_eq0_shift29_mask8(0, -2147483648) == 1
+; run: %rounding_eq_add0_eq0_shift29_mask8(8, -1) == 1
+; run: %rounding_eq_add0_eq0_shift29_mask8(-8, -1) == 1
+; run: %rounding_eq_add0_eq0_shift29_mask8(9, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask8(-1, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask8(4, 0) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask8(2147483647, -1) == 0
+
+function %rounding_eq_add1_eq0_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v3, v0
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+; run: %rounding_eq_add1_eq0_shift29_mask8(0, -2147483648) == 1
+; run: %rounding_eq_add1_eq0_shift29_mask8(8, -1) == 1
+; run: %rounding_eq_add1_eq0_shift29_mask8(-8, -1) == 1
+; run: %rounding_eq_add1_eq0_shift29_mask8(9, -1) == 0
+; run: %rounding_eq_add1_eq0_shift29_mask8(-1, -1) == 0
+; run: %rounding_eq_add1_eq0_shift29_mask8(4, 0) == 0
+; run: %rounding_eq_add1_eq0_shift29_mask8(2147483647, -1) == 0
+
+function %rounding_eq_add0_eq1_shift29_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v6, v0
+ return v7
+}
+; run: %rounding_eq_add0_eq1_shift29_mask8(0, -2147483648) == 1
+; run: %rounding_eq_add0_eq1_shift29_mask8(8, -1) == 1
+; run: %rounding_eq_add0_eq1_shift29_mask8(-8, -1) == 1
+; run: %rounding_eq_add0_eq1_shift29_mask8(9, -1) == 0
+; run: %rounding_eq_add0_eq1_shift29_mask8(-1, -1) == 0
+; run: %rounding_eq_add0_eq1_shift29_mask8(4, 0) == 0
+; run: %rounding_eq_add0_eq1_shift29_mask8(2147483647, -1) == 0
+
+function %rounding_eq_add1_eq1_shift61_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 61
+ v3 = ushr v1, v2
+ v4 = iadd v3, v0
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v6, v0
+ return v7
+}
+; run: %rounding_eq_add1_eq1_shift61_mask8(0, -2147483648) == 1
+; run: %rounding_eq_add1_eq1_shift61_mask8(8, -1) == 1
+; run: %rounding_eq_add1_eq1_shift61_mask8(-8, -1) == 1
+; run: %rounding_eq_add1_eq1_shift61_mask8(9, -1) == 0
+; run: %rounding_eq_add1_eq1_shift61_mask8(-1, -1) == 0
+; run: %rounding_eq_add1_eq1_shift61_mask8(4, 0) == 0
+; run: %rounding_eq_add1_eq1_shift61_mask8(2147483647, -1) == 0
+
+function %rounding_eq_add0_eq0_shift28_mask8(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 28
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -8
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+; run: %rounding_eq_add0_eq0_shift28_mask8(0, -2147483648) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(8, -1) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(-8, -1) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(9, -1) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(-1, -1) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(4, 0) == 0
+; run: %rounding_eq_add0_eq0_shift28_mask8(2147483647, -1) == 0
+
+function %rounding_eq_add0_eq0_shift29_mask12(i32, i32) -> i8 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 29
+ v3 = ushr v1, v2
+ v4 = iadd v0, v3
+ v5 = iconst.i32 -12
+ v6 = band v4, v5
+ v7 = icmp eq v0, v6
+ return v7
+}
+; run: %rounding_eq_add0_eq0_shift29_mask12(0, -2147483648) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask12(8, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask12(-8, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask12(9, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask12(-1, -1) == 0
+; run: %rounding_eq_add0_eq0_shift29_mask12(4, 0) == 1
+; run: %rounding_eq_add0_eq0_shift29_mask12(2147483647, -1) == 0
diff --git a/cranelift/filetests/filetests/runtests/urem.clif b/cranelift/filetests/filetests/runtests/urem.clif
index 6527399dab..780f390dfb 100644
--- a/cranelift/filetests/filetests/runtests/urem.clif
+++ b/cranelift/filetests/filetests/runtests/urem.clif
@@ -10,6 +10,17 @@ target pulley32be
target pulley64
target pulley64be
+set opt_level=speed
+target aarch64
+target s390x
+target x86_64
+target riscv64
+target riscv64 has_c has_zcb
+target pulley32
+target pulley32be
+target pulley64
+target pulley64be
+
function %urem_i64(i64, i64) -> i64 {
block0(v0: i64,v1: i64):
v2 = urem v0, v1
@@ -153,3 +164,74 @@ block0:
}
; run: %constant_inputs() == 0
+
+function %urem_shifted_1_i8(i8, i8) -> i8 {
+block0(v0: i8, v1: i8):
+ v2 = iconst.i8 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+; run: %urem_shifted_1_i8(0, 0) == 0x0
+; run: %urem_shifted_1_i8(-1, 0) == 0x0
+; run: %urem_shifted_1_i8(-1, 7) == 0x7f
+; run: %urem_shifted_1_i8(-1, 8) == 0x0
+; run: %urem_shifted_1_i8(-1, 9) == 0x1
+; run: %urem_shifted_1_i8(-1, 255) == 0x7f
+; run: %urem_shifted_1_i8(-128, 7) == 0x0
+
+function %urem_shifted_1_i16(i16, i16) -> i16 {
+block0(v0: i16, v1: i16):
+ v2 = iconst.i16 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+; run: %urem_shifted_1_i16(0, 0) == 0x0
+; run: %urem_shifted_1_i16(-1, 0) == 0x0
+; run: %urem_shifted_1_i16(-1, 15) == 0x7fff
+; run: %urem_shifted_1_i16(-1, 16) == 0x0
+; run: %urem_shifted_1_i16(-1, 17) == 0x1
+; run: %urem_shifted_1_i16(-1, 65535) == 0x7fff
+; run: %urem_shifted_1_i16(-32768, 15) == 0x0
+
+function %urem_shifted_1_i32(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+; run: %urem_shifted_1_i32(0, 0) == 0x0
+; run: %urem_shifted_1_i32(-1, 0) == 0x0
+; run: %urem_shifted_1_i32(-1, 31) == 0x7fffffff
+; run: %urem_shifted_1_i32(-1, 32) == 0x0
+; run: %urem_shifted_1_i32(-1, 33) == 0x1
+; run: %urem_shifted_1_i32(-1, 4294967295) == 0x7fffffff
+; run: %urem_shifted_1_i32(-2147483648, 31) == 0x0
+
+function %urem_shifted_1_i64(i64, i64) -> i64 {
+block0(v0: i64, v1: i64):
+ v2 = iconst.i64 1
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+; run: %urem_shifted_1_i64(0, 0) == 0x0
+; run: %urem_shifted_1_i64(-1, 0) == 0x0
+; run: %urem_shifted_1_i64(-1, 63) == 0x7fffffffffffffff
+; run: %urem_shifted_1_i64(-1, 64) == 0x0
+; run: %urem_shifted_1_i64(-1, 65) == 0x1
+; run: %urem_shifted_1_i64(-1, 18446744073709551615) == 0x7fffffffffffffff
+; run: %urem_shifted_1_i64(-9223372036854775808, 63) == 0x0
+
+function %urem_shifted_2_i32(i32, i32) -> i32 {
+block0(v0: i32, v1: i32):
+ v2 = iconst.i32 2
+ v3 = ishl v2, v1
+ v4 = urem v0, v3
+ return v4
+}
+; run: %urem_shifted_2_i32(17, 0) == 0x1
+; run: %urem_shifted_2_i32(17, 3) == 0x1
+; run: %urem_shifted_2_i32(-1, 30) == 0x7fffffff